BookingIt/build.gradle at master · aws404/BookingIt · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
plugins {
	id "fabric-loom" version "1.+"
	id "com.modrinth.minotaur" version "2.+"
}

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

version = System.getenv("VERSION") ? System.getenv("VERSION") : "unversioned"

repositories {
	maven { url = "https://jitpack.io" }
}

sourceSets {
	testmod {
		compileClasspath += main.compileClasspath
		runtimeClasspath += main.runtimeClasspath
	}
}

dependencies {
	// To change the versions see the gradle.properties file
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

	modImplementation include("com.github.Chocohead:Fabric-ASM:v${project.mm_version}") {
		exclude (group: "net.fabricmc.fabric-api")
	}

	testmodImplementation sourceSets.main.output
}

loom {
	runs {
		testmodClient {
			client()
			ideConfigGenerated project.rootProject == project
			name = "Testmod Client"
			source sourceSets.testmod
		}
		testmodServer {
			server()
			ideConfigGenerated project.rootProject == project
			name = "Testmod Server"
			source sourceSets.testmod
		}
	}

	accessWidenerPath = file("src/main/resources/booking_it.accesswidener")
	accessWidenerPath = file("src/testmod/resources/bi_test.accesswidener")
}

modrinth {
	token = System.getenv("MODRINTH_TOKEN")
	failSilently = true
	projectId = project.project_id
	versionNumber = version
	versionName = System.getenv("VERSION_NAME") ? System.getenv("VERSION_NAME") : version
	versionType = System.getenv("ALPHA") ? "alpha" : "release"
	changelog = System.getenv("CAHNGELOG")
	uploadFile = "./build/libs/BookingIt-${version}.jar"
	dependencies {
		required.project "P7dR8mSH" // Mark Fabric API as a required dependency
	}
}

processResources {
	inputs.property "version", project.version

	filesMatching("fabric.mod.json") {
		expand "version": project.version
	}
}

tasks.withType(JavaCompile).configureEach {
	// Minecraft 1.18 (1.18-pre2) upwards uses Java 17.
	it.options.release = 17
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()
}

jar {
	from("LICENSE") {
		rename { "${it}_${project.archivesBaseName}"}
	}
}