build.gradle

plugins {
    id 'java'
    id 'java-library'
    id 'org.springframework.boot' version '3.2.4'
    id 'io.spring.dependency-management' version '1.1.6'
    id 'org.asciidoctor.jvm.convert' version '4.0.2'
}

repositories {
    mavenCentral()
}

bootJar.enabled = false

subprojects {
    apply plugin: 'java'
    apply plugin: 'java-library'
    apply plugin: 'org.springframework.boot'
    apply plugin: 'io.spring.dependency-management'
    apply plugin: 'org.asciidoctor.jvm.convert'

    group = 'com.chukcheck'
    version = '0.0.1-SNAPSHOT'
    sourceCompatibility = '21'

    configurations {
        compileOnly {
            extendsFrom annotationProcessor
        }
    }

    repositories {
        mavenCentral()
    }

    dependencies {
        implementation 'org.springframework.boot:spring-boot-starter'
        implementation 'org.springframework.boot:spring-boot-starter-web'
        implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
        implementation 'org.springframework.boot:spring-boot-starter-validation'
        compileOnly 'org.projectlombok:lombok'
        annotationProcessor 'org.projectlombok:lombok'
        testImplementation 'org.springframework.boot:spring-boot-starter-test'
    }

    tasks.named('test') {
        useJUnitPlatform()
    }
}

project(":core") {
    bootJar.enabled = false
    jar.enabled = true

    dependencies {
        implementation 'com.querydsl:querydsl-jpa:5.0.0:jakarta'
        annotationProcessor "com.querydsl:querydsl-apt:${dependencyManagement.importedProperties['querydsl.version']}:jakarta"
        annotationProcessor "jakarta.annotation:jakarta.annotation-api"
        annotationProcessor "jakarta.persistence:jakarta.persistence-api"
        implementation 'org.postgresql:postgresql'
        runtimeOnly 'com.h2database:h2'
    }

    tasks.named('bootBuildImage') {
        builder = 'paketobuildpacks/builder-jammy-base:latest'
    }

    def generated = 'src/main/generated'

    tasks.withType(JavaCompile) {
        options.getGeneratedSourceOutputDirectory().set(file(generated))
    }

    sourceSets {
        main.java.srcDirs += [generated]
    }

    clean {
        delete file('src/main/generated')
    }
}

project(":api") {
    bootJar.enabled = true
    jar.enabled = false

    configurations {
        asciidoctorExtensions
    }

    dependencies {
        implementation project(":core")
        implementation 'org.springframework.boot:spring-boot-starter-security'
        implementation 'io.jsonwebtoken:jjwt:0.12.6'

        testImplementation 'org.springframework.security:spring-security-test'

        asciidoctorExtensions 'org.springframework.restdocs:spring-restdocs-asciidoctor'
        testImplementation 'org.springframework.restdocs:spring-restdocs-mockmvc'
    }

    ext {
        set('snippetsDir', file("build/generated-snippets"))
    }

    test {
        outputs.dir snippetsDir
        useJUnitPlatform()
    }

    asciidoctor {
        dependsOn test
        configurations 'asciidoctorExtensions'
        inputs.dir snippetsDir

        sources {
            include("**/index.adoc", "**/common/*.adoc")
        }

        // 특정 .adoc에 다른 adoc 파일을 가져와서(include) 사용하고 싶을 경우 경로를 baseDir로 맞춰주는 설정입니다.
        // 개별 adoc으로 운영한다면 필요 없는 옵션입니다.
        baseDirFollowsSourceFile()
    }

    // static/docs 폴더 비우기
    asciidoctor.doFirst {
        delete file('src/main/resources/static/docs')
    }

    // asccidoctor 작업 이후 생성된 HTML 파일을 static/docs 로 copy
    tasks.register('copyDocument', Copy) {
        dependsOn asciidoctor
        from file("build/docs/asciidoc")
        into file("src/main/resources/static/docs")
    }

    // build 의 의존작업 명시
    build {
        dependsOn copyDocument
    }

    bootJar {
        dependsOn asciidoctor
        from("${asciidoctor.outputDir}/html5") {
            into 'static/docs'
        }
    }
}

project(":scheduler") {
    bootJar.enabled = true
    jar.enabled = false

    dependencies {
        implementation(project(":core"))
    }
}