scripts: Fix PccDiscovery for plain PATH resolution

Author: MathiasMagnus

cmake/Modules/VulkanSCPccDiscovery.cmake

@@ -12,6 +12,26 @@ find_program(VulkanSC_PCCTOOL_EXECUTABLE
         "$ENV{VULKANSC_SDK}/bin"
 )
 
+function(resolve_vksc_pcc_executable PCC_EXECUTABLE PCC_JSON_PATH OUT_VAR)
+    if(WIN32)
+        set(NATIVE_PATH_SEPARATOR_REGEX [[\\]])
+    else()
+        set(NATIVE_PATH_SEPARATOR_REGEX [[/]])
+    endif()
+    if(NOT PCC_EXECUTABLE MATCHES ${NATIVE_PATH_SEPARATOR_REGEX})
+        separate_arguments(PCC_EXECUTABLE NATIVE_COMMAND PROGRAM "${PCC_EXECUTABLE}")
+    else()
+        cmake_path(IS_RELATIVE PCC_EXECUTABLE PCC_EXECUTABLE_IS_RELATIVE)
+        if(PCC_EXECUTABLE_IS_RELATIVE)
+            cmake_path(GET PCC_JSON_PATH PARENT_PATH PCC_JSON_PARENT_PATH)
+            cmake_path(ABSOLUTE_PATH PCC_EXECUTABLE BASE_DIRECTORY "${PCC_JSON_PARENT_PATH}" NORMALIZE)
+        else()
+            cmake_path(NORMAL_PATH PCC_EXECUTABLE)
+        endif()
+    endif()
+    set(${OUT_VAR} "${PCC_EXECUTABLE}" PARENT_SCOPE)
+endfunction()
+
 # If a PCC executable is set manually then do not perform the PCC discovery
 if(NOT "${VulkanSC_PCC_EXECUTABLE}")
     if(WIN32)
@@ -22,9 +42,12 @@ if(NOT "${VulkanSC_PCC_EXECUTABLE}")
                     RESULT PCC_PROP_NAMES
                     QUERY WINDOWS_REGISTRY "${HIVE}/SOFTWARE/Khronos/VulkanSC/PCC" VALUE_NAMES
                 )
-                if(PCC_PROP_NAMES)
-                    list(APPEND PCC_JSON_PATHS "${PCC_PROP_NAMES}")
-                endif()
+                foreach(PCC_PROP_NAME IN LISTS PCC_PROP_NAMES)
+                    file(REAL_PATH "${PCC_PROP_NAME}" PCC_PROP_NAME)
+                    if(NOT PCC_PROP_NAME IN_LIST PCC_JSON_PATHS)
+                        list(APPEND PCC_JSON_PATHS "${PCC_PROP_NAME}")
+                    endif()
+                endforeach()
             endforeach()
         else()
             message(FATAL_ERROR "PCC (pipeline cache compiler) discovery on Windows requires CMake 3.24 or newer")
@@ -42,9 +65,12 @@ if(NOT "${VulkanSC_PCC_EXECUTABLE}")
             /etc/xdg/vulkansc/pcc.d
         )
             file(GLOB PCC_GLOBBED_PATHS "${MANIFEST_DIR}/*.json")
-            if(PCC_GLOBBED_PATHS)
-                list(APPEND PCC_JSON_PATHS "${PCC_GLOBBED_PATHS}")
-            endif()
+            foreach(PCC_GLOBBED_PATH IN LISTS PCC_GLOBBED_PATHS)
+                file(REAL_PATH "${PCC_GLOBBED_PATH}" PCC_GLOBBED_PATH)
+                if(NOT PCC_GLOBBED_PATH IN_LIST PCC_JSON_PATHS)
+                    list(APPEND PCC_JSON_PATHS "${PCC_GLOBBED_PATH}")
+                endif()
+            endforeach()
         endforeach()
     endif()
     foreach(PCC_JSON_PATH IN LISTS PCC_JSON_PATHS)
@@ -59,13 +85,9 @@ if(NOT "${VulkanSC_PCC_EXECUTABLE}")
             foreach(ARCH_INDEX RANGE ${ARCH_LENGTH_STOP})
                 string(JSON ARCH_NAME MEMBER "${PCC_JSON}" "architectures" ${ARCH_INDEX})
                 string(JSON PCC_EXECUTABLE GET "${PCC_JSON}" "architectures" ${ARCH_NAME} "pipeline_cache_compiler")
-                cmake_path(IS_RELATIVE PCC_EXECUTABLE PCC_EXECUTABLE_IS_RELATIVE)
-                if(PCC_EXECUTABLE_IS_RELATIVE)
-                    cmake_path(GET PCC_JSON_PATH PARENT_PATH PCC_JSON_PARENT_PATH)
-                    cmake_path(ABSOLUTE_PATH PCC_EXECUTABLE BASE_DIRECTORY "${PCC_JSON_PARENT_PATH}" NORMALIZE)
-                else()
-                    cmake_path(NORMAL_PATH PCC_EXECUTABLE)
-                endif()
+                message(DEBUG "PCC entry: ${PCC_EXECUTABLE}")
+                resolve_vksc_pcc_executable("${PCC_EXECUTABLE}" "${PCC_JSON_PATH}" PCC_EXECUTABLE)
+                message(DEBUG "PCC resolved: ${PCC_EXECUTABLE}")
                 string(JSON FLAGS GET "${PCC_JSON}" "architectures" ${ARCH_NAME} "pipeline_cache_flags")
                 string(JSON DEBUG_FLAG GET "${PCC_JSON}" "architectures" ${ARCH_NAME} "pipeline_cache_debug_flag")
                 string(JSON VENDOR_ID_FILTER ERROR_VARIABLE VENDOR_ID_FILTER_ERROR GET "${PCC_JSON}" "architectures" ${ARCH_NAME} "vendor_id_filter")
@@ -129,13 +151,9 @@ if(NOT "${VulkanSC_PCC_EXECUTABLE}")
                         set(DEVICE_ID "${CMAKE_MATCH_1}")
                         set(DEVICE_NAME "${CMAKE_MATCH_2}")
                         string(JSON PCC_EXECUTABLE GET "${PCC_JSON}" "devices" ${DEV_INDEX} "pipeline_cache_compiler")
-                        cmake_path(IS_RELATIVE PCC_EXECUTABLE PCC_EXECUTABLE_IS_RELATIVE)
-                        if(PCC_EXECUTABLE_IS_RELATIVE)
-                            cmake_path(GET PCC_JSON_PATH PARENT_PATH PCC_JSON_PARENT_PATH)
-                            cmake_path(ABSOLUTE_PATH PCC_EXECUTABLE BASE_DIRECTORY "${PCC_JSON_PARENT_PATH}" NORMALIZE)
-                        else()
-                            cmake_path(NORMAL_PATH PCC_EXECUTABLE)
-                        endif()
+                        message(DEBUG "PCC entry: ${PCC_EXECUTABLE}")
+                        resolve_vksc_pcc_executable("${PCC_EXECUTABLE}" "${PCC_JSON_PATH}" PCC_EXECUTABLE)
+                        message(DEBUG "PCC resolved to: ${PCC_EXECUTABLE}")
                         string(JSON DEVICE_FLAG GET "${PCC_JSON}" "devices" ${DEV_INDEX} "pipeline_cache_device_flag")
                         string(JSON DEBUG_FLAG GET "${PCC_JSON}" "devices" ${DEV_INDEX} "pipeline_cache_debug_flag")