SrgUtils/build.gradle at master · MinecraftForge/SrgUtils · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94

plugins {
    id 'java'
    id 'idea'
    id 'eclipse'
    id 'maven-publish'
    alias libs.plugins.licenser
    alias libs.plugins.gradleutils
    alias libs.plugins.versions
}

final projectDisplayName = 'SRG Utils'
final projectArtifactId = base.archivesName = 'srgutils'
final projectVendor = 'Forge Development LLC'
description = 'Library for managing java obfuscation mappings in various formats.'
group = 'net.minecraftforge'
version = gitversion.tagOffset

println "Version: $version"

java {
    toolchain.languageVersion = JavaLanguageVersion.of(8)

    withSourcesJar()
}

dependencies {
    //region Static Analysis
    compileOnly libs.nulls
    compileOnly libs.jsr305
    //endregion

    //region Testing
    testImplementation libs.junit.api
    testRuntimeOnly libs.bundles.junit.runtime
    testImplementation libs.powermock
    //endregion
}

test {
    useJUnitPlatform()
}

changelog {
    from '0.4'
}

license {
    header = rootProject.file('LICENSE-header.txt')
    newLine = false
    exclude '**/*.properties'
}

tasks.named('jar', Jar) {
    manifest {
        attributes([
            'Automatic-Module-Name': 'net.minecraftforge.srgutils'
        ])
        attributes([
            'Specification-Title'   : projectDisplayName,
            'Specification-Vendor'  : projectVendor,
            'Specification-Version' : gitversion.info.tag,
            'Implementation-Title'  : projectDisplayName,
            'Implementation-Vendor' : projectVendor,
            'Implementation-Version': project.version
        ], 'net/minecraftforge/srgutils')
    }
}

publishing {
    repositories {
        maven gradleutils.publishingForgeMaven
    }

    publications.register('mavenJava', MavenPublication) {
        from components.java

        artifactId = 'srgutils'

        pom {
            name = 'SRG Utils'
            description = 'Library for managing java obfuscation mappings in various formats.'
            url = 'https://github.com/MinecraftForge/SrgUtils'

            gradleutils.pom.setGitHubDetails(pom, 'SrgUtils')

            license gradleutils.pom.licenses.LGPLv2_1

            developers {
                developer gradleutils.pom.developers.LexManos
            }
        }
    }
}