build.gradle

import org.jetbrains.kotlin.gradle.dsl.JvmTarget
import com.android.build.gradle.internal.res.LinkApplicationAndroidResourcesTask
import org.jetbrains.dokka.gradle.DokkaTask
import java.net.URL

buildscript {
    repositories {
        mavenCentral()
        maven { url 'https://s01.oss.sonatype.org' }
        gradlePluginPortal()
        mavenLocal()
        google()
        maven { url 'https://oss.sonatype.org/content/repositories/snapshots/' }
        maven { url 'https://s01.oss.sonatype.org/content/repositories/snapshots/' }
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:8.7.3'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
    }
}

plugins {
    id "org.jetbrains.dokka" version "2.0.0"
}

allprojects {
    apply plugin: 'eclipse'
    apply plugin: 'idea'

    repositories {
        mavenCentral()
        google()
    }

    // This allows you to "Build and run using IntelliJ IDEA", an option in IDEA's Settings.
    idea {
        module {
            outputDir file('build/classes/java/main')
            testOutputDir file('build/classes/java/test')
        }
    }
}

configure(subprojects/* - project(':android')*/) {
    apply plugin: 'java-library'
    apply plugin: 'kotlin'
    sourceCompatibility = 11
    targetCompatibility = 11

    // From https://lyze.dev/2021/04/29/libGDX-Internal-Assets-List/
    // The article can be helpful when using assets.txt in your project.
    tasks.register('generateAssetList') {
        inputs.dir("${project.rootDir}/assets/")
        // projectFolder/assets
        File assetsFolder = new File("${project.rootDir}/assets/")
        // projectFolder/assets/assets.txt
        File assetsFile = new File(assetsFolder, "assets.txt")
        // delete that file in case we've already created it
        assetsFile.delete()

        // iterate through all files inside that folder
        // convert it to a relative path
        // and append it to the file assets.txt
        fileTree(assetsFolder).collect { assetsFolder.relativePath(it) }.sort().each {
            if ("node_modules" == it) return
            if (it.endsWith(".lock")) return
            if (it.endsWith(".DS_Store")) return
            if (it.startsWith("._")) return
            assetsFile.append(it + "\n")
        }
    }
    processResources.dependsOn 'generateAssetList'

    compileJava {
        options.incremental = true
    }
    compileKotlin.compilerOptions.jvmTarget.set(JvmTarget.JVM_11)
    compileTestKotlin.compilerOptions.jvmTarget.set(JvmTarget.JVM_11)

}

subprojects {
    apply plugin: 'org.jetbrains.dokka'

    version = projectVersion + (snapshot == "true" ? "-SNAPSHOT" : "")
    ext.appName = 'QuantumVoxel'

    group = 'dev.ultreon.quantum'

    base {
        archivesName = "quantum-${project.name}-v2"
    }

    repositories {
        maven { url 'https://jitpack.io' }
        mavenCentral()
        maven { url 'https://s01.oss.sonatype.org' }
        // You may want to remove the following line if you have errors downloading dependencies.
        mavenLocal()
        maven { url 'https://maven.fabricmc.net/' }
        maven { url 'https://teavm.org/maven/repository/' }
        maven { url 'https://oss.sonatype.org/content/repositories/snapshots/' }
        maven { url 'https://oss.sonatype.org/content/repositories/releases/' }
        maven { url 'https://s01.oss.sonatype.org/content/repositories/snapshots/' }
        maven { url 'https://s01.oss.sonatype.org/content/repositories/releases/' }

        maven {
            url = uri("https://maven.pkg.github.com/Ultreon/scriptic-lang")
            credentials {
                username = project.findProperty("gpr.user") ?: System.getenv("USERNAME")
                password = project.findProperty("gpr.key") ?: System.getenv("TOKEN")
            }
        }
    }

    java {
        withSourcesJar()
    }

    tasks.register("javadocJar", Jar) {
        dependsOn tasks.dokkaJavadoc

        archiveClassifier.set("javadoc")
        from tasks.dokkaJavadoc

        tasks.jar.finalizedBy(it)

        tasks.assemble.dependsOn(it)
    }

    dokkaJavadoc {
        outputDirectory.set(file("$buildDir/docs/javadoc"))
    }

    artifacts {
        archives sourcesJar
        archives javadocJar
    }
}

eclipse.project.name = 'QuantumVoxel' + '-parent'

// Configure dokka to include the client and server source sets
tasks.withType(DokkaTask) {
    moduleName.set("Quantum Voxel")

    dokkaSourceSets {
        configureEach {
            classpath.from(subprojects.collect { it.sourceSets.main.compileClasspath })
            includeNonPublic.set(true)
            skipEmptyPackages.set(true)

            externalDocumentationLink {
                url.set(uri("https://docs.oracle.com/en/java/javase/17/docs/api/").toURL())
                packageListUrl.set(uri("https://docs.oracle.com/en/java/javase/17/docs/api/package-list").toURL())
            }

            externalDocumentationLink {
                url.set(uri("https://javadoc.io/doc/org.lwjgl/lwjgl").toURL())
                packageListUrl.set(uri("https://javadoc.io/doc/org.lwjgl/lwjgl/package-list").toURL())
            }

            externalDocumentationLink {
                url.set(uri("https://javadoc.io/doc/org.lwjgl/lwjgl.glfw").toURL())
                packageListUrl.set(uri("https://javadoc.io/doc/org.lwjgl/lwjgl.glfw/package-list").toURL())
            }

            externalDocumentationLink {
                url.set(uri("https://javadoc.io/doc/org.lwjgl/lwjgl.opengl").toURL())
                packageListUrl.set(uri("https://javadoc.io/doc/org.lwjgl/lwjgl.opengl/package-list").toURL())
            }

            externalDocumentationLink {
                url.set(uri("https://javadoc.io/doc/com.badlogicgames.gdx/gdx").toURL())
                packageListUrl.set(uri("https://javadoc.io/doc/com.badlogicgames.gdx/gdx/package-list").toURL())
            }
        }
        create("common") {
            displayName.set("Common")
            sourceRoots.from("common/src/main/kotlin")
            sourceRoots.from("common/src/main/java")
        }
        create("client") {
            displayName.set("Client")
            sourceRoots.from("client/src/main/kotlin")
            sourceRoots.from("client/src/main/java")
        }
        create("server") {
            displayName.set("Dedicated Server")
            sourceRoots.from("server/src/main/kotlin")
            sourceRoots.from("server/src/main/java")
        }
        create("lwjgl3") {
            displayName.set("LWJGL3")
            sourceRoots.from("lwjgl3/src/main/kotlin")
            sourceRoots.from("lwjgl3/src/main/java")
        }
        create("gameprovider") {
            displayName.set("Game Provider")
            sourceRoots.from("gameprovider/src/main/kotlin")
            sourceRoots.from("gameprovider/src/main/java")
        }
    }
}

tasks.register('runAnsiConsole', JavaExec) {
    classpath = project(":lwjgl3").sourceSets.main.runtimeClasspath
    mainClass = 'dev.ultreon.quantum.lwjgl3.ANSIConsole'

    group = 'application'
    description = 'Run ANSI console test'
}

def publishProjects = [
        project(":client"),
        project(":common"),
        project(":lwjgl3"),
        project(":server"),
        project(":gameprovider")
]

if (System.getenv("CI") != "true") {
    publishProjects.each { project ->
        project.mkdir("build/jreleaser")
        project.apply plugin: "maven-publish"
        project.apply plugin: "java-library"

        project.publishing {
            repositories {
                maven {
                    name = "Staging"
                    url = uri("file://${projectDir.path.replace("\\", "/")}/build/staging-deploy")
                }

                maven {
                    name = "UltreonMaven"
                    url = "https://maven.ultreon.dev/releases"
                    credentials(PasswordCredentials) {
                        username = findProperty("ultreonmvn.name") ?: System.getenv("ULTREON_MVN_NAME")
                        password = findProperty("ultreonmvn.secret") ?: System.getenv("ULTREON_MVN_SEC")
                    }
                    authentication {
                        basic(BasicAuthentication)
                    }
                }
            }

            publications {
                create(MavenPublication) { publication ->
                    from(project.components["java"])
                    artifact project.tasks["javadocJar"]

                    groupId = "dev.ultreon.quantum"
                    artifactId = "quantum-${project.name}-v2"
                    version = projectVersion

                    pom {
                        name = "QuantumVoxel V2"
                        description = "Quantum Voxel: RecƒQomputed is a voxel game that focuses on technology based survival."

                        url = "https://github.com/QuantumVoxel/game"
                        inceptionYear = "2025"

                        developers {
                            developer {
                                id = "XyperCode"
                                name = "Qubilux"

                                organization = "Ultreon"
                                organizationUrl = "https://ultreon.dev/"

                                roles = ["Owner", "Maintainer"]

                                url = "https://github.com/XyperCode"
                            }
                        }

                        organization {
                            name = "Ultreon"
                            url = "https://ultreon.dev/"
                        }

                        issueManagement {
                            system = "GitHub"
                            url = "https://github.com/QuantumVoxel/game/issues"
                        }

                        scm {
                            url = "https://github.com/QuantumVoxel/game"
                            connection = "scm:git:git://github.com/Ultreon/quantum.git"
                        }

                        licenses {
                            license {
                                name = "Apache-2.0"
                                url = "https://github.com/QuantumVoxel/game/blob/main/LICENSE"
                            }
                        }

                        contributors {
                            contributor {
                                name = "Qubilux"
                                url = "https://github.com/XyperCode"

                                roles = ["Author", "Developer"]
                            }

                            contributor {
                                name = "MincraftEinstein"
                                url = "https://github.com/MincraftEinstein"

                                roles = ["Tester", "Modeler"]
                            }

                            contributor {
                                name = "guinea7pig"
                                url = "https://github.com/guinea7pig"
                            }
                        }
                    }
                }
            }
        }
    }
}