build.gradle

plugins {
  id 'me.champeau.jmh'
}

description = 'dd-trace-core'

apply from: "$rootDir/gradle/java.gradle"
apply from: "$rootDir/gradle/version.gradle"

minimumBranchCoverage = 0.5
minimumInstructionCoverage = 0.6
excludedClassesCoverage += [
  'datadog.trace.civisibility.interceptor.CiVisibilityTelemetryInterceptor',
  'datadog.trace.civisibility.writer.ddintake.CiTestCovMapperV2.PayloadV2',
  'datadog.trace.common.writer.ddintake.DDIntakeMapperDiscovery',
  'datadog.trace.common.writer.ListWriter',
  'datadog.trace.common.writer.DDAgentWriter.DDAgentWriterBuilder',
  'datadog.trace.common.sampling.PrioritySampling',
  'datadog.trace.core.scopemanager.ScopeInterceptor.DelegatingScope',
  'datadog.trace.common.writer.RemoteMapper.NoopRemoteMapper',
  'datadog.trace.core.monitor.DDAgentStatsDConnection',
  'datadog.trace.core.monitor.LoggingStatsDClient',
  'datadog.trace.core.PendingTraceBuffer.DelayingPendingTraceBuffer.CommandElement',
  'datadog.trace.core.StatusLogger',
  // covered with CI Visibility smoke tests
  'datadog.trace.core.StreamingTraceCollector',
  // covered with CI Visibility smoke tests
  'datadog.trace.core.StreamingTraceCollector.Factory',
  'datadog.trace.core.scopemanager.ContinuableScopeManager.ScopeStackThreadLocal',
  'datadog.trace.core.scopemanager.SingleContinuation',
  // FIXME: more test coverage needed
  'datadog.trace.core.CoreTracer',
  'datadog.trace.core.CoreTracer.1',
  'datadog.trace.core.DDSpan.1',
  'datadog.trace.core.tagprocessor.QueryObfuscator.1',
  'datadog.trace.common.writer.TraceProcessingWorker.NonDaemonTraceSerializingHandler',
  // Interface with an empty defender method
  'datadog.trace.core.propagation.HttpCodec.Extractor',
  'datadog.trace.core.flare.*',
  // FIXME(DSM): test coverage needed
  'datadog.trace.core.datastreams.DataStreamContextInjector',
  'datadog.trace.common.sampling.TraceSamplingRules.RuleAdapter',
  'datadog.trace.common.sampling.SpanSamplingRules.RuleAdapter',
  'datadog.trace.core.TracingConfigPoller.SamplingRuleTagEntry',
  'datadog.trace.core.TracingConfigPoller.TracingSamplingRule',
  'datadog.trace.core.TracingConfigPoller.TracingSamplingRules',
  'datadog.trace.core.TracingConfigPoller.TracingSamplingRulesAdapter',
  'datadog.trace.core.TracingConfigPoller.Updater',
  // covered with dd-trace-core/src/test/groovy/datadog/trace/core/datastreams/CheckpointerTest.groovy
  'datadog.trace.core.datastreams.DefaultDataStreamsMonitoring',
  // TODO CorePropagation will be removed during context refactoring
  'datadog.trace.core.propagation.CorePropagation',
  // TODO DSM propagator will be tested once fully migrated
  'datadog.trace.core.datastreams.DataStreamPropagator'
]

addTestSuite('traceAgentTest')

tasks.withType(Test).findByName('forkedTest').configure {
  // Needed for FootprintForkedTest on Java 17
  jvmArgs += ['-Djol.magicFieldOffset=true']
}

dependencies {
  api project(':dd-trace-api')
  api project(':communication')
  api project(':internal-api')
  implementation project(':components:json')
  implementation project(':utils:container-utils')
  implementation project(':utils:socket-utils')
  // for span exception debugging
  compileOnly project(':dd-java-agent:agent-debugger:debugger-bootstrap')

  implementation libs.slf4j
  implementation libs.moshi
  implementation libs.jctools

  implementation group: 'com.datadoghq', name: 'sketches-java', version: '0.8.3'

  implementation group: 'com.google.re2j', name: 're2j', version: '1.7'

  compileOnly group: 'com.github.spotbugs', name: 'spotbugs-annotations', version: '4.2.0'

  // We have autoservices defined in test subtree, looks like we need this to be able to properly rebuild this
  testAnnotationProcessor libs.autoservice.processor
  testCompileOnly libs.autoservice.annotation

  testImplementation project(':dd-java-agent:testing')
  testImplementation project(':remote-config:remote-config-core')
  testImplementation group: 'org.msgpack', name: 'msgpack-core', version: '0.8.20'
  testImplementation group: 'org.msgpack', name: 'jackson-dataformat-msgpack', version: '0.8.20'
  testImplementation group: 'org.openjdk.jol', name: 'jol-core', version: '0.16'
  testImplementation group: 'commons-codec', name: 'commons-codec', version: '1.3'
  testImplementation group: 'com.amazonaws', name: 'aws-lambda-java-events', version:'3.11.0'
  testImplementation group: 'com.google.protobuf', name: 'protobuf-java', version: '3.14.0'
  testImplementation libs.testcontainers

  traceAgentTestImplementation libs.testcontainers
}

jmh {
  jmhVersion = '1.28'
  duplicateClassesStrategy = DuplicatesStrategy.EXCLUDE
}