terraform-aws-ec2/data.tf at master · clouddrove/terraform-aws-ec2 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
######################################
# LOCALS
######################################
locals {
  # Map for Amazon Linux AMI patterns
  ami_name_map = {
    al1    = "amzn-ami-*"
    al2    = "amzn2-ami-hvm-*"
    al2023 = "al2023-ami-*"
  }

  # Map for AMI owner IDs
  ami_owner_map = {
    al1    = "591542846629" # Amazon
    al2    = "137112412989" # Amazon
    al2023 = "137112412989" # Amazon
  }
}

######################################
# Amazon (ARM, AMD)
######################################
data "aws_ami" "amazon" {
  count       = var.instance_configuration.ami_id == "" && var.instance_configuration.ami.type != "ubuntu" ? 1 : 0
  most_recent = true
  owners      = [local.ami_owner_map[var.instance_configuration.ami.type]]

  filter {
    name   = "name"
    values = [local.ami_name_map[var.instance_configuration.ami.type]]
  }

  filter {
    name   = "architecture"
    values = [var.instance_configuration.ami.architecture]
  }

  filter {
    name   = "root-device-type"
    values = ["ebs"]
  }

  filter {
    name   = "virtualization-type"
    values = ["hvm"]
  }
}

######################################
# Ubuntu (ARM, AMD)
######################################
data "aws_ami" "ubuntu" {
  count       = var.instance_configuration.ami_id == "" && var.instance_configuration.ami.type == "ubuntu" ? 1 : 0
  most_recent = true
  owners      = ["099720109477"] # Canonical

  filter {
    name = "name"
    values = [
      "${var.instance_configuration.ami.type}/images/*${var.instance_configuration.ami.version == null ? "22.04" : var.instance_configuration.ami.version}*"
    ]
  }

  filter {
    name   = "architecture"
    values = [var.instance_configuration.ami.architecture]
  }

  filter {
    name   = "root-device-type"
    values = ["ebs"]
  }

  filter {
    name   = "virtualization-type"
    values = ["hvm"]
  }
}