build.gradle

group 'org.openkoreantext'
version '5.4.0.2'

apply plugin: 'java'

sourceCompatibility = 1.8

repositories {
    mavenCentral()
}

configurations {
    distJars {
        extendsFrom runtime
    }
}

ext {
    elasticsearchVersion = '5.4.0'
    openKoreanTextVersion = '2.0.1'
}

test {
    jvmArgs '-Dtests.security.manager=false'
}

dependencies {
    compile group: 'org.openkoreantext', name: 'open-korean-text', version: openKoreanTextVersion

    compileOnly group: 'org.elasticsearch', name: 'elasticsearch', version: elasticsearchVersion

    testCompile group: 'org.elasticsearch.test', name: 'framework', version: elasticsearchVersion
    testCompile group: 'org.apache.logging.log4j', name: 'log4j-api', version: '2.7'
    testCompile group: 'org.apache.logging.log4j', name: 'log4j-core', version: '2.7'
}

task makePluginDescriptor(type: Copy) {
    from 'src/main/resources'
    into 'build/tmp/plugin'
    expand([
        'descriptor': [
            'name': 'elasticserach-analysis-openkoreantext',
            'classname': 'org.elasticsearch.plugin.analysis.openkoreantext.AnalysisOpenKoreanTextPlugin',
            'description': 'Korean analysis plugin integrates open-korean-text module into elasticsearch.',
            'version': '1.0.0',
            'javaVersion': sourceCompatibility,
            'elasticsearchVersion' : '5.4.0'
        ]
    ])
}

task buildPluginZip(type: Zip, dependsOn: [':jar', ':makePluginDescriptor']) {
    from configurations.distJars
    from jar.archivePath
    from 'build/tmp/plugin'
    into 'elasticsearch'
    classifier = 'plugin'
}

build.finalizedBy(buildPluginZip)


task wrapper(type: Wrapper) {
    gradleVersion = '3.4'
}