build.gradle

plugins {
    id "java"
    id 'org.springframework.boot' version '3.3.0'
    id 'io.spring.dependency-management' version '1.1.5'
    id "com.diffplug.spotless" version "6.25.0"
    id "maven-publish"
}

group 'rocks.inspectit.gepard'

sourceCompatibility = "17"
targetCompatibility = "17"

// we don't have a main class
bootJar.enabled = false

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java

            versionMapping {
                allVariants {
                    fromResolutionResult()
                }
            }
        }
    }

    repositories {
        maven {
            name = "GitHubPackages"
            url = uri("https://maven.pkg.github.com/inspectIT/inspectit-gepard-config")
            credentials {
                username = System.getenv("GITHUB_ACTOR")
                password = System.getenv("GITHUB_TOKEN")
            }
        }
    }
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

spotless {
    java {
        importOrder()
        removeUnusedImports()
        googleJavaFormat()
        formatAnnotations()
        target("src/**/*.java")
        licenseHeader '/* (C) 2024 */'
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    annotationProcessor 'org.projectlombok:lombok'
}