build.gradle

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.3.1'

        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.7.3'

        classpath 'com.github.dcendents:android-maven-gradle-plugin:1.5'

        classpath "com.neenbedankt.gradle.plugins:android-apt:1.8"

        classpath "me.tatarka:gradle-retrolambda:3.4.0"

        classpath "com.jakewharton:butterknife-gradle-plugin:8.4.0"

        classpath 'com.squareup.sqldelight:gradle-plugin:0.6.1'
    }
}

ext {
    projectVersion = '0.0.0.8'
    libraryName = 'geofence-manager'
    projectVersionCode = 1;
}

apply plugin: 'com.android.library'
apply plugin: 'com.jakewharton.butterknife'
apply plugin: 'android-apt'
apply plugin: 'me.tatarka.retrolambda'
apply plugin: 'com.squareup.sqldelight'
apply plugin: 'com.github.dcendents.android-maven'

apply from: new File('bintray.gradle')

android {
    compileSdkVersion 25
    buildToolsVersion "25.0.1"
    defaultConfig {
        minSdkVersion 21
        targetSdkVersion 25
        versionCode projectVersionCode
        versionName projectVersion
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
}

// Used by dcendents.android-maven to set the artifact id for maven
group = 'com.hgyllensvard'
version = projectVersion
project.archivesBaseName = libraryName


def googleServicesVersion = '10.2.1'
def dagger2Version = '2.8'
def butterKnife = '8.4.0'
def fragmentArgs = '3.0.2'
def autoValue = '1.2'

dependencies {

    // Play Services
    compile "com.google.android.gms:play-services-maps:$googleServicesVersion"
    compile "com.google.android.gms:play-services-location:$googleServicesVersion"
    compile "com.google.android.gms:play-services-gcm:$googleServicesVersion"

    // Constraint layout
    compile 'com.android.support.constraint:constraint-layout:1.0.2'

    // Google support libraries
    compile 'com.android.support:appcompat-v7:25.3.1'

    // Dependency Injection
    compile "com.google.dagger:dagger:$dagger2Version"
    apt "com.google.dagger:dagger-compiler:$dagger2Version"

    // View and resource binding
    compile "com.jakewharton:butterknife:$butterKnife"
    apt "com.jakewharton:butterknife-compiler:$butterKnife"

    // Auto Value
    compile "com.google.auto.value:auto-value:$autoValue"
    apt "com.google.auto.value:auto-value:$autoValue"

    /** Reactive libraries */

    // Reactive programming
    compile "io.reactivex.rxjava2:rxjava:2.0.4"
    compile "io.reactivex.rxjava2:rxandroid:2.0.1"

    // Reactive Android views
    compile 'com.jakewharton.rxbinding:rxbinding:1.0.0'

    // Temporary library to convert between Rx1 and Rx2
    compile "com.github.akarnokd:rxjava2-interop:0.7.2"

    // Reactive wrapper around Android's permission system
    compile 'com.tbruyelle.rxpermissions2:rxpermissions:0.8.2@aar'

    //Reactive database
    compile 'com.squareup.sqlbrite:sqlbrite:1.1.1'

    /** End reactive libraries */

    // Sending arguments to fragments
    compile "com.hannesdorfmann.fragmentargs:annotation:$fragmentArgs"
    apt "com.hannesdorfmann.fragmentargs:processor:$fragmentArgs"

    // Logging helper
    compile 'com.jakewharton.timber:timber:4.4.0'

    // Floating action bar library
    compile 'com.github.clans:fab:1.6.4'

    /**
     * Unit Tests
     */

    testApt "com.google.dagger:dagger-compiler:$dagger2Version"
    testCompile "com.google.dagger:dagger-compiler:$dagger2Version"

    // Allows unit testing Android parts.
    testCompile "org.robolectric:robolectric:3.1.4"

    // Improved assertions in tests
    testCompile 'org.assertj:assertj-core:3.6.1'

    // Mocking library
    testCompile "org.mockito:mockito-core:2.2.0"
    testCompile 'junit:junit:4.12'

    /**
     * Instrumentation Tests
     */

    androidTestApt "com.google.dagger:dagger-compiler:$dagger2Version"
    androidTestCompile "com.google.dagger:dagger-compiler:$dagger2Version"

    androidTestCompile('com.android.support.test.espresso:espresso-core:2.2.2', {
        exclude group: 'com.android.support', module: 'support-annotations'
    })
}

allprojects {
    repositories {
        jcenter()
    }
}