build.gradle

buildscript {
  ext {
    kotlinVersion = "1.1.51"
    springBootVersion = "2.0.0.M4"
  }
  repositories {
    mavenCentral()
    maven { url "https://repo.spring.io/snapshot" }
    maven { url "https://repo.spring.io/milestone" }
  }
  dependencies {
    classpath("org.springframework.boot:spring-boot-gradle-plugin:$springBootVersion")
    classpath("org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion")
    classpath("org.jetbrains.kotlin:kotlin-allopen:$kotlinVersion")
  }
}

plugins {
  id "idea"
  id "eclipse"
}

allprojects { ap ->

  apply plugin: "java"
  apply plugin: "kotlin"
  apply plugin: "kotlin-spring"

  version = "0.0.1"
  group = "daggerok"
  sourceCompatibility = targetCompatibility = JavaVersion.VERSION_1_8

  compileKotlin {
    kotlinOptions.jvmTarget = "1.8"//JavaVersion.VERSION_1_8
  }

  compileTestKotlin {
    kotlinOptions.jvmTarget = "1.8"//JavaVersion.VERSION_1_8
  }

  repositories {
    mavenCentral()
    maven { url "https://repo.spring.io/snapshot" }
    maven { url "https://repo.spring.io/milestone" }
  }

  wrapper {
    gradleVersion = "4.2.1"
    distributionType = "ALL"
  }
}

subprojects { sp ->

  apply plugin: "org.springframework.boot"
  apply plugin: "io.spring.dependency-management"

  dependencies {
    compile("org.springframework.boot:spring-boot-starter")

    compile("org.jetbrains.kotlin:kotlin-stdlib-jre8:$kotlinVersion")
    compile("org.jetbrains.kotlin:kotlin-reflect:$kotlinVersion")

    testCompile("org.springframework.boot:spring-boot-starter-test")
    testCompile('io.projectreactor:reactor-test')
  }

  bootJar {
    launchScript {
      included = true
    }
  }
}