v0.0.1

Author: mirek

.gitignore

@@ -0,0 +1,2 @@
+npm-debug.log
+node_modules

.tm_properties

@@ -0,0 +1,3 @@
+excludeInFileChooser = "{$excludeInFileChooser,node_modules}"
+excludeInBrowser = "{$excludeInBrowser}"
+excludeInFolderSearch = "{$excludeInFolderSearch,node_modules}"

Gruntfile.coffee

@@ -0,0 +1,33 @@
+
+module.exports = (grunt) ->
+  grunt.loadNpmTasks 'grunt-mocha-test'
+  grunt.loadNpmTasks 'grunt-contrib-coffee'
+  grunt.loadNpmTasks 'grunt-contrib-watch'
+  grunt.loadNpmTasks 'grunt-codo'
+
+  grunt.initConfig
+    pkg: grunt.file.readJSON("package.json")
+
+    coffee:
+      compile:
+        files:
+          'lib/index.js': 'src/index.coffee'
+
+    watch:
+      coffee:
+        files: ['src/index.coffee'],
+        tasks: ['coffee']
+
+    mochaTest:
+      test:
+        options:
+          reporter: 'spec'
+          require: [
+            'coffee-script'
+          ]
+        src: ['spec/**/*.coffee']
+
+  grunt.registerTask 'doc', ['codo']
+  grunt.registerTask 'test', ['mochaTest']
+  grunt.registerTask "compile", ["coffee"]
+  grunt.registerTask "default", ["compile"]

README.md

@@ -0,0 +1,3 @@
+#!/bin/bash
+
+`dirname $0`/../node_modules/coffee-script/bin/coffee $@

bin/coffee

@@ -0,0 +1,3 @@
+#!/bin/bash
+
+`dirname $0`/../node_modules/grunt-cli/bin/grunt $@

bin/grunt

@@ -0,0 +1,35 @@
+{
+  "name": "rus-diff",
+  "version": "0.0.1",
+  "description": "MongoDB compatible JSON diff.",
+  "main": "lib/index.js",
+  "scripts": {
+    "test": "bin/grunt test"
+  },
+  "repository": {
+    "type": "git",
+    "url": "git://github.com/mirek/node-rus-diff.git"
+  },
+  "keywords": [
+    "json",
+    "diff",
+    "mongo",
+    "mongodb"
+  ],
+  "author": "Mirek Rusin http://github.com/mirek",
+  "license": "MIT",
+  "bugs": {
+    "url": "https://github.com/mirek/node-rus-diff/issues"
+  },
+  "homepage": "https://github.com/mirek/node-rus-diff",
+  "devDependencies": {
+    "grunt-mocha-test": "^0.9.4",
+    "mocha": "^1.17.1",
+    "grunt-cli": "^0.1.13",
+    "grunt": "^0.4.3",
+    "coffee-script": "^1.7.1",
+    "grunt-contrib-coffee": "^0.10.1",
+    "grunt-codo": "^0.1.0",
+    "grunt-contrib-watch": "^0.5.3"
+  }
+}

lib/index.js

@@ -0,0 +1,46 @@
+assert = require 'assert'
+{rusDiff} = require '../src'
+
+describe 'rusDiff', ->
+  it 'should produce no difference', ->
+    assert.deepEqual {}, rusDiff {}, {}
+
+  it 'should produce scoped diff', ->
+    a =
+      foo:
+        bb:
+          inner:
+            this_is_a: 1
+            to_rename: "Hello"
+        aa: 1
+      bar: 1
+      replace_me: 1
+
+    b =
+      foo:
+        bb:
+          inner:
+            this_is_b: 2
+        cc:
+          new_val: 2
+      bar2: 2
+      zz: 2
+      renamed: "Hello"
+      replace_me: 2
+
+    r =
+      $rename:
+        "my.value.foo.bb.inner.to_rename": "my.value.renamed"
+      $unset:
+        "my.value.bar": true
+        "my.value.foo.aa": true
+        "my.value.foo.bb.inner.this_is_a": true
+      $set:
+        "my.value.bar2": 2
+        "my.value.foo.bb.inner.this_is_b": 2
+        "my.value.foo.cc":
+          new_val: 2
+        "my.value.replace_me": 2
+        "my.value.zz": 2
+
+    assert.deepEqual r, rusDiff a, b, ['my', 'value']

package.json

@@ -0,0 +1,101 @@
+
+# Difference between JSON objects.
+#
+# @param [Object] a
+# @param [Object] b
+# @param [Array] stack Optional scope.
+# @param [Boolean] rename Internal
+# @param [Object] garbage Internal
+#
+# @return [Object] Difference between b - a JSON objects.
+#
+rusDiff = (a, b, stack = [], rename = true, garbage = {}) ->
+
+  # Sorted lists of keys.
+  aKeys = Object.keys(a).sort()
+  bKeys = Object.keys(b).sort()
+
+  # Number of keys.
+  aN = aKeys.length
+  bN = bKeys.length
+
+  # Key indices.
+  aI = 0
+  bI = 0
+
+  # Result.
+  rus =
+    $rename: {}
+    $unset: {}
+    $set: {}
+
+  # Unset 
+  unsetA = (i) ->
+    key = (stack.concat aKeys[i]).join('.')
+    rus.$unset[key] = true
+    (garbage[ a[aKeys[i]] ] ||= []).push key
+
+  setB = (i) ->
+    key = (stack.concat bKeys[i]).join('.')
+    rus.$set[key] = b[bKeys[i]]
+
+  while (aI < aN) and (bI < bN)
+    aKey = aKeys[aI]
+    bKey = bKeys[bI]
+
+    if aKey is bKey
+      aVal = a[aKey]
+      bVal = b[bKey]
+      if aVal isnt bVal
+        if (typeof aVal is 'object') and (typeof bVal is 'object')
+          for k, v of rusDiff(aVal, bVal, stack.concat([aKey]), false, garbage)
+
+            # Merge changes
+            for k2, v2 of v
+              rus[k][k2] = v2
+        else
+
+          # At least one is not an Object (hash), b overwrites a.
+          #
+          # NOTE: aVal doesn't go to garbage (as a potential rename) because MongoDB 2.4.x doesn't allow $set
+          #       and $rename for the same key paths giving MongoDB error 10150: "exception: Field name duplication
+          #       not allowed with modifiers"
+          setB bI
+      ++aI
+      ++bI
+    else
+      if aKey < bKey
+        unsetA aI
+        ++aI
+      else
+        setB bI
+        ++bI
+
+  # Finish remaining a keys if any left.
+  while aI < aN
+    unsetA aI++
+
+  # Finish remaining b keys if any left.
+  while bI < bN
+    setB bI++
+
+  if rename
+
+    # Diff has been completed, root invocation wants to do the rename, collect from garbage
+    # whatever we can.
+    collect = ([k, key] for k, v of rus.$set when garbage[v]? and (key = garbage[v].pop()))
+    for e in collect
+      [k, key] = e
+      rus.$rename[key] = k
+      delete rus.$unset[key]
+      delete rus.$set[k]
+
+  # Return non-empty modifications only.
+  for k of rus
+    if Object.keys(rus[k]).length is 0
+      delete rus[k]
+
+  rus
+
+if module? and module.exports?
+  module.exports.rusDiff = rusDiff