[PR 128] CMake: Add Findleveldb.cmake module for building without Hunter

Imported from:

https://gitlab.cern.ch/dss/eos/blob/master/cmake/Findleveldb.cmake

Author: eigendude

cmake/dependencies.cmake

@@ -42,7 +42,7 @@ find_package(Boost.DI CONFIG REQUIRED)
 
 # https://docs.hunter.sh/en/latest/packages/pkg/leveldb.html
 hunter_add_package(leveldb)
-find_package(leveldb CONFIG REQUIRED)
+find_package(leveldb REQUIRED)
 
 # https://github.com/soramitsu/libp2p
 hunter_add_package(libp2p)

cmake/modules/Findleveldb.cmake

@@ -0,0 +1,47 @@
+#.rst:
+# Findleveldb
+# -----------
+# Finds the leveldb library
+#
+# This will define the following variables:
+#
+#   LEVELDB_FOUND        -  system has leveldb
+#   LEVELDB_INCLUDE_DIRS -  leveldb include directories
+#   LEVELDB_LIBRARIES    -  libraries needed to use leveldb
+#
+# and the following imported targets:
+#
+#   leveldb::leveldb   - The leveldb library
+#
+
+include(FindPackageHandleStandardArgs)
+
+find_path(
+  LEVELDB_INCLUDE_DIR
+  NAMES leveldb/db.h
+  HINTS ${LEVELDB_ROOT_DIR} $ENV{LEVELDB_ROOT_DIR}
+  PATH_SUFFIXES include)
+
+find_library(
+  LEVELDB_LIBRARY
+  NAMES leveldb
+  HINTS ${LEVELDB_ROOT_DIR} $ENV{LEVELDB_ROOT_DIR}
+  PATH_SUFFIXES ${LIBRARY_PATH_PREFIX})
+
+find_package_handle_standard_args(
+  leveldb
+  DEFAULT_MSG LEVELDB_LIBRARY LEVELDB_INCLUDE_DIR)
+
+if (LEVELDB_FOUND)
+  set(LEVELDB_INCLUDE_DIRS ${LEVELDB_INCLUDE_DIR})
+  set(LEVELDB_LIBRARIES ${LEVELDB_LIBRARY})
+
+  if (NOT TARGET leveldb::leveldb)
+    add_library(leveldb::leveldb UNKNOWN IMPORTED)
+    set_target_properties(leveldb::leveldb PROPERTIES
+      IMPORTED_LOCATION "${LEVELDB_LIBRARY}"
+      INTERFACE_INCLUDE_DIRECTORIES "${LEVELDB_INCLUDE_DIR}")
+  endif()
+endif()
+
+mark_as_advanced(LEVELDB_LIBRARY LEVELDB_INCLUDE_DIR)