Justfile

#rg := 'rg -IN --sort=path'

sed := 'gsed -E'
hledger := 'hledger -n'
hledgerc := 'hledger -f main.journal'
downloads := '/Users/simon/Downloads'
occsvsrc := downloads / 'hledger-transactions.csv'
csv := 'data/oc.csv'
checks := 'accounts commodities balanced ordereddates'
open := 'open'

# Make constants and recipe arguments available as environment variables.
# (But {{ VAR }} handles multi-word values better.)

set export := true

# By default, list this justfile's commands, optionally filtered by case-insensitive REGEX
@_help *REGEX:
    if [[ '{{ REGEX }}' =~ '' ]]; then just -ul; else just -ul --color=always | rg -i '{{ REGEX }}'; true; fi

alias h := _help

# Check this justfile for errors and non-standard format
@_chk:
    just --fmt --unstable --check

alias chk := _chk

# If this justfile is error free but in non-standard format, reformat it
@_fmt:
    just -q chk || just -q --fmt --unstable

alias fmt := _fmt

# maintenance

# Open the opencollective transactions page for downloading csv
[group('maintenance')]
@csv:
    $open 'https://opencollective.com/hledger/transactions?kind=ALL'
    read -p 'After successful download, press enter to move the csv file: '
    just csvmv

# Moved the downloaded csv here, if any.
[group('maintenance')]
@csvmv:
    if [[ -f $occsvsrc ]]; then mv $occsvsrc $csv; else echo "no new $occsvsrc found"; fi

# Regenerate and check journals, update readme reports
[group('maintenance')]
@update: _journal _accounts _check _readme

# Review the cli reports and opencollective budget page
[group('maintenance')]
@review: oc-budget
    hledger reports

# Commit all that's committable
[group('maintenance')]
@commit:
    -git commit -m "oc csv"   -- data/oc.csv
    -git commit -m "journals" -- *.journal
    -git commit -m "reports"  -- README.md

# All of the above. except opening the csv page.
[group('maintenance')]
@process:
    just csvmv update commit

# Publish latest commits
[group('maintenance')]
@push:
    git push

# steps

# Regenerate OC journal from OC csv
[group('steps')]
@_journal:
    ($hledger -f $csv --rules oc.csv.rules print -x --round=soft >.oc.journal && mv .oc.journal oc.journal) \
    || (rm -f .oc.journal; false)

# Declare any new accounts found, preserving existing declaration order
[group('steps')]
@_accounts:
    ((cat accounts.journal; $hledgerc accounts --undeclared --directives) >.accounts.journal && mv .accounts.journal accounts.journal) \
    || (rm -f .accounts.journal; false)

# Check the journal for problems
[group('steps')]
@_check:
    printf "checking journal.. "
    $hledgerc check $checks && echo "all ok ✅"

# Update reports in README.md
[group('steps')]
@_readme:
    $sed '/<!-- REPORTS:/q' README.md >.README.md
    hledger ytdrx -Ohtml >>.README.md
    hledger yrx -Ohtml >>.README.md
    hledger yal -Ohtml >>.README.md
    $sed -z 's/(<link[^>]+>)*<style>[^>]+>(<link[^>]+>)*/\n\n/g' <.README.md >README.md  # XXX remove HTML reports' CSS (handling hledger version variations)
    rm -f .README.md

# Preview the rendered readme
[group('steps')]
@_readme-preview:
    pandoc README.md -o .README.html && $open .README.html

# misc

# Report hours of review work per month.
[group('misc')]
@review-hours *ARGS:
    hledger -f $TIMELOG bal hl.review -M --transpose {{ ARGS }}

# Open the opencollective page, for invoicing.
[group('misc')]
@oc:
    $open 'https://opencollective.com/hledger'

# Open the opencollective expenses page, for approving.
[group('misc')]
@oc-expenses:
    $open 'https://opencollective.com/hledger/expenses'

# Show reports
[group('misc')]
@reports:
    hledger reports

# Open the opencollective page, budget section.
[group('misc')]
@oc-budget:
    $open 'https://opencollective.com/hledger#category-BUDGET'

# Open sm's liberapay ledger
[group('misc')]
@li-ledger:
    $open https://liberapay.com/simonmichael/ledger

# Open liberapay receiving page for sm
[group('misc')]
@li-rx-sm:
    $open https://liberapay.com/simonmichael/receiving

# Open liberapay receiving page for hledger
[group('misc')]
@li-rx-hledger:
    $open https://liberapay.com/hledger/receiving

# Download liberapay patrons as csv
[group('misc')]
@li-csv: _li-pub _li-active _li-all

# Download liberapay public active patrons
[group('misc')]
@_li-pub:
    wget -O data/liberapay-public-active-patrons-simonmichael-`date -I`.csv https://liberapay.com/simonmichael/patrons/public.csv

# Download liberapay active patrons
[group('misc')]
@_li-active:
    $open 'https://liberapay.com/simonmichael/patrons/export.csv?scope=active'
    read -p 'After successful download, press enter: '
    mv $downloads/liberapay-active-patrons-simonmichael-*.csv data

# Download liberapay patrons from last 10 years
[group('misc')]
@_li-all:
    $open 'https://liberapay.com/simonmichael/patrons/export.csv?scope=all'
    read -p 'After successful download, press enter: '
    mv $downloads/liberapay-patrons-simonmichael-*.csv data