What's the correct way to render a response from a Promise? #2058

hussam-qasem · 2023-04-13T03:47:02Z

hussam-qasem
Apr 13, 2023

In Mojolicious, what's the correct way to render a response from a Promise? In my code below, I get:

[2023-04-12] [trace] Template "example/search.html.ep" not found
[2023-04-12] [trace] Nothing has been rendered, expecting delayed response

Why is it looking for example/search.html.ep? I didn't ask for it.
I am rendering content... Mojo couldn't wait?

Sample app:

1. `script/my_app`

#!/usr/bin/env perl

use strict;
use warnings;

use Mojo::File qw(curfile);
use lib curfile->dirname->sibling('lib')->to_string;
use Mojolicious::Commands;

Mojolicious::Commands->start_app('MyApp');

2. `lib/MyApp.pm`

package MyApp;
use Mojo::Base 'Mojolicious', -signatures;

sub startup ($self) {
    $self->secrets('s3cret');
    my $r = $self->routes;
    $r->get('/')->to('Example#index');
    $r->post('/')->to('Example#search');
}

1;

3. `lib/MyApp/Controller/Example.pm`

package MyApp::Controller::Example;
use Mojo::Base 'Mojolicious::Controller', -signatures;

sub index ($self)
{
    return $self->render(inline => '<html><body><form method="post"><textarea name="numbers" maxlength="11">123</textarea><button type="submit">Go</button></form></body></html>');
}

sub search ($self)
{
    my $v = $self->validation;
    $v->required("numbers");
    return $self->render(text=>"Validation Error") if $v->has_error;
    my $numbers = $v->param("numbers");
    my @numbers = split(/\r?\n/, $numbers);

    Mojo::Promise
    ->map(
    {concurrency => 2},
    sub {
        $self->ua->get_p("https://httpbin.org/delay/1?q=$_" => {'api-key'=>'shhh'});
    }, @numbers)
    ->then(
    sub{
        my @results = @_;
        my @json = map { $_->[0]->res->json } @results;
        return $self->render(json => \@json);
    })
    ->catch(
    sub {
        my $err = shift;
        return $self->render(text => $err);
    })
    ->wait;
    #return $self->render(text => "This shall result is 'Unhandled rejected promise: A response has already been rendered'");
}

1;

Answered by guest20

Apr 13, 2023

if you don't $c->render_later, Mojo does an auto-render using the action name as the template name.

View full answer

guest20 · 2023-04-13T11:25:38Z

guest20
Apr 13, 2023

if you don't $c->render_later, Mojo does an auto-render using the action name as the template name.

0 replies

hussam-qasem · 2023-04-13T13:17:47Z

hussam-qasem
Apr 13, 2023
Author

Thank you. And I assume wait is useless in my example.

4 replies

jberger Apr 13, 2023
Maintainer

Thank you. And I assume wait is useless in my example.

Within a Mojolicious webapp the ioloop is already running (in most cases) so yes, the wait does nothing. Wait is good for a toplevel promise in a script say

guest20 Apr 13, 2023

to me, It feels like returning a pending promise should be enough to signal that one intends to render_later (i think i saw a patch for that a while ago?)

... does this happen because wait doesn't/can't return the promise?

kraih Apr 13, 2023
Maintainer

The answer for why we don't do the obvious thing is usually backwards compatibility.

guest20 Apr 14, 2023

compatibility would have been my second guess.

Also $r->get_p("/")->... does look kinda goofy.

Provide feedback

Saved searches

Use saved searches to filter your results more quickly

What's the correct way to render a response from a Promise? #2058

{{title}}

Replies: 2 comments 4 replies

{{title}}

{{title}}

{{title}}

{{title}}

{{title}}

{{title}}

Select a reply

What's the correct way to render a response from a Promise? #2058

hussam-qasem Apr 13, 2023

1. script/my_app

2. lib/MyApp.pm

3. lib/MyApp/Controller/Example.pm

Replies: 2 comments · 4 replies

guest20 Apr 13, 2023

hussam-qasem Apr 13, 2023 Author

jberger Apr 13, 2023 Maintainer

guest20 Apr 13, 2023

kraih Apr 13, 2023 Maintainer

guest20 Apr 14, 2023

hussam-qasem
Apr 13, 2023

1. `script/my_app`

2. `lib/MyApp.pm`

3. `lib/MyApp/Controller/Example.pm`

Replies: 2 comments 4 replies

guest20
Apr 13, 2023

hussam-qasem
Apr 13, 2023
Author

jberger Apr 13, 2023
Maintainer

kraih Apr 13, 2023
Maintainer