Build executable with script load facility

[dmitrys99]

Hi!
I was wondered by Janet and its C integration, amazing work!
Found no example for such a scenario:

1. There is a main.janet which read/evaluate script:

(defn main [& args]
  (if (< (length args) 2)
    (do
      (print "Use: my_app <script.janet>")
      (os/exit 1)))

  (def script-path (get args 1))

  (print "[Janet Host]: Read external file: " script-path)
  
  (if (os/stat script-path)
    (let [script-content (slurp script-path)
          current-env (make-env)]
      (print "--------------------------------------------------")
      (eval-string script-content current-env)
      (print "--------------------------------------------------")
      (print "[Janet Host]: Done."))
    (print "[Janet Host]: Error: No file found!")))

2. There is an external function (the bunch of it, in fact, but single is enough to show), mylib1.c:

#include <janet.h>
#include <stdio.h>

static Janet c_do_thing1(int32_t argc, Janet *argv) {
    (void) argc; (void) argv;
    printf("[C mylib1]: Call from monolith binary!\n");
    return janet_wrap_nil();
}

static const JanetReg cfuns[] = {
    {"do-thing1", c_do_thing1, "(do-thing1)\n\nPrint from C."},
    {NULL, NULL, NULL}
};

JANET_MODULE_ENTRY(JanetTable *env) {
    printf("[C mylib1]: entry!\n");
    janet_cfuns(env, "mylib1", cfuns);
}

3. Project 'project.janet':

(declare-project
  :name "my-static-app"
  :author "Developer")

(def m1
  (declare-native
    :name "mylib1"
    :source @["mylib1.c"]))

(declare-executable
  :name "myexec"
  :entry "main.janet"
  :deps [(m1 :static)])

4. Script script.janet

#(import mylib1 :export true) 

(print "[External File]: On air!")
(print "[External File]: call (do-thing1):")

(do-thing1)

(print "[External File]: End")

5. Run

./build/myexec ./script.janet

Error:

error: unknown symbol do-thing1
  in eval [boot.janet] on line 2793, column 5
  in eval-string [boot.janet] on line 2831, column 36
  in main [main.janet] on line 15, column 7

Q1: How to deal with it?

I want do-thing1 to be linked to static binary and to call it from outer script.

Q2: If I declare (defn foo ...) in main.janet, it is not found in a script as well.

Probably I do something wrong, but have no idea what exactly is wrong.

Thanks!

[sogaiu]

Does this help?

(use mylib1)

# trick from: https://github.com/janet-lang/janet/discussions/1619
(def my-env (curenv))

(defn main [& args]
  (if (< (length args) 2)
    (do
      (print "Use: my_app <script.janet>")
      (os/exit 1)))

  (def script-path (get args 1))

  (print "[Janet Host]: Read external file: " script-path)
  
  (if (os/stat script-path)
    (do
      (print "--------------------------------------------------")
      (dofile script-path :env my-env)
      (print "--------------------------------------------------")
      (print "[Janet Host]: Done."))
    (print "[Janet Host]: Error: No file found!")))

Seems to work here:

$ jpm clean && jpm build
$ ./build/myexec script.janet 
[C mylib1]: entry!
[Janet Host]: Read external file: script.janet
--------------------------------------------------
[External File]: On air!
[External File]: call (do-thing1):
[C mylib1]: Call from monolith binary!
[External File]: End
--------------------------------------------------
[Janet Host]: Done.

In case the static bits don't work, possibly this might be worth investigating.

[dmitrys99]

Amazing! Works like a charm!

Thank you!

[dmitrys99]

It may be good sample application. I can manage addition. Please give a hint where to put files, I'll cleanup source and add README and create PR.

[veqqq]

@dmitrys99 by the way, https://janet.zulipchat.com/ is the normal place for Janet discussion in case you want to read/check other community stuff. Welcome!