settings.gradle

pluginManagement {
	repositories {
		gradlePluginPortal()
		mavenCentral()
	}
}

rootProject.name = 'baymax'

ext {
	//@formatter:off

	//plugin versions
	gradleGitVersion        = '[2.4, 3.0['
	springBootVersion       = '[3.3.1, 3.4['
	sonarqubeVersion        = '[5.0.0.4638, 6.0['
	versionsVersion         = '0.+'

	jdaVersion              = '[5.1.2, 5.2['
	sentryVersion           = '[7.0.0, 8.0['
	emojiVersion            = '[5.1.1, 6.0['
	guavaVersion            = '[33.0.0-jre, 34['

	//@formatter:on
}

dependencyResolutionManagement {

	versionCatalogs {
		libs {
			version("spring-boot", "$springBootVersion")

			plugin("gitprops", "com.gorylenko.gradle-git-properties").version("$gradleGitVersion")
			plugin("spring", "org.springframework.boot").version("$springBootVersion")
			plugin("sonar", "org.sonarqube").version("$sonarqubeVersion")
			plugin("versions", "com.github.ben-manes.versions").version("$versionsVersion")

			library("spring-boot-bom", "org.springframework.boot", "spring-boot-dependencies").versionRef("spring-boot")
			library("jda", "net.dv8tion:JDA:$jdaVersion")
			library("logback", "ch.qos.logback", "logback-classic").withoutVersion()
			library("sentry", "io.sentry:sentry-logback:$sentryVersion")
			library("sentry-spring-starter", "io.sentry:sentry-spring-boot-starter-jakarta:$sentryVersion")
			library("snakeyaml", "org.yaml", "snakeyaml").withoutVersion()
			library("caffeine", "com.github.ben-manes.caffeine", "caffeine").withoutVersion()
			library("emojis", "com.vdurmont:emoji-java:$emojiVersion")
			library("guava", "com.google.guava:guava:$guavaVersion")
			library("sqlite", "org.xerial", "sqlite-jdbc").withoutVersion()
			library("flyway", "org.flywaydb", "flyway-core").withoutVersion()

			library("spring-boot-starter", "org.springframework.boot", "spring-boot-starter").withoutVersion()

			library("junit-api", "org.junit.jupiter", "junit-jupiter-api").withoutVersion()
			library("junit-engine", "org.junit.jupiter", "junit-jupiter-engine").withoutVersion()
			library("junit-launcher", "org.junit.platform", "junit-platform-launcher").withoutVersion()
		}
	}
}