feat(query): implements "Beta - SQL DB Instance Without Centralized Logging"

assets/queries/terraform/gcp/sql_db_instance_without_centralized_logging/metadata.json

@@ -0,0 +1,14 @@
+{
+  "id": "245eb024-d08a-449b-a1f2-02f7bba00fc2",
+  "queryName": "Beta - SQL DB Instance Without Centralized Logging",
+  "severity": "LOW",
+  "category": "Observability",
+  "descriptionText": "All 'google_sql_database_instance' resources based on POSTGRES should enable the 'cloudsql.enable_pgaudit' flag to allow for centralized logging",
+  "descriptionUrl": "https://registry.terraform.io/providers/hashicorp/google/latest/docs/resources/sql_database_instance.html#settings-1",
+  "platform": "Terraform",
+  "descriptionID": "245eb024",
+  "cloudProvider": "gcp",
+  "cwe": "778",
+  "riskScore": "1.0",
+  "experimental": "true"
+}

assets/queries/terraform/gcp/sql_db_instance_without_centralized_logging/query.rego

@@ -0,0 +1,85 @@
+package Cx
+
+import data.generic.common as common_lib
+import data.generic.terraform as tf_lib
+
+CxPolicy[result] {
+	resource := input.document[i].resource.google_sql_database_instance[name]
+
+	contains(resource.database_version, "POSTGRES")
+	results := get_results(resource, name)
+
+	result := {
+		"documentId": input.document[i].id,
+		"resourceType": "google_sql_database_instance",
+		"resourceName": tf_lib.get_resource_name(resource, name),
+		"searchKey": results.searchKey,
+		"issueType": results.issueType,
+		"keyExpectedValue": results.keyExpectedValue,
+		"keyActualValue": results.keyActualValue,
+		"searchLine": results.searchLine
+	}
+}
+
+get_results(resource, name) = results {
+	not common_lib.valid_key(resource, "settings")
+
+	results := {
+		"searchKey": sprintf("google_sql_database_instance[%s]", [name]),
+		"issueType": "MissingAttribute",
+		"keyExpectedValue": sprintf("'google_sql_database_instance[%s].settings.database_flags' should be defined and set 'cloudsql.enable_pgaudit' to 'on'", [name]),
+		"keyActualValue": sprintf("'google_sql_database_instance[%s].settings' is undefined or null", [name]),
+		"searchLine": common_lib.build_search_line(["resource", "google_sql_database_instance", name], [])
+
+	}
+} else = results {
+	not common_lib.valid_key(resource.settings, "database_flags")
+
+	results := {
+		"searchKey": sprintf("google_sql_database_instance[%s].settings", [name]),
+		"issueType": "MissingAttribute",
+		"keyExpectedValue": sprintf("'google_sql_database_instance[%s].settings.database_flags' should be defined and set 'cloudsql.enable_pgaudit' to 'on'", [name]),
+		"keyActualValue": sprintf("'google_sql_database_instance[%s].settings.database_flags' is undefined or null", [name]),
+		"searchLine": common_lib.build_search_line(["resource", "google_sql_database_instance", name, "settings"], [])
+	}
+
+} else = results {
+	not has_flag(resource.settings.database_flags)
+
+	results := {
+		"searchKey": sprintf("google_sql_database_instance[%s].settings.database_flags", [name]),
+		"issueType": "MissingAttribute",
+		"keyExpectedValue": sprintf("'google_sql_database_instance[%s].settings.database_flags' should set 'cloudsql.enable_pgaudit' to 'on'", [name]),
+		"keyActualValue": sprintf("'google_sql_database_instance[%s].settings.database_flags' does not set 'cloudsql.enable_pgaudit'", [name]),
+		"searchLine": common_lib.build_search_line(["resource", "google_sql_database_instance", name, "settings", "database_flags"], [])
+	}
+
+} else = results { # array
+	resource.settings.database_flags[x].name  == "cloudsql.enable_pgaudit"
+	resource.settings.database_flags[x].value != "on"
+
+	results := {
+		"searchKey": sprintf("google_sql_database_instance[%s].settings.database_flags[%d].name", [name, x]),
+		"issueType": "IncorrectValue",
+		"keyExpectedValue": sprintf("'google_sql_database_instance[%s].settings.database_flags' should set 'cloudsql.enable_pgaudit' to 'on'", [name]),
+		"keyActualValue": sprintf("'google_sql_database_instance[%s].settings.database_flags' sets 'cloudsql.enable_pgaudit' to '%s'", [name, resource.settings.database_flags[x].value]),
+		"searchLine": common_lib.build_search_line(["resource", "google_sql_database_instance", name, "settings", "database_flags", x, "name"], [])
+	}
+} else = results { # single object
+	resource.settings.database_flags.name  == "cloudsql.enable_pgaudit"
+	resource.settings.database_flags.value != "on"
+
+	results := {
+		"searchKey": sprintf("google_sql_database_instance[%s].settings.database_flags.name", [name]),
+		"issueType": "IncorrectValue",
+		"keyExpectedValue": sprintf("'google_sql_database_instance[%s].settings.database_flags' should set 'cloudsql.enable_pgaudit' to 'on'", [name]),
+		"keyActualValue": sprintf("'google_sql_database_instance[%s].settings.database_flags' sets 'cloudsql.enable_pgaudit' to '%s'", [name, resource.settings.database_flags.value]),
+		"searchLine": common_lib.build_search_line(["resource", "google_sql_database_instance", name, "settings", "database_flags", "name"], [])
+	}
+}
+
+has_flag(database_flags) {
+	database_flags[_].name == "cloudsql.enable_pgaudit"
+} else {
+	database_flags.name == "cloudsql.enable_pgaudit"
+}

assets/queries/terraform/gcp/sql_db_instance_without_centralized_logging/test/negative.tf

@@ -0,0 +1,49 @@
+resource "google_sql_database_instance" "negative_1" {
+  name             = "main-instance"
+  database_version = "MYSQL_8_0"      # Is not a POSTGRES instance
+  region           = "us-central1"
+
+  settings {
+    tier = "db-f1-micro"
+  }
+}
+
+resource "google_sql_database_instance" "negative_2" {
+  name             = "mysql-instance-with-flag"
+  database_version = "POSTGRES_15"
+  region           = "us-central1"
+
+  settings {
+    tier = "db-f1-micro"
+
+    database_flags {
+      name = "sample_flag1"
+      value = "off"
+      }
+
+    database_flags {                                  # Has flag set to "on"
+      name = "cloudsql.enable_pgaudit"
+      value = "on"
+      }
+
+    database_flags {
+      name = "sample_flag2"
+      value = "off"
+      }
+  }
+}
+
+resource "google_sql_database_instance" "negative_3" {  # Single object support test
+  name             = "mysql-instance-with-flag"
+  database_version = "POSTGRES_15"
+  region           = "us-central1"
+
+  settings {
+    tier = "db-f1-micro"
+
+    database_flags {
+      name = "cloudsql.enable_pgaudit"
+      value = "on"
+      }   # Has flag set to "on"
+  }
+}

assets/queries/terraform/gcp/sql_db_instance_without_centralized_logging/test/positive.tf

@@ -0,0 +1,64 @@
+resource "google_sql_database_instance" "positive_1" {
+  name             = "mysql-instance-without-flag"
+  database_version = "POSTGRES_17"
+  region           = "us-central1"
+
+  # Missing 'settings' field
+}
+
+resource "google_sql_database_instance" "positive_2" {
+  name             = "postgres-instance-without-flag"
+  database_version = "POSTGRES_16"
+  region           = "us-central1"
+
+  settings {}  # Missing 'database_flags' field
+}
+
+resource "google_sql_database_instance" "positive_3" {
+  name             = "postgres-instance-without-flag"
+  database_version = "POSTGRES_15"
+  region           = "us-central1"
+
+  settings {
+    database_flags {
+      name = "sample_flag1"
+      value = "off"
+      } # Missing 'cloudsql.enable_pgaudit' flag
+  }
+}
+
+resource "google_sql_database_instance" "positive_4" {
+  name             = "postgres-instance-with-flag"
+  database_version = "POSTGRES_14"
+  region           = "us-central1"
+
+  settings {
+    database_flags {
+      name = "sample_flag1"
+      value = "off"
+      }
+
+    database_flags {                                  # Flag is not set to "on"
+      name = "cloudsql.enable_pgaudit"
+      value = "off"
+      }
+
+    database_flags {
+      name = "sample_flag2"
+      value = "off"
+      }
+  }
+}
+
+resource "google_sql_database_instance" "positive_5" { # Single object support test
+  name             = "postgres-instance-with-flag"
+  database_version = "POSTGRES_14"
+  region           = "us-central1"
+
+  settings {
+    database_flags {
+      name = "cloudsql.enable_pgaudit"
+      value = "off"
+      }  # Flag is not set to "on"
+  }
+}

assets/queries/terraform/gcp/sql_db_instance_without_centralized_logging/test/positive_expected_result.json

@@ -0,0 +1,27 @@
+[
+  {
+    "queryName": "Beta - SQL DB Instance Without Centralized Logging",
+    "severity": "LOW",
+    "line": 1
+  },
+  {
+    "queryName": "Beta - SQL DB Instance Without Centralized Logging",
+    "severity": "LOW",
+    "line": 14
+  },
+  {
+    "queryName": "Beta - SQL DB Instance Without Centralized Logging",
+    "severity": "LOW",
+    "line": 23
+  },
+  {
+    "queryName": "Beta - SQL DB Instance Without Centralized Logging",
+    "severity": "LOW",
+    "line": 42
+  },
+  {
+    "queryName": "Beta - SQL DB Instance Without Centralized Logging",
+    "severity": "LOW",
+    "line": 60
+  }
+]

assets/similarityID_transition/terraform_gcp.yaml

@@ -3,3 +3,7 @@ similarityIDChangeList:
       queryName: Beta - Google DNS Policy Logging Disabled
       observations: ""
       change: 2
+    - queryId: 245eb024-d08a-449b-a1f2-02f7bba00fc2
+      queryName: Beta - SQL DB Instance Without Centralized Logging
+      observations: ""
+      change: 2