Overhaul CMake (#63)

Fixes: #58

* Overhaul CMake

* Clang format

* Rename method header

* Merge conflicts

---------

Co-authored-by: Sy Brand <sy.brand@fastly.com>

Author: TartanLlama

.github/workflows/release.yml

@@ -38,6 +38,9 @@ jobs:
       - name: Set env
         run: echo "ARCHIVE_FILENAME_PREFIX=fastly-cpp-${GITHUB_REF#refs/*/}" >> $GITHUB_ENV
 
+      - name: Install SDK
+        run: cmake --install . --prefix target/release/dist
+
       - name: Archive core dist
         run: tar cvf ${{ env.ARCHIVE_FILENAME_PREFIX }}.tar -C target/release/dist fastly libfastly.a
 

CMakeLists.txt

@@ -1,97 +1,92 @@
 # From https://github.com/XiangpengHao/cxx-cmake-example/blob/master/fastly/CMakeLists.txt
 cmake_minimum_required(VERSION 3.15)
-project(compute-sdk-cpp)
 
-if(!WASI_SDK)
-    set(WASI_SDK "/opt/wasi-sdk")
-endif()
+project(compute-sdk-cpp VERSION 0.2.0 LANGUAGES CXX)
 
 if(VERBOSE)
     set(VERBOSE_FLAG "--verbose")
 endif()
 
-set(CMAKE_CXX_STANDARD 20)
-
-set(TARGET_TRIPLE wasm32-wasip1)
-
 if (CMAKE_BUILD_TYPE STREQUAL "Debug")
-    set(CARGO_CMD cargo build --target=${TARGET_TRIPLE} ${VERBOSE_FLAG})
+    set(CARGO_CMD cargo build --target=${CMAKE_CXX_COMPILER_TARGET} ${VERBOSE_FLAG})
     set(TARGET_DIR "debug")
 else ()
-    set(CARGO_CMD cargo build --target=${TARGET_TRIPLE} --release ${VERBOSE_FLAG})
+    set(CARGO_CMD cargo build --target=${CMAKE_CXX_COMPILER_TARGET} --release ${VERBOSE_FLAG})
     set(TARGET_DIR "release")
 endif ()
 
-set(DIST_DIR ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_DIR}/dist)
-
-set(CC "${WASI_SDK}/bin/clang")
-set(ENV{CC} "${WASI_SDK}/bin/clang")
-set(CXX "${WASI_SDK}/bin/clang++")
-
 option(ENABLE_LTO "Enable cross language linking time optimization" ON)
+set(LTO_SUPPORTED FALSE)
 if(ENABLE_LTO)
     include(CheckIPOSupported)
     check_ipo_supported(RESULT supported OUTPUT error)
     if(supported)
         message(STATUS "IPO / LTO enabled")
-        set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
-        add_link_options(-fuse-ld=lld)
-        set(CFLAGS "-flto=thin -Oz")
-        set(CXXFLAGS "${CMAKE_CXX_FLAGS} -flto=thin -Oz --sysroot=${WASI_SDK}/share/wasi-sysroot -DRUST_CXX_NO_EXCEPTIONS -fno-exceptions")
-        set(CMAKE_CXX_FLAGS ${CXXFLAGS})
-        set(RUST_FLAGS "-Clinker-plugin-lto" "-Clinker=${CMAKE_CURRENT_SOURCE_DIR}/build-workaround.sh" "-Clink-arg=-fuse-ld=lld" "-L${WASI_SDK}/share/wasi-sysroot/lib/wasm32-wasi" "-lstatic=c++" "-lstatic=c++abi")
+        set(LTO_SUPPORTED TRUE)
+        set(FASTLY_LDFLAGS -fuse-ld=lld)
+        set(FASTLY_CFLAGS -flto=thin -Oz)
+        set(FASTLY_CXXFLAGS -flto=thin -Oz "--sysroot=${WASI_SDK_PREFIX}/share/wasi-sysroot" -DRUST_CXX_NO_EXCEPTIONS -fno-exceptions)
+        set(FASTLY_RUST_FLAGS -Clinker-plugin-lto "-Clinker=${CMAKE_CURRENT_SOURCE_DIR}/build-workaround.sh" "-Clink-arg=-fuse-ld=lld" "-L${WASI_SDK_PREFIX}/share/wasi-sysroot/lib/wasm32-wasi" "-lstatic=c++" "-lstatic=c++abi")
     else()
         message(STATUS "IPO / LTO not supported: <${error}>")
-        set(CXXFLAGS "${CMAKE_CXX_FLAGS} --sysroot=${WASI_SDK}/share/wasi-sysroot -DRUST_CXX_NO_EXCEPTIONS -fno-exceptions")
-        set(CMAKE_CXX_FLAGS ${CXXFLAGS})
-        set(RUST_FLAGS "-L${WASI_SDK}/share/wasi-sysroot/lib/wasm32-wasi" "-lstatic=c++" "-lstatic=c++abi")
+        set(FASTLY_CXXFLAGS "--sysroot=${WASI_SDK_PREFIX}/share/wasi-sysroot -DRUST_CXX_NO_EXCEPTIONS -fno-exceptions")
+        set(FASTLY_RUST_FLAGS "-L${WASI_SDK_PREFIX}/share/wasi-sysroot/lib/wasm32-wasi" "-lstatic=c++" "-lstatic=c++abi")
     endif()
 else()
-    set(CXXFLAGS "${CMAKE_CXX_FLAGS} --sysroot=${WASI_SDK}/share/wasi-sysroot -DRUST_CXX_NO_EXCEPTIONS -fno-exceptions")
-    set(CMAKE_CXX_FLAGS ${CXXFLAGS})
-    set(RUST_FLAGS "-L${WASI_SDK}/share/wasi-sysroot/lib/wasm32-wasi" "-lstatic=c++" "-lstatic=c++abi")
+    set(FASTLY_CXXFLAGS "-sysroot=${WASI_SDK_PREFIX}/share/wasi-sysroot -DRUST_CXX_NO_EXCEPTIONS -fno-exceptions")
+    set(FASTLY_RUST_FLAGS "-L${WASI_SDK_PREFIX}/share/wasi-sysroot/lib/wasm32-wasi" "-lstatic=c++" "-lstatic=c++abi")
 endif()
-if (POLICY CMP0048)
-    cmake_policy(SET CMP0048 NEW)
-endif ()
 
-set(FASTLY_SYS_LIB "${CMAKE_CURRENT_BINARY_DIR}/${TARGET_TRIPLE}/${TARGET_DIR}/libfastly_sys.a")
+set(FASTLY_SYS_LIB "${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CXX_COMPILER_TARGET}/${TARGET_DIR}/libfastly_sys.a")
 
 set(FASTLY_SYS_CXX "${CMAKE_CURRENT_BINARY_DIR}/fastly-sys.cpp")
 file(GLOB_RECURSE FASTLY_CXX "${CMAKE_CURRENT_SOURCE_DIR}/src/cpp/**/*.cpp" "${CMAKE_CURRENT_SOURCE_DIR}/src/cpp/*.cpp")
 
 add_library(fastly-sys STATIC ${FASTLY_SYS_CXX})
+add_library(fastly::sys ALIAS fastly-sys)
+set_target_properties(fastly-sys PROPERTIES 
+    INTERPROCEDURAL_OPTIMIZATION ${LTO_SUPPORTED})
+target_link_options(fastly-sys PRIVATE ${FASTLY_LDFLAGS})
+
 add_library(fastly-sys-orig STATIC IMPORTED)
-add_library(fastly-thin STATIC ${FASTLY_CXX} fastly-sys ${CMAKE_CURRENT_SOURCE_DIR}/vendor/tl/expected.h)
 set_target_properties(fastly-sys-orig PROPERTIES IMPORTED_LOCATION ${FASTLY_SYS_LIB})
 
-if(MSVC)
-    target_compile_options(fastly-thin PRIVATE /W3 /WX)
-else()
-    target_compile_options(fastly-thin PRIVATE -Wall -Wextra -Werror)
-endif()
+add_library(fastly-thin STATIC ${FASTLY_CXX})
+add_library(fastly::thin ALIAS fastly-thin)
+target_include_directories(fastly-thin PRIVATE 
+    ${CMAKE_CURRENT_SOURCE_DIR}/vendor/tl)
+set_target_properties(fastly-thin PROPERTIES
+    INTERPROCEDURAL_OPTIMIZATION ${LTO_SUPPORTED})
+target_link_options(fastly-thin PRIVATE ${FASTLY_LDFLAGS})
+
+target_compile_options(fastly-thin PRIVATE -Wall -Wextra -Werror ${FASTLY_CXXFLAGS})
+target_compile_options(fastly-sys PRIVATE ${FASTLY_CXXFLAGS})
+target_compile_features(fastly-thin PUBLIC cxx_std_20)
 
 set_target_properties(
     fastly-sys fastly-thin
     PROPERTIES
     ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_DIR}
 )
 
-file(GLOB_RECURSE RUST_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/**/*.rs" "${CMAKE_CURRENT_COURSE_DIR}/src/*.rs")
+file(GLOB_RECURSE RUST_SRC "${CMAKE_CURRENT_SOURCE_DIR}/src/**/*.rs" "${CMAKE_CURRENT_SOURCE_DIR}/src/*.rs")
 
 add_custom_command(
-    OUTPUT ${FASTLY_SYS_CXX} ${FASTLY_SYS_LIB} ${DIST_DIR}/fastly/sdk-sys.h ${DIST_DIR}/fastly/util.h
-    COMMAND CARGO_TARGET_DIR=${CMAKE_CURRENT_BINARY_DIR} CC=${CC} CXX=${CXX} CFLAGS=${CFLAGS} CXXFLAGS=${CXXFLAGS} RUSTFLAGS="${RUST_FLAGS}" ${CARGO_CMD}
+    OUTPUT ${FASTLY_SYS_CXX} ${FASTLY_SYS_LIB} ${CMAKE_CURRENT_BINARY_DIR}/include/fastly/sdk-sys.h
+    COMMAND CARGO_TARGET_DIR=${CMAKE_CURRENT_BINARY_DIR} CC="${CMAKE_C_COMPILER}" CXX="${CMAKE_CXX_COMPILER}" CFLAGS="${FASTLY_CFLAGS}" CXXFLAGS="${FASTLY_CXXFLAGS}" RUSTFLAGS="${FASTLY_RUST_FLAGS}" ${CARGO_CMD}
     COMMAND cp ${CMAKE_CURRENT_BINARY_DIR}/cxxbridge/fastly-sys/src/lib.rs.cc ${FASTLY_SYS_CXX}
-    COMMAND cp ${CMAKE_CURRENT_BINARY_DIR}/cxxbridge/fastly-sys/src/lib.rs.h ${DIST_DIR}/fastly/sdk-sys.h
-    COMMAND cp ${CMAKE_CURRENT_SOURCE_DIR}/vendor/tl/expected.h ${DIST_DIR}/fastly/expected.h
+    COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_CURRENT_BINARY_DIR}/include/fastly
+    COMMAND cp ${CMAKE_CURRENT_BINARY_DIR}/cxxbridge/fastly-sys/src/lib.rs.h ${CMAKE_CURRENT_BINARY_DIR}/include/fastly/sdk-sys.h
+    COMMAND cp ${CMAKE_CURRENT_SOURCE_DIR}/vendor/tl/expected.h ${CMAKE_CURRENT_BINARY_DIR}/include/fastly/expected.h
     WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
     DEPENDS ${RUST_SRC}
 )
 
-target_include_directories(fastly-thin PUBLIC ${DIST_DIR} ${DIST_DIR}/fastly ${DIST_DIR}/fastly/http)
+target_include_directories(fastly-thin PUBLIC
+    ${CMAKE_CURRENT_SOURCE_DIR}/include
+    ${CMAKE_CURRENT_BINARY_DIR}/include)
 
-target_link_libraries(fastly-thin PUBLIC fastly-sys-orig fastly-sys)
+target_link_libraries(fastly-thin PUBLIC fastly-sys-orig fastly::sys)
 
 function(bundle_static_library tgt_name bundled_tgt_name)
     list(APPEND static_libs ${tgt_name})
@@ -129,47 +124,33 @@ function(bundle_static_library tgt_name bundled_tgt_name)
 
     list(REMOVE_DUPLICATES static_libs)
 
-    set(bundled_tgt_full_name
-    ${DIST_DIR}/${CMAKE_STATIC_LIBRARY_PREFIX}${bundled_tgt_name}${CMAKE_STATIC_LIBRARY_SUFFIX})
+    set(bundled_tgt_full_name "${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_STATIC_LIBRARY_PREFIX}${bundled_tgt_name}${CMAKE_STATIC_LIBRARY_SUFFIX}" CACHE INTERNAL "Bundled target full name")
 
     if (CMAKE_CXX_COMPILER_ID MATCHES "^(Clang|GNU)$")
-        file(WRITE ${CMAKE_BINARY_DIR}/${bundled_tgt_name}.ar.in
-      "CREATE ${bundled_tgt_full_name}\n" )
+        file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${bundled_tgt_name}.ar.in "CREATE ${bundled_tgt_full_name}\n" )
 
         foreach(tgt IN LISTS static_libs)
-            file(APPEND ${CMAKE_BINARY_DIR}/${bundled_tgt_name}.ar.in
-        "ADDLIB $<TARGET_FILE:${tgt}>\n")
+            file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/${bundled_tgt_name}.ar.in
+                "ADDLIB $<TARGET_FILE:${tgt}>\n")
         endforeach()
 
-        file(APPEND ${CMAKE_BINARY_DIR}/${bundled_tgt_name}.ar.in "SAVE\n")
-        file(APPEND ${CMAKE_BINARY_DIR}/${bundled_tgt_name}.ar.in "END\n")
+        file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/${bundled_tgt_name}.ar.in "SAVE\n")
+        file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/${bundled_tgt_name}.ar.in "END\n")
 
         file(GENERATE
-      OUTPUT ${CMAKE_BINARY_DIR}/${bundled_tgt_name}.ar
-      INPUT ${CMAKE_BINARY_DIR}/${bundled_tgt_name}.ar.in)
+            OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${bundled_tgt_name}.ar
+            INPUT ${CMAKE_CURRENT_BINARY_DIR}/${bundled_tgt_name}.ar.in)
 
         set(ar_tool ${CMAKE_AR})
         if (CMAKE_INTERPROCEDURAL_OPTIMIZATION)
             set(ar_tool ${CMAKE_CXX_COMPILER_AR})
         endif()
 
         add_custom_command(
-      COMMAND ${ar_tool} -M < ${CMAKE_BINARY_DIR}/${bundled_tgt_name}.ar
-      OUTPUT ${bundled_tgt_full_name}
-      COMMENT "Bundling ${bundled_tgt_name}"
-      VERBATIM)
-    elseif(MSVC)
-        find_program(lib_tool lib)
-
-        foreach(tgt IN LISTS static_libs)
-            list(APPEND static_libs_full_names $<TARGET_FILE:${tgt}>)
-        endforeach()
-
-        add_custom_command(
-      COMMAND ${lib_tool} /NOLOGO /OUT:${bundled_tgt_full_name} ${static_libs_full_names}
-      OUTPUT ${bundled_tgt_full_name}
-      COMMENT "Bundling ${bundled_tgt_name}"
-      VERBATIM)
+            COMMAND ${ar_tool} -M < ${CMAKE_CURRENT_BINARY_DIR}/${bundled_tgt_name}.ar
+            OUTPUT ${bundled_tgt_full_name}
+            COMMENT "Bundling ${bundled_tgt_name}"
+            VERBATIM)
     else()
         message(FATAL_ERROR "Unknown bundle scenario!")
     endif()
@@ -178,26 +159,54 @@ function(bundle_static_library tgt_name bundled_tgt_name)
     add_dependencies(bundling_target ${tgt_name})
 
     add_library(${bundled_tgt_name} STATIC IMPORTED)
-    set_target_properties(${bundled_tgt_name} ${bundled_target_full_name}
-    PROPERTIES
-      IMPORTED_LOCATION ${bundled_tgt_full_name}
-      INTERFACE_INCLUDE_DIRECTORIES $<TARGET_PROPERTY:${tgt_name},INTERFACE_INCLUDE_DIRECTORIES>
-      LIBRARY_OUTPUT_DIRECTORY ${DIST_DIR}
+    set_target_properties(${bundled_tgt_name} PROPERTIES
+        IMPORTED_LOCATION ${bundled_tgt_full_name}
+        INTERFACE_INCLUDE_DIRECTORIES $<TARGET_PROPERTY:${tgt_name},INTERFACE_INCLUDE_DIRECTORIES>
+        LIBRARY_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
     )
     add_dependencies(${bundled_tgt_name} bundling_target)
 
 endfunction()
 bundle_static_library(fastly-thin fastly)
 
-file(GLOB_RECURSE FASTLY_HEADERS "${CMAKE_CURRENT_SOURCE_DIR}/src/cpp/**/*.h" "${CMAKE_CURRENT_SOURCE_DIR}/src/cpp/*.h")
+file(GLOB_RECURSE FASTLY_HEADERS "${CMAKE_CURRENT_SOURCE_DIR}/include/**/*.h")
 foreach(f ${FASTLY_HEADERS})
-    file(RELATIVE_PATH fr "${CMAKE_CURRENT_SOURCE_DIR}/src/cpp" ${f})
-    configure_file(${f} ${DIST_DIR}/fastly/${fr} COPYONLY)
-    list(APPEND incls "#include \"${fr}\"\n")
+    file(RELATIVE_PATH fr "${CMAKE_CURRENT_SOURCE_DIR}/include" ${f})
+    list(APPEND incls "#include <${fr}>\n")
 endforeach(f)
-list(APPEND incls "#include \"expected.h\"\n")
-file(WRITE ${DIST_DIR}/fastly/sdk.h ${incls})
+list(APPEND incls "#include <fastly/expected.h>\n")
+file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/include/fastly/sdk.h ${incls})
+
+if(CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME)
+    include(CTest)
+endif()
+if (BUILD_TESTING)
+    add_test(NAME fastly_test
+        COMMAND cargo test
+        WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
+endif()
+
+
+include(CMakePackageConfigHelpers)
+write_basic_package_version_file(
+    fastly-config-version.cmake
+    VERSION ${PACKAGE_VERSION}
+    COMPATIBILITY AnyNewerVersion
+)
+
+include(GNUInstallDirs)
+install(FILES ${CMAKE_CURRENT_BINARY_DIR}/fastly-config-version.cmake
+    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/fastly
+)
+install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/cmake/fastly-config.cmake
+    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/fastly
+)
+
+install(FILES ${bundled_tgt_full_name}
+    DESTINATION ${CMAKE_INSTALL_LIBDIR})
+install(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/include/fastly
+    DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
+install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/fastly
+    DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
+
 
-add_test(NAME fastly_test
-    COMMAND cargo test
-    WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})

CONTRIBUTING.md

@@ -23,7 +23,7 @@ one used by your `rustc`.
 
 The build script assumes you're installing `wasi-sdk` to `/opt/wasi-sdk`. You
 can specify a custom path using `--set wasi-sdk /path/to/wasi-sdk-dist` in
-`just`, or `-DWASI_SDK=/path/to/wasi-sdk-dist` if using `cmake` along.
+`just`, or by supplying the relevant `wasi-sdk-p1.cmake` file with `-DCMAKE_TOOLCHAIN_FILE` if using CMake directly.
 
 ### Example(s)
 

README.md

@@ -56,7 +56,7 @@ simply reference the `quickstart` project for a working example configuration.
 
 All header files are included in the `fastly/` folder. You can choose to import
 individual headers only for the things you need, or to import the entire Fastly
-SDK using `#include "fastly/sdk.h"`.
+SDK using `#include <fastly/sdk.h>`.
 
 #### Building from source
 

cmake/fastly-config.cmake

@@ -0,0 +1,11 @@
+include(${CMAKE_CURRENT_LIST_DIR}/fastly-config-version.cmake)
+
+add_library(fastly::fastly STATIC IMPORTED)
+
+set_target_properties(fastly::fastly PROPERTIES
+  IMPORTED_LOCATION "${CMAKE_CURRENT_LIST_DIR}/../../libfastly.a"
+  INTERFACE_COMPILE_FEATURES "cxx_std_20"
+  INTERFACE_INCLUDE_DIRECTORIES "${CMAKE_CURRENT_LIST_DIR}/../../../include"
+)
+
+set(FASTLY_INCLUDE_DIR "${CMAKE_CURRENT_LIST_DIR}/../../../include")

examples/CMakeLists.txt

@@ -1,7 +1,4 @@
 cmake_minimum_required(VERSION 3.15)
-if(!WASI_SDK)
-    set(WASI_SDK "/opt/wasi-sdk")
-endif()
 if(!EXAMPLE_NAME)
     set(EXAMPLE_NAME "echo")
 endif()
@@ -12,36 +9,28 @@ else ()
     set(TARGET_DIR "release")
 endif ()
 
-set(CMAKE_C_COMPILER "${WASI_SDK}/bin/clang")
-set(CMAKE_CXX_COMPILER "${WASI_SDK}/bin/clang++")
-set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions")
+project(cxx_example)
+
+add_link_options(-L${WASI_SDK_PREFIX}/share/wasi-sysroot/lib/wasm32-wasi)
+
+add_subdirectory(.. ../../target)
+
+add_executable(${EXAMPLE_NAME} ${EXAMPLE_NAME}.cpp)
+target_compile_options(${EXAMPLE_NAME} PRIVATE -Wall -Wextra -Werror -fno-exceptions)
 
 option(ENABLE_LTO "Enable cross language linking time optimization" OFF)
 if(ENABLE_LTO)
     include(CheckIPOSupported)
     check_ipo_supported(RESULT supported OUTPUT error)
     if(supported)
         message(STATUS "IPO / LTO enabled")
-        set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
-        add_link_options(-fuse-ld=lld)
+        set_target_properties(${EXAMPLE_NAME} PROPERTIES CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
+        target_link_options(${EXAMPLE_NAME} PRIVATE -fuse-ld=lld)
     else()
         message(STATUS "IPO / LTO not supported: <${error}>")
     endif()
 endif()
-if (POLICY CMP0048)
-    cmake_policy(SET CMP0048 NEW)
-endif ()
-
-project(cxx_example)
-
-set (CMAKE_CXX_STANDARD 20)
-
-add_link_options(-L${WASI_SDK}/share/wasi-sysroot/lib/wasm32-wasi)
-
-add_subdirectory(.. ../../target)
-
-add_executable(${EXAMPLE_NAME} ${EXAMPLE_NAME}.cpp)
 
 set_target_properties(${EXAMPLE_NAME} PROPERTIES SUFFIX .wasm)
 target_include_directories(${EXAMPLE_NAME} PUBLIC ${CMAKE_CURRENT_BINARY_DIR}/../../${TARGET_DIR})
-target_link_libraries(${EXAMPLE_NAME} fastly-thin)
+target_link_libraries(${EXAMPLE_NAME} fastly::thin)

src/cpp/backend.h include/fastly/backend.hsrc/cpp/backend.h renamed to include/fastly/backend.h

@@ -1,10 +1,9 @@
 #ifndef FASTLY_BACKEND_H
 #define FASTLY_BACKEND_H
 
-#include "error.h"
-#include "http/request.h"
-#include "sdk-sys.h"
-#include "util.h"
+#include <fastly/error.h>
+#include <fastly/http/request.h>
+#include <fastly/sdk-sys.h>
 #include <chrono>
 #include <string>
 #include <string_view>

src/cpp/config_store.h include/fastly/config_store.hsrc/cpp/config_store.h renamed to include/fastly/config_store.h

@@ -1,9 +1,8 @@
 #ifndef FASTLY_CONFIG_STORE_H
 #define FASTLY_CONFIG_STORE_H
 
-#include "error.h"
-#include "sdk-sys.h"
-#include "util.h"
+#include <fastly/error.h>
+#include <fastly/sdk-sys.h>
 #include <optional>
 #include <string>
 #include <string_view>