build.gradle

plugins {
    id "spring.jdbc.plus.java-conventions"
    id "spring.jdbc.plus.spring-bom-conventions"
    id "groovy"
}

compileGroovy {
    options.encoding = "UTF-8"
    groovyOptions.encoding = "UTF-8"
}

if (project.convention.findPlugin(JavaPluginConvention)) {
    // Change the output directory for the main and test source sets back to the old path
    sourceSets.main.java.destinationDirectory = new File(buildDir, "classes/main")
    sourceSets.main.groovy.destinationDirectory = new File(buildDir, "classes/main")
    sourceSets.test.java.destinationDirectory = new File(buildDir, "classes/test")
    sourceSets.test.groovy.destinationDirectory = new File(buildDir, "classes/test")
}

tasks.withType(GroovyCompile).configureEach {
    dependsOn = []
    options.compilerArgs << '-parameters'
    options.generatedSourceOutputDirectory = project.file("src/main/generated")
}

sourceSets {
    main {
        java { srcDirs = [] }
        groovy { srcDirs += ["src/main/java"] }
    }
}

dependencies {
    implementation("org.springframework.boot:spring-boot-starter-web")
    implementation project(":spring-boot-starter-data-jdbc-plus-sql")
    implementation("org.springframework.boot:spring-boot-starter-actuator")
    implementation('org.codehaus.groovy:groovy:3.0.23')
    implementation("com.h2database:h2")

    implementation("org.springframework.data:spring-data-jdbc")
    implementation("org.springframework.data:spring-data-relational")
    implementation("org.springframework.data:spring-data-commons")

    implementation project(":spring-data-plus-sql-gen")
    annotationProcessor project(":spring-data-plus-sql-gen")
    annotationProcessor("org.springframework.data:spring-data-jdbc")
    annotationProcessor("org.springframework.data:spring-data-relational")
    annotationProcessor("org.springframework.data:spring-data-commons")

    compileOnly("org.projectlombok:lombok")
    annotationProcessor("org.projectlombok:lombok")

    testImplementation("org.springframework.boot:spring-boot-starter-test")
    testCompileOnly("org.projectlombok:lombok")
    testAnnotationProcessor("org.projectlombok:lombok")
}