protobuf.hexpat

#include <std/mem.pat>

#include <type/leb128.pat>

using Entry;

struct ZigZag32 {
	u32 value;
} [[sealed, format("format_zigzag32")]];

fn format_zigzag32(ZigZag32 zigzag) {
	return s32((s32(zigzag.value) << 1) ^ (s32(zigzag.value) >> 31));
};

struct ZigZag64 {
	u64 value;
} [[sealed, format("format_zigzag64")]];

fn format_zigzag64(ZigZag64 zigzag) {
	return s64((s64(zigzag.value) << 1) ^ (s64(zigzag.value) >> 63));
};

u32 currentPosition;

enum WireType : u8 {
	Varint 			= 0,
	_64Bit 			= 1,
	LengthDelimited = 2,
	_32Bit 			= 5
};

bitfield Key {
	field_number : 5;
	wire_type    : 3;
} [[left_to_right]];

union _64Bit {
	u64 fixed64;
	ZigZag64 sfixed64;
	double dbl;
};

union _32Bit {
	u32 fixed32;
	ZigZag32 sfixed32;
	float flt;
};

struct Entry {
	Key key;
	
	if (key.wire_type == WireType::Varint) {
		type::LEB128 value;
	} else if (key.wire_type == WireType::_64Bit) {
		_64Bit value;
    } else if (key.wire_type == WireType::LengthDelimited) {
		type::LEB128 length;
		
		u8 raw_data[length] [[no_unique_address]];
	
		if (std::mem::read_unsigned($, 1) & 7 == 0) {
			Entry subentries[while($ < addressof(raw_data) + length)];
		} else if (std::mem::read_unsigned($, 1) & 7 == 1 && length >= 8) {
			Entry subentries[while($ < addressof(raw_data) + length)];
		} else if (std::mem::read_unsigned($, 1) & 7 == 2 && std::mem::read_unsigned($ + 1, 1) <= length) {
			Entry subentries[while($ < addressof(raw_data) + length)];
		} else if (std::mem::read_unsigned($, 1) & 7 == 5 && length >= 4) {
			Entry subentries[while($ < addressof(raw_data) + length)];
		} else {
			char data[length];
		}
    } else if (key.wire_type == WireType::_32Bit) {
		_32Bit value;
    }
};

struct Protobuf {
    Entry entries[while(!std::mem::eof())];
};

Protobuf protobuf @ 0x00;