add a set_environment_variable procedure to stdlib_system

[jalvesz]

Motivation

While iso_fortran_env provides get_environment_variable to query existing env variables, there doesn't seem to be a "set" counterpart availble in the Fortran standard or other standard modules.

A (yet to be) set_environment_variable could be added to stdlib by wrapping the C procedures

• Windows : _putenv_s
• Unix: setenv

Prior Art

No response

Additional Information

No response

[jalvesz]

Something like:

    subroutine set_environment_variable(name, value, overwrite, status)
        character(len=*), intent(in) :: name
        character(len=*), intent(in) :: value
        logical, intent(in), optional :: overwrite
        integer, intent(out), optional  :: status

        logical :: overwrite_
        integer(c_int) :: c_status
        character(kind=c_char, len=:), allocatable :: c_name, c_value
        
        interface
#ifdef _WIN32
            function c_putenv_s(name, value) bind(C, name="_putenv_s")
                import :: c_char, c_int
                integer(c_int) :: c_putenv_s
                character(c_char) :: name(*)
                character(c_char) :: value(*)
            end function
#else
            function c_setenv(name, value, overwrite) bind(C, name="setenv")
                import :: c_char, c_int
                integer(c_int) :: c_setenv
                character(c_char) :: name(*)
                character(c_char) :: value(*)
                integer(c_int), value :: overwrite
            end function
#endif
        end interface

        overwrite_= .true.
        if (present(overwrite)) overwrite_= overwrite

        c_name  = trim(name) // c_null_char
        c_value = trim(value) // c_null_char
        
#ifdef _WIN32
        c_status = c_putenv_s(c_name, c_value)
#else
        c_status = c_setenv(c_name, c_value, merge(1_c_int, 0_c_int, overwrite_) )
#endif
        if (present(status)) status = int(c_status)
    end subroutine set_environment_variable