build.gradle.kts

import java.io.FileNotFoundException

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath("com.google.code.gson:gson:2.14.0")
    }
}

plugins {
    id("java")
}

val modVersion = providers.gradleProperty("mod.version").get()
val hytaleVersion = providers.gradleProperty("hytale.version").get()
val hytalePatchline = providers.gradleProperty("hytale.patchline").getOrElse("release")

group = "me.nullicorn"
version = modVersion

repositories {
    maven {
        name = "hytale-$hytalePatchline"
        url = uri("https://maven.hytale.com/$hytalePatchline/")
    }
}

dependencies {
    implementation("com.hypixel.hytale:Server:$hytaleVersion")
}

val pluginProcessResourcesTask = tasks.register<Copy>("pluginProcessResources") {
    description = "Copy non-asset resources for the plugin"
    group = "hytale"

    copy {
        from("src/main/resources/manifest.json")
        into("build/resources/main/")
        filter {
            it.replace("\"IncludesAssetPack\": true,", "")
        }
    }
}

val pluginJarTask = tasks.register<Jar>("pluginJar") {
    description = "Packages the plugin without any assets"
    group = "hytale"

    dependsOn("classes", "pluginProcessResources")
    from("build/classes/java/main/", "build/resources/main/manifest.json")
    archiveClassifier = "bin"
}

// Turn off 'processResources' if 'pluginProcessResources' is executing.
gradle.taskGraph.whenReady {
    if (this.hasTask(pluginProcessResourcesTask.get())) {
        tasks.processResources.get().enabled = false
    }
}

tasks.jar {
    // Exclude EditorConfig (only used during development).
    exclude(".editorconfig")
    // Exclude files generated by the generateAssetSchema task (only used during development).
    exclude("Schema/", ".vscode/")
    // Include NOTICE.md and LICENSE.md.
    // Also remove any occurrences of "src/main/resources/" from paths within them. That path structure is not present
    // in the jar.
    from(files("NOTICE.md", "LICENSE.md")) {
        filter { content ->
            content
                .replace("src/main/resources/", "")
                .replace("src/main/java/", "")
        }
    }
}

fun runServer(task: JavaExec, vararg extraArgs: String) {
    val hytaleServerArtifact =
        project.configurations.compileClasspath.get().resolvedConfiguration.resolvedArtifacts.find { it.moduleVersion.id.group == "com.hypixel.hytale" && it.moduleVersion.id.name == "Server" }
    if (hytaleServerArtifact == null) {
        throw FileNotFoundException("failed to locate Hytale server dependency and its jar file")
    }

    val hytaleAssetsZip = layout.projectDirectory.file("run/Assets.zip").asFile
    if (!hytaleAssetsZip.isFile) {
        throw FileNotFoundException("please copy the Assets.zip file for version ${hytaleServerArtifact.moduleVersion.id.version} into the `run` folder")
    }

    task.workingDir = layout.projectDirectory.dir("run/").asFile
    task.classpath = files(hytaleServerArtifact.file)
    task.mainClass = "com.hypixel.hytale.Main"
    task.args = listOf(
        "--assets", hytaleAssetsZip.path,
        // Load our mod jar.
        "--mods", layout.buildDirectory.get().dir("libs/").asFile.path,
        // Load our mod asset pack.
        "--mods", layout.projectDirectory.dir("src/main/").asFile.path,
    ) + extraArgs
}

tasks.register<JavaExec>("runServer") {
    dependsOn("pluginJar")
    group = "hytale"

    // Allow Hytale console commands to be input through this Gradle task's stdin.
    standardInput = System.`in`

    runServer(task = this)
}

tasks.register<JavaExec>("generateAssetSchema") {
    dependsOn("pluginJar")
    group = "hytale"

    runServer(
        this,
        "--generate-asset-schema", layout.projectDirectory.dir("src/main/resources/").asFile.path
    )
}