MinecraftMavenizer/settings.gradle at master · MinecraftForge/MinecraftMavenizer · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
plugins {
    id 'org.gradle.toolchains.foojay-resolver-convention' version '1.0.0'
}

rootProject.name = 'minecraft-mavenizer'

// Applying plugins causes them to not have any IDE support when also applied to any build.gradle files
// The workaround for now is to use this listener here so that it can stay in settings.gradle
// See: https://youtrack.jetbrains.com/issue/IDEA-332061/Gradle-Missing-Code-Completion-Suggestions-for-Settings-Plugins-in-Groovy-DSL
gradle.beforeProject { Project project ->
    project.pluginManager.withPlugin('net.minecraftforge.gradleutils') {
        project.repositories {
            mavenCentral()
            maven project.gradleutils.forgeMaven
            mavenLocal()
        }
    }
}

//formatter:off
dependencyResolutionManagement.versionCatalogs.register('libs') {
    plugin 'licenser',    'net.minecraftforge.licenser'    version '1.2.0'
    plugin 'gradleutils', 'net.minecraftforge.gradleutils' version '3.3.21'
    plugin 'gitversion',  'net.minecraftforge.gitversion'  version '3.1.6'
    plugin 'changelog',   'net.minecraftforge.changelog'   version '3.1.3'
    plugin 'shadow',      'com.gradleup.shadow'            version '9.2.2'

    // Static Analysis
    library 'nulls', 'org.jetbrains', 'annotations' version '26.0.2-1'

    library 'gson',     'com.google.code.gson', 'gson'             version '2.10.1'
    library 'jopt',     'net.sf.jopt-simple',   'jopt-simple'      version '6.0-alpha-3'
    library 'jver',     'net.minecraftforge',   'java-provisioner' version '2.0.4'
    library 'srgutils', 'net.minecraftforge',   'srgutils'         version '0.6.3'
    library 'diff',     'io.codechicken',       'DiffPatch'        version '2.0.0.36' // Fuzzy patching

    library 'fastcsv',   'de.siegmar', 'fastcsv'    version '3.4.0'
    library 'commonsio', 'commons-io', 'commons-io' version '2.18.0'

    // Utilities
    library 'utils-download', 'net.minecraftforge', 'download-utils'  version '0.4.0'
    library 'utils-files',    'net.minecraftforge', 'file-utils'      version '0.3.3'
    library 'utils-hash',     'net.minecraftforge', 'hash-utils'      version '0.2.2'
    library 'utils-data',     'net.minecraftforge', 'json-data-utils' version '0.4.3'
    library 'utils-logging',  'net.minecraftforge', 'log-utils'       version '0.5.1'
    library 'utils-os',       'net.minecraftforge', 'os-utils'        version '0.1.0'
    bundle 'utils', ['utils-download', 'utils-files', 'utils-hash', 'utils-data', 'utils-logging', 'utils-os']
}

dependencyResolutionManagement.versionCatalogs.register('testLibs') {
    description = 'Dependencies used exclusively for testing or test projects.'

    version 'junit', '5.10.2'
    library 'junit-api',               'org.junit.jupiter',  'junit-jupiter-api'       versionRef 'junit'
    library 'junit-engine',            'org.junit.jupiter',  'junit-jupiter-engine'    versionRef 'junit'
    library 'junit-platform-launcher', 'org.junit.platform', 'junit-platform-launcher' version    '1.10.2'
    bundle 'junit-runtime', ['junit-engine', 'junit-platform-launcher']
}
//formatter:on