dotvim/flake.nix at master · TwIStOy/dotvim · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
{
  description = "Neovim Configuration";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
    nixvim.url = "github:nix-community/nixvim";
  };

  outputs = {
    nixpkgs,
    nixvim,
    flake-parts,
    ...
  } @ inputs:
    flake-parts.lib.mkFlake {inherit inputs;} {
      systems = [
        "x86_64-linux"
        "aarch64-darwin"
      ];

      perSystem = {
        system,
        pkgs,
        self,
        lib,
        ...
      }: let
        nixvimLib = nixvim.lib.${system};
        nixvim' = nixvim.legacyPackages.${system};
        utils = import ./lib {inherit inputs;};
        configArguments =
          {
            inherit utils;
          }
          // inputs;
        nixvimModule = {
          inherit pkgs;
          module = import ./config configArguments;
          extraSpecialArgs = {
            inherit utils;
          };
        };
        nixvimNe = nixvim'.makeNixvimWithModule nixvimModule;
        printInit = nixvimNe.passthru.config.build.printInitPackage;
        ne =
          pkgs.runCommand "ne" {
            nativeBuildInputs = [pkgs.makeWrapper];
          } ''
            mkdir -p $out/bin
            makeWrapper ${lib.getExe nixvimNe} $out/bin/ne \
              --set NVIM_APPNAME ne
            ln -s ${lib.getExe printInit} $out/bin/nixvim-print-init
          '';
      in {
        checks = {
          default = nixvimLib.check.mkTestDerivationFromNixvimModule nixvimModule;
        };

        formatter = nixpkgs.legacyPackages.${system}.alejandra;

        packages = {
          default = ne;
          print-init = printInit;
        };
      };
    };
}