build.gradle

plugins {
	id 'java'
	id 'org.springframework.boot' version '3.1.3'
	id 'io.spring.dependency-management' version '1.1.3'
	id 'com.diffplug.spotless' version '6.23.3'
}

group = 'com.example'
version = '0.0.1-SNAPSHOT'

java {
	sourceCompatibility = '17'
}

configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}
}

repositories {
	mavenCentral()
}


dependencies {
	implementation 'org.springframework.boot:spring-boot-starter-security'
	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
	implementation 'org.springframework.boot:spring-boot-starter-thymeleaf'
	implementation 'org.springframework.boot:spring-boot-starter-web'
	implementation 'org.springframework.boot:spring-boot-starter-validation'
	implementation 'javax.servlet:javax.servlet-api:4.0.1'

	//크롤링
	implementation 'org.seleniumhq.selenium:selenium-java:4.15.0'
	implementation 'io.github.bonigarcia:webdrivermanager:5.6.2'
	// Email
	implementation 'org.springframework.boot:spring-boot-starter-mail'

	implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.0.0'

	// Querydsl
	implementation 'com.querydsl:querydsl-jpa:5.0.0:jakarta'
	annotationProcessor "com.querydsl:querydsl-apt:5.0.0:jakarta"
	annotationProcessor "jakarta.annotation:jakarta.annotation-api"
	annotationProcessor "jakarta.persistence:jakarta.persistence-api"


	// JWT
	implementation 'io.jsonwebtoken:jjwt-api:0.11.5'
	implementation 'io.jsonwebtoken:jjwt-impl:0.11.5'
	implementation 'io.jsonwebtoken:jjwt-jackson:0.11.5'


	compileOnly 'org.projectlombok:lombok'
	testImplementation 'junit:junit:4.13.1'
	runtimeOnly 'com.h2database:h2'
	annotationProcessor 'org.projectlombok:lombok'
	testImplementation 'org.springframework.boot:spring-boot-starter-test'
}


tasks.named('test') {
	useJUnitPlatform()
}

tasks.register('updateGitHooks', Copy) {
	from new File(rootProject.rootDir, '.script/pre-commit')
	into { new File(rootProject.rootDir, '.git/hooks') }
	if (System.getProperty('os.name').toLowerCase().contains('windows')) {
		Runtime.getRuntime().exec("cmd /c chmod -R +x .git/hooks/")
	} else {
		Runtime.getRuntime().exec("chmod -R +x .git/hooks/")
	}
}

tasks.named('compileJava') {
	dependsOn 'spotlessApply'
	dependsOn 'updateGitHooks'
}

def generated = 'src/main/generated'
tasks.withType(JavaCompile) {
	options.getGeneratedSourceOutputDirectory().set(file(generated))
}

clean {
	delete file(generated)
}

spotless {
	java {
		//사용하지 않는 import 제거
		removeUnusedImports()
		// 공백 제거
		trimTrailingWhitespace()
		// 끝부분 NewLine 처리
		endWithNewline()
		// Google Java 포맷 적용 -> 탭은 4개의 공백
		googleJavaFormat().aosp()
		// import 정렬
		importOrder('java', 'javax', 'jakarta', 'org', 'com')
	}
}