jpasskit/build.gradle.kts at main · drallgood/jpasskit · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
import org.jreleaser.model.Active
import org.jreleaser.model.Signing
import java.util.Calendar

plugins {
    `maven-publish`
    id("de.brendamour.java-conventions")
    id("org.jreleaser") version "1.24.0"
}

allprojects {
    group = "de.brendamour"
    repositories {
        mavenCentral()
        gradlePluginPortal()
    }
    tasks.withType<JavaCompile> {
        sourceCompatibility = JavaVersion.VERSION_11.toString()
        targetCompatibility = JavaVersion.VERSION_11.toString()
    }
}

jreleaser {
    gitRootSearch.set(true)

    project {
        name.set("jpasskit")
        description.set("Java Library for Apple PassKit Web Service")
        license.set("Apache-2.0")
        authors.set(listOf("Patrice Brend'amour"))
        copyright.set("2012-${Calendar.getInstance().get(Calendar.YEAR)} Patrice Brend'amour")
    }

    release {
        github {
            repoOwner.set("drallgood")
            name.set("jpasskit")
            overwrite.set(true)
            skipTag.set(true)
            changelog {
                preset.set("conventional-commits")
                skipMergeCommits.set(true)
            }
        }
    }

    signing {
        active.set(Active.ALWAYS)
        armored.set(true)
        command {
            executable.set("gpg")
            args.set(listOf("--batch", "--yes", "--pinentry-mode", "loopback"))
            keyName.set("9474B9FCBDF93BEE7CC4B69B4CE3C3B7A5E5FCC2")
        }
        mode.set(Signing.Mode.COMMAND)
    }

    deploy {
        maven {
            mavenCentral {
                create("release-deploy") {
                    active.set(Active.RELEASE)
                    url.set("https://central.sonatype.com/api/v1/publisher")
                    stagingRepositories.set(
                        listOf(
                            layout.buildDirectory.dir("staging-deploy").get().asFile.absolutePath,
                            project(":jpasskit").layout.buildDirectory.dir("staging-deploy").get().asFile.absolutePath,
                            project(":jpasskit.server").layout.buildDirectory.dir("staging-deploy").get().asFile.absolutePath
                        )
                    )
                    applyMavenCentralRules.set(true)
                }
            }
            nexus2 {
                create("snapshot-deploy") {
                    active.set(Active.SNAPSHOT)
                    url.set("https://central.sonatype.com/api/v1/publisher")
                    snapshotUrl.set("https://central.sonatype.com/repository/maven-snapshots")
                    stagingRepositories.set(
                        listOf(
                            layout.buildDirectory.dir("staging-deploy").get().asFile.absolutePath,
                            project(":jpasskit").layout.buildDirectory.dir("staging-deploy").get().asFile.absolutePath,
                            project(":jpasskit.server").layout.buildDirectory.dir("staging-deploy").get().asFile.absolutePath
                        )
                    )
                    applyMavenCentralRules.set(true)
                    closeRepository.set(true)
                    snapshotSupported.set(true)
                }
            }
        }
    }
}