zuul/zuul-integration-test/build.gradle at 4089d0aa1cc0a5ff7af2443a3aa5729b4dd5a6cc · Netflix/zuul · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
import com.netflix.zuul.build.SslFixtureGenerator

apply plugin: "java"
apply plugin: 'application'

def generatedSslResourcesDir = layout.buildDirectory.dir("generated/resources/dev-ssl")

tasks.register("generateIntegrationTestSslFixtures") {
    description = "Generates short-lived SSL fixtures for integration tests."
    outputs.dir(generatedSslResourcesDir)
    outputs.upToDateWhen { false }

    doLast {
        SslFixtureGenerator.generate(generatedSslResourcesDir.get().asFile.toPath())
    }
}

sourceSets {
    test {
        resources.srcDir(tasks.named("generateIntegrationTestSslFixtures"))
    }
}

tasks.named("processTestResources") {
    dependsOn(tasks.named("generateIntegrationTestSslFixtures"))
}

dependencies {
    implementation project(":zuul-core"),
            project(":zuul-discovery")

    implementation "io.netty:netty-transport-classes-epoll"
    implementation "com.netflix.eureka:eureka-client:2.0.4"
    implementation "com.netflix.ribbon:ribbon-eureka:$versions_ribbon"
    implementation "com.netflix.ribbon:ribbon-loadbalancer:$versions_ribbon"
    implementation 'commons-configuration:commons-configuration:1.10'
    annotationProcessor project(":zuul-processor")

    testImplementation 'org.wiremock:wiremock:3.10.0'
    testImplementation 'javax.servlet:javax.servlet-api:4.0.1'
    testImplementation libraries.assertj, libraries.jupiterApi, libraries.jupiterParams, libraries.jupiterEngine, libraries.junitPlatformLauncher, libraries.jupiterMockito, libraries.okhttp
    testImplementation "io.netty:netty-transport-native-io_uring"
//    testImplementation "io.netty.incubator:netty-transport-native-io_uring::linux-x86_64"
    testImplementation "org.slf4j:slf4j-api:2.0.16"
    testImplementation 'org.apache.commons:commons-lang3:3.18.0'
    testImplementation "com.aayushatharva.brotli4j:brotli4j:$versions_brotli4j"
    testRuntimeOnly 'org.apache.logging.log4j:log4j-core:2.25.2'
    testRuntimeOnly 'org.apache.logging.log4j:log4j-slf4j2-impl:2.25.2'
    testRuntimeOnly "com.aayushatharva.brotli4j:native-osx-aarch64:$versions_brotli4j"
    testRuntimeOnly "com.aayushatharva.brotli4j:native-osx-x86_64:$versions_brotli4j"
    testRuntimeOnly "com.aayushatharva.brotli4j:native-linux-x86_64:$versions_brotli4j"
    testRuntimeOnly "com.aayushatharva.brotli4j:native-linux-aarch64:$versions_brotli4j"
    testRuntimeOnly "io.netty:netty-transport-native-epoll::linux-x86_64"
}

tasks.withType(Test).all {
    systemProperty("io.netty.leakDetection.level", "paranoid")
}

tasks.withType(PublishToMavenRepository) {
    onlyIf { false }
}

tasks.withType(PublishToMavenLocal) {
    onlyIf { false }
}

tasks.withType(PublishToIvyRepository) {
    onlyIf { false }
}