registration.gradle

tasks.register('consulRegistration', Exec) {
    group = 'consul'
    description = 'Registers the service in Consul'
    workingDir = file('consul')
    commandLine 'node', 'registration.js', '-c', 'register', '-f', 'config.json'
}

tasks.register('consulDeregistration', Exec) {
    group = 'consul'
    description = 'Deregisters the service from Consul'
    workingDir = file('consul')
    commandLine 'node', 'registration.js', '-c', 'deregister', '-f', 'config.json'
}

tasks.register('copyRegistrationToConsulBuild', Copy) {
    from 'consul'
    into 'build/consul'
    include 'package.json', 'registration.js', 'config.json'
}

tasks.register('copyRamlToConsulBuild', Copy) {
    from 'src/main/resources'
    into 'build/consul'
    include 'api-definition.yaml'
}

tasks.register('copyRamlSchemasToConsulBuild', Copy) {
    from 'src/main/resources/schemas'
    into 'build/consul/schemas'
}

tasks.register('prepareConsulBuild') {
    group = 'build'
    description = 'Prepares all Consul configuration files for the Docker build'
    dependsOn 'copyRegistrationToConsulBuild'
    dependsOn 'copyRamlSchemasToConsulBuild'
    dependsOn 'copyRamlToConsulBuild'
}