build.gradle

plugins {
	id 'fabric-loom' version '1.7-SNAPSHOT'
	id 'maven-publish'
	id 'scala'
	id 'io.github.cosmicsilence.scalafix' version '0.2.2'
	id 'org.cadixdev.licenser' version '0.6.1'
}

version = project.mod_version
group = project.maven_group

base {
	archivesName = project.archives_base_name
}

repositories {
	mavenCentral()
	mavenLocal()
	// Add repositories to retrieve artifacts from in here.
	// You should only use this when depending on other mods because
	// Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
	// See https://docs.gradle.org/current/userguide/declaring_repositories.html
	// for more information about repositories.
    maven {
        name = 'Ladysnake Mods'
        url = 'https://maven.ladysnake.org/releases'
    }
	maven {
		name "DragonPlus"
        url = "https://maven.dragons.plus/releases"
	}
	maven {
    	name = "Terraformers"
    	url = "https://maven.terraformersmc.com/"
  	}
}

license {
    header = project.file('LICENSE')
	include '**/*.scala'
}

loom {
	splitEnvironmentSourceSets()
	accessWidenerPath = file("src/main/resources/are.accesswidener")
	mods {
		"are" {
			sourceSet sourceSets.main
			sourceSet sourceSets.client
		}
	}
}

fabricApi {
	configureDataGeneration()
}

dependencies {
	// To change the versions see the gradle.properties file
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

	// Mod Menu
  	modImplementation "com.terraformersmc:modmenu:${project.modmenu_version}"

	// Fabric API. This is technically optional, but you probably want it anyway.
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

	// Fabric Language Scala
	// modImplementation "maven.modrinth:krysztal-language-scala:${project.kls_version}+scala.${project.scala_version}"
	modImplementation "dev.krysztal:krysztal-language-scala:${project.kls_version}+scala.${project.scala_version}"

	// Cardinal Components API
	modApi "org.ladysnake.cardinal-components-api:cardinal-components-base:${cca_version}"
	modImplementation "org.ladysnake.cardinal-components-api:cardinal-components-world:${cca_version}"
	modImplementation "org.ladysnake.cardinal-components-api:cardinal-components-chunk:${cca_version}"
}

processResources {
	inputs.property "version", project.version

	filesMatching("fabric.mod.json") {
		expand "version": project.version
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.release = 21
}

tasks.withType(ScalaCompile) {
    it.targetCompatibility = 21
	scalaCompileOptions.additionalParameters = [
		"-Wunused:imports"
	]
}

tasks.withType(ScalaDoc) {
	scalaDocOptions.additionalParameters = [
		"-author"
	]
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()

	sourceCompatibility = JavaVersion.VERSION_21
	targetCompatibility = JavaVersion.VERSION_21
}

scalafix {
	excludes = ["**/generated/**"]
}

jar {
	from("LICENSE") {
		rename { "${it}_${project.base.archivesName.get()}"}
	}
}

// configure the maven publication
publishing {
	publications {
		create("mavenJava", MavenPublication) {
			artifactId = project.archives_base_name
			from components.java
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	repositories {
		// Add repositories to publish to here.
		// Notice: This block does NOT have the same function as the block in the top level.
		// The repositories here will be used for publishing your artifact, not for
		// retrieving dependencies.
	}
}