Equiv.v

(** * Equiv: Program Equivalence *)

Set Warnings "-notation-overridden,-parsing,-deprecated-hint-without-locality".
From PLF Require Import Maps.
From Coq Require Import Bool.
From Coq Require Import Arith.
From Coq Require Import Init.Nat.
From Coq Require Import PeanoNat. Import Nat.
From Coq Require Import EqNat.
From Coq Require Import Lia.
From Coq Require Import List. Import ListNotations.
From Coq Require Import FunctionalExtensionality.
From PLF Require Export Imp.
Set Default Goal Selector "!".

(** *** Before You Get Started:

    - Create a fresh directory for this volume. (Do not try to mix the
      files from this volume with files from _Logical Foundations_ in
      the same directory: the result will not make you happy.)  You
      can either start with an empty directory and populate it with
      the files listed below, or else download the whole PLF zip file
      and unzip it.

    - The new directory should contain at least the following files:
         - [Imp.v] (make sure it is the one from the PLF distribution,
           not the one from LF: they are slightly different);
         - [Maps.v] (ditto)
         - [Equiv.v] (this file)
         - [_CoqProject], containing the following line:

           -Q . PLF

    - If you see errors like this...

             Compiled library PLF.Maps (in file
             /Users/.../plf/Maps.vo) makes inconsistent assumptions
             over library Coq.Init.Logic

      ... it may mean something went wrong with the above steps.
      Doing "[make clean]" (or manually removing everything except
      [.v] and [_CoqProject] files) may help.

    - If you are using VSCode with the VSCoq extension, you'll then
      want to open a new window in VSCode, click [Open Folder > plf],
      and run [make].  If you get an error like "Cannot find a
      physical path..." error, it may be because you didn't open plf
      directly (you instead opened a folder containing both lf and
      plf, for example). *)

(** *** Advice for Working on Exercises:

    - Most of the Coq proofs we ask you to do in this chapter are
      similar to proofs that we've provided.  Before starting to work
      on exercises, take the time to work through our proofs (both
      informally and in Coq) and make sure you understand them in
      detail.  This will save you a lot of time.

    - The Coq proofs we're doing now are sufficiently complicated that
      it is more or less impossible to complete them by random
      experimentation or following your nose.  You need to start with
      an idea about why the property is true and how the proof is
      going to go.  The best way to do this is to write out at least a
      sketch of an informal proof on paper -- one that intuitively
      convinces you of the truth of the theorem -- before starting to
      work on the formal one.  Alternately, grab a friend and try to
      convince them that the theorem is true; then try to formalize
      your explanation.

    - Use automation to save work!  The proofs in this chapter can get
      pretty long if you try to write out all the cases explicitly. *)

(* ################################################################# *)
(** * Behavioral Equivalence *)

(** In an earlier chapter, we investigated the correctness of a very
    simple program transformation: the [optimize_0plus] function.  The
    programming language we were considering was the first version of
    the language of arithmetic expressions -- with no variables -- so
    in that setting it was very easy to define what it means for a
    program transformation to be correct: it should always yield a
    program that evaluates to the same number as the original.

    To talk about the correctness of program transformations for the
    full Imp language -- in particular, assignment -- we need to
    consider the role of mutable state and develop a more
    sophisticated notion of correctness, which we'll call _behavioral
    equivalence_. *)

(** For example:
      - [X + 2] is behaviorally equivalent to [1 + X + 1]
      - [X - X] is behaviorally equivalent to [0]
    (* TODO *)  - [(X - 1) + 1] is _not_ behaviorally equivalent to [X]   *)

(* ================================================================= *)
(** ** Definitions *)

(** For [aexp]s and [bexp]s with variables, the definition we want is
    clear: Two [aexp]s or [bexp]s are "behaviorally equivalent" if
    they evaluate to the same result in every state. *)

Definition aequiv (a1 a2 : aexp) : Prop :=
  forall (st : state),
    aeval st a1 = aeval st a2.

Definition bequiv (b1 b2 : bexp) : Prop :=
  forall (st : state),
    beval st b1 = beval st b2.

(** Here are some simple examples of equivalences of arithmetic
    and boolean expressions. *)

Theorem aequiv_example:
  aequiv
    <{ X - X }>
    <{ 0 }>.
Proof.
  intros st. simpl. lia.
Qed.

Theorem bequiv_example:
  bequiv
    <{ X - X = 0 }>
    <{ true }>.
Proof.
  intros st. unfold beval.
  rewrite aequiv_example. reflexivity.
Qed.

(** For commands, the situation is a little more subtle.  We
    can't simply say "two commands are behaviorally equivalent if they
    evaluate to the same ending state whenever they are started in the
    same initial state," because some commands, when run in some
    starting states, don't terminate in any final state at all!

    What we need instead is this: two commands are behaviorally
    equivalent if, for any given starting state, they either (1) both
    diverge or (2) both terminate in the same final state.  A compact
    way to express this is "if the first one terminates in a
    particular state then so does the second, and vice versa." *)

Definition cequiv (c1 c2 : com) : Prop :=
  forall (st st' : state),
    (st =[ c1 ]=> st') <-> (st =[ c2 ]=> st').

(** We can also define an asymmetric variant of this relation: We say
    that [c1] _refines_ [c2] if they produce the same final states
    _when [c1] terminates_ (but [c1] may not terminate in some cases
    where [c2] does). *)

Definition refines (c1 c2 : com) : Prop :=
  forall (st st' : state),
    (st =[ c1 ]=> st') -> (st =[ c2 ]=> st').

(* ================================================================= *)
(** ** Simple Examples *)

(** For examples of command equivalence, let's start by looking at
    a trivial program equivalence involving [skip]: *)

Theorem skip_left : forall c,
  cequiv
    <{ skip; c }>
    c.
Proof.
  (* WORKED IN CLASS *)
  intros c st st'.
  split; intros H.
  - (* -> *)
    inversion H. subst.
    inversion H2. subst.
    assumption.
  - (* <- *)
    apply E_Seq with st.
    + apply E_Skip.
    + assumption.
Qed.

(** **** Exercise: 2 stars, standard (skip_right)

    Prove that adding a [skip] after a command results in an
    equivalent program *)

Theorem skip_right : forall c,
  cequiv
    <{ c ; skip }>
    c.
Proof.
  intros c st st'. split; intros H.
  - inversion H. subst. inversion H5. subst. assumption.
  - apply E_Seq with st'.
    * assumption. 
    * constructor.
Qed.

(** [] *)

(** Similarly, here is a simple equivalence that optimizes [if]
    commands: *)

Theorem if_true_simple : forall c1 c2,
  cequiv
    <{ if true then c1 else c2 end }>
    c1.
Proof.
  intros c1 c2.
  split; intros H.
  - (* -> *)
    inversion H; subst.
    + assumption.
    + discriminate.
  - (* <- *)
    apply E_IfTrue.
    + reflexivity.
    + assumption.  Qed.

(** Of course, no (human) programmer would write a conditional whose
    condition is literally [true].  But they might write one whose
    condition is _equivalent_ to true:

    _Theorem_: If [b] is equivalent to [true], then [if b then c1
    else c2 end] is equivalent to [c1].
   _Proof_:

     - ([->]) We must show, for all [st] and [st'], that if [st =[
       if b then c1 else c2 end ]=> st'] then [st =[ c1 ]=> st'].

       Proceed by cases on the rules that could possibly have been
       used to show [st =[ if b then c1 else c2 end ]=> st'], namely
       [E_IfTrue] and [E_IfFalse].

       - Suppose the final rule in the derivation of [st =[ if b
         then c1 else c2 end ]=> st'] was [E_IfTrue].  We then have,
         by the premises of [E_IfTrue], that [st =[ c1 ]=> st'].
         This is exactly what we set out to prove.

       - On the other hand, suppose the final rule in the derivation
         of [st =[ if b then c1 else c2 end ]=> st'] was [E_IfFalse].
         We then know that [beval st b = false] and [st =[ c2 ]=> st'].

         Recall that [b] is equivalent to [true], i.e., forall [st],
         [beval st b = beval st <{true}> ].  In particular, this means
         that [beval st b = true], since [beval st <{true}> = true].  But
         this is a contradiction, since [E_IfFalse] requires that
         [beval st b = false].  Thus, the final rule could not have
         been [E_IfFalse].

     - ([<-]) We must show, for all [st] and [st'], that if
       [st =[ c1 ]=> st'] then
       [st =[ if b then c1 else c2 end ]=> st'].

       Since [b] is equivalent to [true], we know that [beval st b] =
       [beval st <{true}> ] = [true].  Together with the assumption that
       [st =[ c1 ]=> st'], we can apply [E_IfTrue] to derive
       [st =[ if b then c1 else c2 end ]=> st'].  []

   Here is the formal version of this proof: *)

Theorem if_true: forall b c1 c2,
  bequiv b <{true}>  ->
  cequiv
    <{ if b then c1 else c2 end }>
    c1.
Proof.
  intros b c1 c2 Hb.
  split; intros H.
  - (* -> *)
    inversion H; subst.
    + (* b evaluates to true *)
      assumption.
    + (* b evaluates to false (contradiction) *)
      unfold bequiv in Hb. simpl in Hb.
      rewrite Hb in H5.
      discriminate.
  - (* <- *)
    apply E_IfTrue; try assumption.
    unfold bequiv in Hb. simpl in Hb.
    apply Hb. Qed.

(** **** Exercise: 2 stars, standard, especially useful (if_false) *)
Theorem if_false : forall b c1 c2,
  bequiv b <{false}> ->
  cequiv
    <{ if b then c1 else c2 end }>
    c2.
Proof.
  intros b c1 c2 Hb. split; intros H.
  - inversion H; subst.
    * unfold bequiv in Hb. simpl in Hb. rewrite Hb in H5. discriminate H5.
    * assumption.
  - apply E_IfFalse.
    * unfold bequiv in Hb. simpl in Hb. apply Hb.
    * assumption.
Qed.

(** [] *)

(** **** Exercise: 3 stars, standard (swap_if_branches)

    Show that we can swap the branches of an [if] if we also negate its
    condition. *)

Theorem swap_if_branches : forall b c1 c2,
  cequiv
    <{ if b then c1 else c2 end }>
    <{ if ~ b then c2 else c1 end }>.
Proof.
  intros b c1 c2. split; intros H.
  - inversion H; subst;
    [apply E_IfFalse | apply E_IfTrue]; 
    try assumption;
    simpl; rewrite H5; reflexivity.
  - inversion H; subst; [apply E_IfFalse | apply E_IfTrue]; try assumption;
    simpl in H5; [apply negb_true_iff | apply negb_false_iff]; assumption.
Qed.

(** [] *)

(** For [while] loops, we can give a similar pair of theorems.  A loop
    whose guard is equivalent to [false] is equivalent to [skip],
    while a loop whose guard is equivalent to [true] is equivalent to
    [while true do skip end] (or any other non-terminating program). *)

(** The first of these facts is easy. *)

Theorem while_false : forall b c,
  bequiv b <{false}> ->
  cequiv
    <{ while b do c end }>
    <{ skip }>.
Proof.
  intros b c Hb. split; intros H.
  - (* -> *)
    inversion H; subst.
    + (* E_WhileFalse *)
      apply E_Skip.
    + (* E_WhileTrue *)
      rewrite Hb in H2. discriminate.
  - (* <- *)
    inversion H. subst.
    apply E_WhileFalse.
    apply Hb.  
Qed.

(** **** Exercise: 2 stars, advanced, optional (while_false_informal)

    Write an informal proof of [while_false].

(* FILL IN HERE *)
  _Theorem_: If [b] is equivalent to [false] then [while b do c end] is equivalent to [skip].
  _Proof_:
    We wish to show that for any starting state [st] and some ending state [st'], 
    we have that [st =[ while b do c end ]=> st'] and [st =[ skip ]=> st'].
    Note that if [b] is equivalent to [false] then we have that [b] evaluates to [false]. 
    We proceed by cases on the rules that could have possibly been used to show 
    [st =[ while b do c end ]=> st']. Namely, [E_WhileFalse] and [E_WhileTrue].
             
             - Suppose [E_WhileFalse] is the final inference rule in the derivation of [st =[ while b do c end ]=> st'].
               We have that by the premises of [E_WhileFalse] we have that [st =[ while b do c end ]=> st].
               I.e., [st = st'] by [ceval_deterministic]. Furthermore, by definition [st =[ skip ]=> st] and so,
               We have that in the same starting state, both commands end in the same final state which is what we wished to prove.
             
             - Now suppose that [E_WhileTrue] is the final inference rule in the derivation.
               We have by the premises of [E_WhileTrue] that [b] evaluates to [true]. However, by assumption [b] evaluates to [false] so this yields a contradiction.
               Therefore, [E_WhileTrue] could not be the final inference rule.
   
   Therefore if [b] is equivalent to [false] then [while b do c end] is equivalent to [skip].
  
*)
(** [] *)

(** To prove the second fact, we need an auxiliary lemma stating that
    [while] loops whose guards are equivalent to [true] never
    terminate. *)

(** _Lemma_: If [b] is equivalent to [true], then it cannot be
    the case that [st =[ while b do c end ]=> st'].

    _Proof_: Suppose that [st =[ while b do c end ]=> st'].  We show,
    by induction on a derivation of [st =[ while b do c end ]=> st'],
    that this assumption leads to a contradiction. The only two cases
    to consider are [E_WhileFalse] and [E_WhileTrue], the others
    are contradictory.

    - Suppose [st =[ while b do c end ]=> st'] is proved using rule
      [E_WhileFalse].  Then by assumption [beval st b = false].  But
      this contradicts the assumption that [b] is equivalent to
      [true].

    - Suppose [st =[ while b do c end ]=> st'] is proved using rule
      [E_WhileTrue].  We must have that:

      1. [beval st b = true],
      2. there is some [st0] such that [st =[ c ]=> st0] and
         [st0 =[ while b do c end ]=> st'],
      3. and we are given the induction hypothesis that
         [st0 =[ while b do c end ]=> st'] leads to a contradiction,

      We obtain a contradiction by 2 and 3. [] *)

Lemma while_true_nonterm : forall b c st st',
  bequiv b <{true}> ->
  ~( st =[ while b do c end ]=> st' ).
Proof.
  (* WORKED IN CLASS *)
  intros b c st st' Hb.
  intros H.
  remember <{ while b do c end }> as cw eqn:Heqcw.
  induction H;
  (* Most rules don't apply; we rule them out by inversion: *)
  inversion Heqcw; subst; clear Heqcw.
  (* The two interesting cases are the ones for while loops: *)
  - (* E_WhileFalse *) (* contradictory -- b is always true! *)
    unfold bequiv in Hb.
    (* [rewrite] is able to instantiate the quantifier in [st] *)
    rewrite Hb in H. discriminate.
  - (* E_WhileTrue *) (* immediate from the IH *)
    apply IHceval2. reflexivity.  
Qed.

(** **** Exercise: 2 stars, standard, optional (while_true_nonterm_informal)

    Explain what the lemma [while_true_nonterm] means in English.

(* FILL IN HERE *)
The lemma means that if the condition for the while loop is always true, then the loop won't terminate.
Specifically, it won't evaluate to a final state because it will continue forever without emitting a final state.
*)
(** [] *)

(** **** Exercise: 2 stars, standard, especially useful (while_true)

    Prove the following theorem. _Hint_: You'll want to use
    [while_true_nonterm] here. *)

Theorem while_true : forall b c,
  bequiv b <{true}>  ->
  cequiv
    <{ while b do c end }>
    <{ while true do skip end }>.
Proof.
  intros b c Hb. split; intros H.
  - apply (while_true_nonterm b c st st') in Hb. contradiction.
  - assert ((bequiv BTrue <{ true }>)) as HTrue. { unfold bequiv. auto. }
    apply (while_true_nonterm BTrue <{ skip }> st st') in HTrue.
    apply HTrue in H. 
    contradiction.
Qed.

(** [] *)

(** A more interesting fact about [while] commands is that any number
    of copies of the body can be "unrolled" without changing meaning.

    Loop unrolling is an important transformation in any real
    compiler: its correctness is of more than academic interest! *)

Theorem loop_unrolling : forall b c,
  cequiv
    <{ while b do c end }>
    <{ if b then c ; while b do c end else skip end }>.
Proof.
  (* WORKED IN CLASS *)
  intros b c st st'.
  split; intros Hce.
  - (* -> *)
    inversion Hce; subst.
    + (* loop doesn't run *)
      apply E_IfFalse.
      * assumption.
      * apply E_Skip.
    + (* loop runs *)
      apply E_IfTrue.
      * assumption.
      * apply E_Seq with (st' := st'0).
        -- assumption.
        -- assumption.
  - (* <- *)
    inversion Hce; subst.
    + (* loop runs *)
      inversion H5; subst.
      apply E_WhileTrue with (st' := st'0).
      * assumption.
      * assumption.
      * assumption.
    + (* loop doesn't run *)
      inversion H5; subst. apply E_WhileFalse. assumption.  Qed.

(** **** Exercise: 2 stars, standard, optional (seq_assoc) *)
Theorem seq_assoc : forall c1 c2 c3,
  cequiv <{(c1;c2);c3}> <{c1;(c2;c3)}>.
Proof.
  intros c1 c2 c3 st st'. split; intros H; inversion H; subst.
  - inversion H2. subst.
    apply E_Seq with st'1; try assumption.
    apply E_Seq with st'0; try assumption.
  - inversion H5. subst.
    apply E_Seq with st'1.
    * apply E_Seq with st'0; assumption.
    * assumption.
Qed.

(** [] *)

(** Proving program properties involving assignments is one place
    where the fact that program states are treated extensionally
    (e.g., [x !-> m x ; m] and [m] are equal maps) comes in handy. *)

Theorem identity_assignment : forall x,
  cequiv
    <{ x := x }>
    <{ skip }>.
Proof.
  intros.
  split; intro H; inversion H; subst; clear H.
  - (* -> *)
    rewrite t_update_same.
    apply E_Skip.
  - (* <- *)
    assert (Hx : st' =[ x := x ]=> (x !-> st' x ; st')).
    { apply E_Asgn. reflexivity. }
    rewrite t_update_same in Hx.
    apply Hx.
Qed.

(** **** Exercise: 2 stars, standard, especially useful (assign_aequiv) *)
Theorem assign_aequiv : forall (X : string) (a : aexp),
  aequiv <{ X }> a ->
  cequiv <{ skip }> <{ X := a }>.
Proof.
  intros X a H st st'. 
  split; intros H2; inversion H2; subst;
  unfold aequiv in H; simpl in H.
  - assert (Heval : st' =[ X := a ]=> (X !-> st' X; st')).
    { apply E_Asgn. symmetry. apply H. }
    rewrite t_update_same in Heval.
    exact Heval.
  - rewrite <- (H st). rewrite t_update_same. apply E_Skip.
Qed.

(** [] *)

(** **** Exercise: 2 stars, standard (equiv_classes) *)

(** Given the following programs, group together those that are
    equivalent in Imp. Your answer should be given as a list of lists,
    where each sub-list represents a group of equivalent programs. For
    example, if you think programs (a) through (h) are all equivalent
    to each other, but not to (i), your answer should look like this:

       [ [prog_a;prog_b;prog_c;prog_d;prog_e;prog_f;prog_g;prog_h] ;
         [prog_i] ]

    Write down your answer below in the definition of
    [equiv_classes]. *)

Definition prog_a : com :=
  <{ while X > 0 do
       X := X + 1
     end }>.

Definition prog_b : com :=
  <{ if (X = 0) then
       X := X + 1;
       Y := 1
     else
       Y := 0
     end;
     X := X - Y;
     Y := 0 }>.

Definition prog_c : com :=
  <{ skip }> .

Definition prog_d : com :=
  <{ while X <> 0 do
       X := (X * Y) + 1
     end }>.

Definition prog_e : com :=
  <{ Y := 0 }>.

Definition prog_f : com :=
  <{ Y := X + 1;
     while X <> Y do
       Y := X + 1
     end }>.

Definition prog_g : com :=
  <{ while true do
       skip
     end }>.

Definition prog_h : com :=
  <{ while X <> X do
       X := X + 1
     end }>.

Definition prog_i : com :=
  <{ while X <> Y do
       X := Y + 1
     end }>.

Ltac map_equal_assert := apply functional_extensionality; intros x; destruct (string_dec x Y);
          [subst; repeat rewrite t_update_eq; reflexivity
          | destruct (string_dec x X);
            [subst; rewrite t_update_neq; auto | repeat (rewrite t_update_neq; auto)]
          ].

Theorem equiv_b_e : cequiv prog_b prog_e.
Proof.
  unfold prog_b. unfold prog_e.
  intros st. split; intros H.
  - inversion H. subst. destruct (st X) eqn:HstX.
    * inversion H2; subst.
      + eassert (st =[ X := X + 1; Y := 1 ]=> _).
        { eapply E_Seq; eapply E_Asgn; simpl; [rewrite HstX | ..]; simpl; eexists. }
        apply (ceval_deterministic _ _ _ _ H8) in H0. subst.
        eassert ((Y !-> 1; X !-> 1; st) =[ X := X - Y; Y := 0 ]=> _).
        { eapply E_Seq; eapply E_Asgn; simpl; eexists. }
        apply (ceval_deterministic _ _ _ _ H5) in H0. subst.
        assert ((Y !-> 0; X !-> 0; Y !-> 1; X !-> 1; st) = (Y !-> 0; st)).
        { map_equal_assert. }
        rewrite H0. constructor. reflexivity.
      + simpl in H7. rewrite HstX in H7. discriminate H7.
    * inversion H2; subst.
      + simpl in H7. rewrite HstX in H7. discriminate H7.
      + inversion H8. subst. simpl in H5.
        eassert ((Y !-> 0; st) =[ X := X - Y; Y := 0 ]=> _).
        { eapply E_Seq; eapply E_Asgn; simpl.
          { rewrite t_update_neq; [.. | discriminate]. rewrite t_update_eq. rewrite sub_0_r. eexists. }
          { eexists. }
        }
        apply (ceval_deterministic _ _ _ _ H5) in H0. rewrite H0.
        assert ((Y !-> 0; X !-> st X; Y !-> 0; st) = (Y !-> 0; st)).
        { map_equal_assert. }
        rewrite H1. constructor. reflexivity.
  - inversion H. subst. simpl. destruct (st X) eqn:HstX; eapply E_Seq.
    * apply E_IfTrue; simpl.
      + rewrite HstX. reflexivity.
      + eapply E_Seq; apply E_Asgn; simpl; [rewrite HstX | ..]; simpl; eexists.
    * eapply E_Seq.
      + eapply E_Asgn. simpl. eexists.
      + assert ((Y !-> 0; X !-> 0; Y !-> 1; X !-> 1; st) = (Y !-> 0; st)).
        { map_equal_assert. }
        rewrite <- H0. constructor. reflexivity.
    * apply E_IfFalse; simpl.
      + rewrite HstX. reflexivity.
      +  simpl in H. apply H.
    * eapply E_Seq.
      + eapply E_Asgn. simpl. eexists.
      + rewrite t_update_eq. rewrite t_update_neq; [.. | discriminate]. rewrite sub_0_r.
        assert ((Y !-> 0; X !-> st X; Y !-> 0; st) = (Y !-> 0; st)).
        { map_equal_assert. }
        rewrite <- H0 at 2. constructor. reflexivity.
Qed. 
        
Theorem equiv_c_h : cequiv prog_c prog_h.
Proof.
  unfold prog_c. unfold prog_h.
  intros st st'. split; intros H; inversion H; subst.
  - apply E_WhileFalse. simpl.
    rewrite eqb_refl. reflexivity.
  - apply E_Skip.
  - simpl in H2. rewrite eqb_refl in H2. discriminate H2.
Qed.

Ltac zero_case := match goal with
  | Hstx : (?st ?X) = 0 |- _ => 
    match goal with
    | Hb : beval ?st ?b = true |- _ => simpl in Hb; rewrite Hstx in Hb; simpl in Hb; discriminate Hb
    | _ => apply E_WhileFalse; simpl; rewrite Hstx; auto
    end
  | Hb1 : beval ?st ?b = true, Hb2 : beval ?st ?b = false |- _ => rewrite Hb1 in Hb2; discriminate Hb2
  end.

Lemma inc_equiv_a : forall (st st' : state),
  (exists n, st X = S n) -> st =[ while X > 0 do X := X + 1 end ]=> st' -> st =[ while X + 1 > 0 do X := X + 1 end ]=> st'.
Proof.
  intros st st' Hst H.
  remember <{ while X > 0 do X := X + 1 end }> as cw eqn:Heqcw. 
  induction H; inversion Heqcw; subst; clear Heqcw.
  - simpl in H. destruct Hst as [n Hst]. rewrite Hst in H. discriminate H.
  - apply E_WhileTrue with st'.
    * simpl. destruct Hst as [n Hst]. rewrite Hst. reflexivity.
    * assumption.
    * apply IHceval2.
      + inversion H0; subst. simpl. destruct Hst as [n0 Hst].
        rewrite t_update_eq. exists (S n0). rewrite add_1_r. rewrite Hst.
        reflexivity.
      + reflexivity.
Qed.

Lemma inc_equiv_b : forall (st st' : state),
  (exists n, st X = S n) -> st =[ while X <> 0 do X := X * Y + 1 end ]=> st' -> st =[ while X * Y + 1 > 0 do X := X * Y + 1 end ]=> st'.
Proof.
  intros st st' Hst H.
  remember <{ while X <> 0 do X := X * Y + 1 end }> as cw eqn:Heqcw.
  induction H; inversion Heqcw; subst; clear Heqcw.
  - simpl in H. destruct Hst as [n Hst]. rewrite Hst in H. discriminate H.
  - apply E_WhileTrue with st'.
    * simpl. destruct Hst as [n Hst]. rewrite Hst.
      destruct (st Y); [ rewrite mul_0_r | ..]; reflexivity.
    * assumption.
    * apply IHceval2.
      + inversion H0; subst. simpl. destruct Hst as [n0 Hst].
        rewrite t_update_eq. exists ((st X) * st Y). rewrite add_1_r.
        reflexivity.
      + reflexivity.
Qed.

Theorem equiv_a_d : cequiv prog_a prog_d.
Proof.
  unfold prog_a. unfold prog_d.
  intros st st'. split; intros H.
  - destruct (st X) eqn:Hstx.
    * inversion H; subst; zero_case.
    * assert (exists n', st X = S n') as Hexst. { exists n. assumption. }
      apply (inc_equiv_a st st') in Hexst; auto.
      assert (bequiv <{ X + 1 > 0 }> <{ true }>) as Htrue.
      { unfold bequiv. intros st0. simpl. destruct (st0 X); reflexivity. }
      apply (while_true_nonterm _ <{ X := X + 1 }> st st') in Htrue.
      apply Htrue in Hexst. contradiction Hexst.
  - destruct (st X) eqn:Hstx.
    * inversion H; subst; zero_case.
    * assert (exists n', st X = S n') as Hexst. { exists n. assumption. }
      apply (inc_equiv_b st st') in Hexst; auto.
      assert (bequiv <{ X * Y + 1 > 0 }> <{ true }>) as Htrue.
      { unfold bequiv. intros st0. simpl. destruct (st0 X); destruct (st0 Y); try rewrite mul_0_r; auto. }
      apply (while_true_nonterm _ <{ X := X * Y + 1 }> st st') in Htrue.
      apply Htrue in Hexst. contradiction Hexst.
Qed.

Lemma prog_f_collapsed : forall st st',
  X <> Y ->
  st =[ Y := X + 1; while X <> Y do Y := X + 1 end ]=> st' ->
  st =[ while X <> X + 1 do Y := X + 1 end ]=> st'.
Proof.
  intros st st' Hxy H.
  inversion H. subst.
  remember <{ while X <> Y do Y := X + 1 end }> as cw eqn:Heqcw.
  induction H5; inversion Heqcw; subst; clear Heqcw.
  - inversion H2; subst. simpl in H0. rewrite t_update_eq in H0.
    rewrite t_update_neq in H0; auto.
    apply negb_false_iff in H0. apply eqb_eq in H0.
    rewrite add_1_r in H0. apply neq_succ_diag_r in H0.
    destruct H0.
  - apply IHceval2.
    * reflexivity.
    * assumption.
    * inversion H2. subst. simpl in H2. inversion H5_. subst.
      simpl. rewrite t_update_neq; auto. rewrite t_update_shadow.
      assumption.
Qed.


Theorem equiv_f_g : cequiv prog_f prog_g.
Proof.
  unfold prog_f. unfold prog_g.
  intros st st'. split; intros H.
  - apply prog_f_collapsed in H; [.. | discriminate].
    assert (bequiv <{ X <> X + 1 }> <{ true }>) as Htrue. 
    { intros st0. simpl. rewrite negb_true_iff. rewrite add_1_r.
      rewrite eqb_neq. apply neq_succ_diag_r. }
    apply (while_true_nonterm _ <{ Y := X + 1 }> st st') in Htrue.
    contradiction.
  - assert (bequiv <{ true }> <{ true }>) as Htrue.
    { intros st0. reflexivity. }
    apply (while_true_nonterm _ <{ skip }> st st') in Htrue.
    contradiction.
Qed.

Theorem not_equiv_c_e : ~(cequiv prog_c prog_e).
Proof.
  unfold prog_c. unfold prog_e. unfold cequiv.
  intros Heq. specialize Heq with (Y !-> 3) (Y !-> 0; Y !-> 3).
  destruct Heq.
  assert ((Y !-> 3) =[ Y := 0 ]=> (Y !-> 0; Y !-> 3)) as He.
  { constructor. reflexivity. }
  apply H0 in He. inversion He.
  assert (~(forall x, (Y !-> 3) x = (Y !-> 0; Y !-> 3) x)) as Hneq.
  { intros contra. specialize contra with Y. repeat rewrite t_update_eq in contra.
    inversion contra.
  }
  apply Hneq. apply equal_f. apply H1.
Qed.

Theorem not_equiv_f_i : ~(cequiv prog_f prog_i).
Proof.
  unfold prog_f. unfold prog_i. unfold cequiv.
  intros Heq. specialize Heq with (X !-> 0; Y !-> 0) (X !-> 0; Y !-> 0).
  destruct Heq.
  assert ((X !-> 0; Y !-> 0) =[ while X <> Y do X := Y + 1 end ]=> (X !-> 0; Y !-> 0)) as Hwhile.
  { apply E_WhileFalse. reflexivity. }
  apply H0 in Hwhile.
  inversion Hwhile. subst. inversion H3. subst.
  simpl in H6.
  destruct (string_dec X Y).
  - rewrite e in H6. inversion H6; subst.
    * assert (~(forall x, (Y !-> 1; Y !-> 0; Y !-> 0) x = (Y !-> 0; Y !-> 0) x)) as Hneq.
      { intros contra. specialize contra with Y. repeat rewrite t_update_eq in contra.
        inversion contra. }
      apply Hneq. apply equal_f. apply H7.
    * simpl in H4. discriminate H4.
  - apply (prog_f_collapsed _ _ n) in Hwhile.
    assert (bequiv <{ X <> X + 1}> <{ true }>) as Hb.
    { intros st0. simpl. apply negb_true_iff. rewrite add_1_r. rewrite eqb_neq. apply neq_succ_diag_r. }
    apply (while_true_nonterm _ <{ Y := X + 1 }> (X !-> 0; Y !-> 0)  (X !-> 0; Y !-> 0)) in Hb.
    contradiction.
Qed.

Theorem not_equiv_a_c : ~(cequiv prog_a prog_c).
Proof.
  unfold prog_a. unfold prog_c. unfold cequiv.
  intros Heq. specialize Heq with (st := (X !-> 1)).
  edestruct Heq.
  eassert ((X !-> 1) =[ skip ]=> _). { apply E_Skip. }
  apply H0 in H1.
  assert (exists n, (X !-> 1) X = S n). { exists 0. auto. }
  apply (inc_equiv_a _ _ H2) in H1.
  assert (bequiv <{ X + 1 > 0 }> <{ true }>).
  { intros st0. simpl. destruct (st0 X); reflexivity. }
  eapply while_true_nonterm in H3.
  apply H3 in H1. auto.
Qed.

Definition equiv_classes : list (list com) :=
  [
  [prog_a; prog_d];
  [prog_b; prog_e];
  [prog_c; prog_h];
  [prog_f; prog_g];
  [prog_i]
  ].

(* Do not modify the following line: *)
Definition manual_grade_for_equiv_classes : option (nat*string) := None.
(** [] *)

(* ################################################################# *)
(** * Properties of Behavioral Equivalence *)

(** We next consider some fundamental properties of program
    equivalence. *)

(* ================================================================= *)
(** ** Behavioral Equivalence Is an Equivalence *)

(** First, let's verify that the equivalences on [aexps], [bexps], and
    [com]s really are _equivalences_ -- i.e., that they are reflexive,
    symmetric, and transitive.  The proofs are all easy. *)

Lemma refl_aequiv : forall (a : aexp),
  aequiv a a.
Proof.
  intros a st. reflexivity.  Qed.

Lemma sym_aequiv : forall (a1 a2 : aexp),
  aequiv a1 a2 -> aequiv a2 a1.
Proof.
  intros a1 a2 H. intros st. symmetry. apply H.  Qed.

Lemma trans_aequiv : forall (a1 a2 a3 : aexp),
  aequiv a1 a2 -> aequiv a2 a3 -> aequiv a1 a3.
Proof.
  unfold aequiv. intros a1 a2 a3 H12 H23 st.
  rewrite (H12 st). rewrite (H23 st). reflexivity.  Qed.

Lemma refl_bequiv : forall (b : bexp),
  bequiv b b.
Proof.
  unfold bequiv. intros b st. reflexivity.  Qed.

Lemma sym_bequiv : forall (b1 b2 : bexp),
  bequiv b1 b2 -> bequiv b2 b1.
Proof.
  unfold bequiv. intros b1 b2 H. intros st. symmetry. apply H.  Qed.

Lemma trans_bequiv : forall (b1 b2 b3 : bexp),
  bequiv b1 b2 -> bequiv b2 b3 -> bequiv b1 b3.
Proof.
  unfold bequiv. intros b1 b2 b3 H12 H23 st.
  rewrite (H12 st). rewrite (H23 st). reflexivity.  Qed.

Lemma refl_cequiv : forall (c : com),
  cequiv c c.
Proof.
  unfold cequiv. intros c st st'. reflexivity.  Qed.

Lemma sym_cequiv : forall (c1 c2 : com),
  cequiv c1 c2 -> cequiv c2 c1.
Proof.
  unfold cequiv. intros c1 c2 H st st'.
  rewrite H. reflexivity.
Qed.

Lemma trans_cequiv : forall (c1 c2 c3 : com),
  cequiv c1 c2 -> cequiv c2 c3 -> cequiv c1 c3.
Proof.
  unfold cequiv. intros c1 c2 c3 H12 H23 st st'.
  rewrite H12. apply H23.
Qed.

(* ================================================================= *)
(** ** Behavioral Equivalence Is a Congruence *)

(** Less obviously, behavioral equivalence is also a _congruence_.
    That is, the equivalence of two subprograms implies the
    equivalence of the larger programs in which they are embedded:

                 aequiv a a'
         -------------------------
         cequiv (x := a) (x := a')

              cequiv c1 c1'
              cequiv c2 c2'
         --------------------------
         cequiv (c1;c2) (c1';c2')

    ... and so on for the other forms of commands. *)

(** (Note that we are using the inference rule notation here not
    as part of an inductive definition, but simply to write down some
    valid implications in a readable format. We prove these
    implications below.) *)

(** We will see a concrete example of why these congruence
    properties are important in the following section (in the proof of
    [fold_constants_com_sound]), but the main idea is that they allow
    us to replace a small part of a large program with an equivalent
    small part and know that the whole large programs are equivalent
    _without_ doing an explicit proof about the parts that didn't
    change -- i.e., the "proof burden" of a small change to a large
    program is proportional to the size of the change, not the
    program! *)

Theorem CAsgn_congruence : forall x a a',
  aequiv a a' ->
  cequiv <{x := a}> <{x := a'}>.
Proof.
  intros x a a' Heqv st st'.
  split; intros Hceval.
  - (* -> *)
    inversion Hceval. subst. apply E_Asgn.
    rewrite Heqv. reflexivity.
  - (* <- *)
    inversion Hceval. subst. apply E_Asgn.
    rewrite Heqv. reflexivity.  Qed.

(** The congruence property for loops is a little more interesting,
    since it requires induction.

    _Theorem_: Equivalence is a congruence for [while] -- that is, if
    [b] is equivalent to [b'] and [c] is equivalent to [c'], then
    [while b do c end] is equivalent to [while b' do c' end].

    _Proof_: Suppose [b] is equivalent to [b'] and [c] is
    equivalent to [c'].  We must show, for every [st] and [st'], that
    [st =[ while b do c end ]=> st'] iff [st =[ while b' do c'
    end ]=> st'].  We consider the two directions separately.

      - ([->]) We show that [st =[ while b do c end ]=> st'] implies
        [st =[ while b' do c' end ]=> st'], by induction on a
        derivation of [st =[ while b do c end ]=> st'].  The only
        nontrivial cases are when the final rule in the derivation is
        [E_WhileFalse] or [E_WhileTrue].

          - [E_WhileFalse]: In this case, the form of the rule gives us
            [beval st b = false] and [st = st'].  But then, since
            [b] and [b'] are equivalent, we have [beval st b' =
            false], and [E_WhileFalse] applies, giving us
            [st =[ while b' do c' end ]=> st'], as required.

          - [E_WhileTrue]: The form of the rule now gives us [beval st
            b = true], with [st =[ c ]=> st'0] and [st'0 =[ while
            b do c end ]=> st'] for some state [st'0], with the
            induction hypothesis [st'0 =[ while b' do c' end ]=>
            st'].

            Since [c] and [c'] are equivalent, we know that [st =[
            c' ]=> st'0].  And since [b] and [b'] are equivalent,
            we have [beval st b' = true].  Now [E_WhileTrue] applies,
            giving us [st =[ while b' do c' end ]=> st'], as
            required.

      - ([<-]) Similar. [] *)

Theorem CWhile_congruence : forall b b' c c',
  bequiv b b' -> cequiv c c' ->
  cequiv <{ while b do c end }> <{ while b' do c' end }>.
Proof.
  (* WORKED IN CLASS *)

  (* We will prove one direction in an "assert"
     in order to reuse it for the converse. *)
  assert (A: forall (b b' : bexp) (c c' : com) (st st' : state),
             bequiv b b' -> cequiv c c' ->
             st =[ while b do c end ]=> st' ->
             st =[ while b' do c' end ]=> st').
  { unfold bequiv,cequiv.
    intros b b' c c' st st' Hbe Hc1e Hce.
    remember <{ while b do c end }> as cwhile
      eqn:Heqcwhile.
    induction Hce; inversion Heqcwhile; subst.
    + (* E_WhileFalse *)
      apply E_WhileFalse. rewrite <- Hbe. apply H.
    + (* E_WhileTrue *)
      apply E_WhileTrue with (st' := st').
      * (* show loop runs *) rewrite <- Hbe. apply H.
      * (* body execution *)
        apply (Hc1e st st').  apply Hce1.
      * (* subsequent loop execution *)
        apply IHHce2. reflexivity. }

  intros. split.
  - apply A; assumption.
  - apply A.
    + apply sym_bequiv. assumption.
    + apply sym_cequiv. assumption.
Qed.

(** **** Exercise: 3 stars, standard, optional (CSeq_congruence) *)
Theorem CSeq_congruence : forall c1 c1' c2 c2',
  cequiv c1 c1' -> cequiv c2 c2' ->
  cequiv <{ c1;c2 }> <{ c1';c2' }>.
Proof.
  intros c1 c1' c2 c2' Hc1 Hc2. split; intros H; inversion H; subst;
  apply Hc1 in H2; apply Hc2 in H5; apply E_Seq with st'0; assumption.
Qed.

(** [] *)

Ltac solve_if_congruence := match goal with 
  | Hb : bequiv ?b1 ?b2, Heval : beval _ ?bv = ?b3 |- _ => 
        match bv with
        | ?b1 => rewrite Hb in Heval
        | ?b2 => rewrite <- Hb in Heval
        end;
        match goal with
        | _ : ?b3 = true |- _ => apply E_IfTrue
        | _ : ?b3 = false |- _ => apply E_IfFalse
        end;
        [ idtac |
        match goal with
        | Hc : cequiv ?c ?c', He : _ =[ ?c ]=> _ |- _ => apply Hc in He
        | Hc : cequiv ?c ?c', He : _ =[ ?c' ]=> _ |- _ => apply Hc in He
        end];
        assumption
  end.
  
(** **** Exercise: 3 stars, standard (CIf_congruence) *)
Theorem CIf_congruence : forall b b' c1 c1' c2 c2',
  bequiv b b' -> cequiv c1 c1' -> cequiv c2 c2' ->
  cequiv <{ if b then c1 else c2 end }>
         <{ if b' then c1' else c2' end }>.
Proof.
  intros b b' c1 c1' c2 c2' Hb Hc1 Hc2. 
  split; intros H; inversion H; subst; solve_if_congruence.
Qed.
(** [] *)

(** For example, here are two equivalent programs and a proof of their
    equivalence using these congruence theorems... *)

Example congruence_example:
  cequiv
    (* Program 1: *)
    <{ X := 0;
       if X = 0 then Y := 0
       else Y := 42 end }>
    (* Program 2: *)
    <{ X := 0;
       if X = 0 then Y := X - X   (* <--- Changed here *)
       else Y := 42 end }>.
Proof.
  apply CSeq_congruence.
  - apply refl_cequiv.
  - apply CIf_congruence.
    + apply refl_bequiv.
    + apply CAsgn_congruence. unfold aequiv. simpl.
      symmetry. apply sub_diag.
    + apply refl_cequiv.
Qed.

(** **** Exercise: 3 stars, advanced (not_congr)

    We've shown that the [cequiv] relation is both an equivalence and
    a congruence on commands.  Can you think of a relation on commands
    that is an equivalence but _not_ a congruence?  Write down the
    relation (formally), together with an informal sketch of a proof
    that it is an equivalence but not a congruence. *)

(* FILL IN HERE *)
Definition equiv_not_congr (c1 c2 : com) : Prop := forall st,
  empty_st =[ c1 ]=> st <-> empty_st =[ c2 ]=> st.
  
Theorem equiv_not_congr_refl : forall c,
  equiv_not_congr c c.
Proof.
  intros c st. split; intros H; assumption.
Qed.

Theorem equiv_not_congr_symm : forall c1 c2,
  equiv_not_congr c1 c2 -> equiv_not_congr c2 c1.
Proof.
  intros c1 c2. unfold equiv_not_congr. intros H st.
  split; intros H'; apply H in H'; assumption.
Qed.

Theorem equiv_not_congr_trans : forall c1 c2 c3,
  equiv_not_congr c1 c2 -> equiv_not_congr c2 c3 -> equiv_not_congr c1 c3.
Proof.
  intros c1 c2 c3. unfold equiv_not_congr. intros H12 H23 st.
  split; intros H.
  - apply H23. apply H12. assumption.
  - apply H12. apply H23. assumption.
Qed.

Theorem equiv_not_congr_not_congr : exists c1 c1' c2 c2',
  equiv_not_congr c1 c1' /\ equiv_not_congr c2 c2' /\
  ~(cequiv <{ c1; c2 }> <{ c1'; c2' }>).
Proof.
  exists <{ X := X + 1 }>, <{ X := 1 }>, <{ X := 3 }>, <{ X := X + 3 }>.
  split; [.. | split].
  - intros st. split; intros H; inversion H; subst; simpl; apply E_Asgn; reflexivity.
  - intros st. split; intros H; inversion H; subst; simpl; apply E_Asgn; reflexivity.
  - unfold cequiv. intros contra. specialize contra with empty_st (X !-> 3;  X !-> empty_st X + 1; empty_st).
    destruct contra.
    assert (Heval : empty_st =[ X := X + 1; X := 3 ]=> (X !-> 3; X !-> empty_st X + 1; empty_st)).
    { apply E_Seq with (X !-> empty_st X + 1; empty_st).
      { simpl. apply E_Asgn. reflexivity. }
      { simpl. apply E_Asgn. reflexivity. }
    }
    apply H in Heval. inversion Heval. subst.
    inversion H3. subst. simpl in H6.
    inversion H6. subst. simpl in H7.
    assert (~(forall x, (X !-> 4; X !-> 1) x = (X !-> 3; X !-> 1) x)) as Hneq.
    { intros contra. specialize contra with X. 
      repeat rewrite t_update_eq in contra. inversion contra. }
    apply Hneq. apply equal_f. apply H7.
Qed.

(* Do not modify the following line: *)
Definition manual_grade_for_not_congr : option (nat*string) := None.
(** [] *)

(* ################################################################# *)
(** * Program Transformations *)

(** A _program transformation_ is a function that takes a program as
    input and produces a modified program as output.  Compiler
    optimizations such as constant folding are a canonical example,
    but there are many others. *)

(** A program transformation is said to be _sound_ if it preserves the
    behavior of the original program. *)

Definition atrans_sound (atrans : aexp -> aexp) : Prop :=
  forall (a : aexp),
    aequiv a (atrans a).

Definition btrans_sound (btrans : bexp -> bexp) : Prop :=
  forall (b : bexp),
    bequiv b (btrans b).

Definition ctrans_sound (ctrans : com -> com) : Prop :=
  forall (c : com),
    cequiv c (ctrans c).

(* ================================================================= *)
(** ** The Constant-Folding Transformation *)

(** An expression is _constant_ if it contains no variable references.

    Constant folding is an optimization that finds constant
    expressions and replaces them by their values. *)

Fixpoint fold_constants_aexp (a : aexp) : aexp :=
  match a with
  | ANum n       => ANum n
  | AId x        => AId x
  | <{ a1 + a2 }>  =>
    match (fold_constants_aexp a1,
           fold_constants_aexp a2)
    with
    | (ANum n1, ANum n2) => ANum (n1 + n2)
    | (a1', a2') => <{ a1' + a2' }>
    end
  | <{ a1 - a2 }> =>
    match (fold_constants_aexp a1,
           fold_constants_aexp a2)
    with
    | (ANum n1, ANum n2) => ANum (n1 - n2)
    | (a1', a2') => <{ a1' - a2' }>
    end
  | <{ a1 * a2 }>  =>
    match (fold_constants_aexp a1,
           fold_constants_aexp a2)
    with
    | (ANum n1, ANum n2) => ANum (n1 * n2)
    | (a1', a2') => <{ a1' * a2' }>
    end
  end.

Example fold_aexp_ex1 :
    fold_constants_aexp <{ (1 + 2) * X }>
  = <{ 3 * X }>.
Proof. reflexivity. Qed.

(** Note that this version of constant folding doesn't do other
    "obvious" things like eliminating trivial additions (e.g.,
    rewriting [0 + X] to just [X]).: we are focusing attention on a
    single optimization for the sake of simplicity.

    It is not hard to incorporate other ways of simplifying
    expressions -- the definitions and proofs just get longer.  We'll
    consider optimizations in the exercises. *)

Example fold_aexp_ex2 :
  fold_constants_aexp <{ X - ((0 * 6) + Y) }> = <{ X - (0 + Y) }>.
Proof. reflexivity. Qed.

(** Not only can we lift [fold_constants_aexp] to [bexp]s (in the
    [BEq], [BNeq], and [BLe] cases); we can also look for constant
    _boolean_ expressions and evaluate them in-place as well. *)

Fixpoint fold_constants_bexp (b : bexp) : bexp :=
  match b with
  | <{true}>        => <{true}>
  | <{false}>       => <{false}>
  | <{ a1 = a2 }>  =>
      match (fold_constants_aexp a1,
             fold_constants_aexp a2) with
      | (ANum n1, ANum n2) =>
          if n1 =? n2 then <{true}> else <{false}>
      | (a1', a2') =>
          <{ a1' = a2' }>
      end
  | <{ a1 <> a2 }>  =>
      match (fold_constants_aexp a1,
             fold_constants_aexp a2) with
      | (ANum n1, ANum n2) =>
          if negb (n1 =? n2) then <{true}> else <{false}>
      | (a1', a2') =>
          <{ a1' <> a2' }>
      end
  | <{ a1 <= a2 }>  =>
      match (fold_constants_aexp a1,
             fold_constants_aexp a2) with
      | (ANum n1, ANum n2) =>
          if n1 <=? n2 then <{true}> else <{false}>
      | (a1', a2') =>
          <{ a1' <= a2' }>
      end
  | <{ a1 > a2 }>  =>
      match (fold_constants_aexp a1,
             fold_constants_aexp a2) with
      | (ANum n1, ANum n2) =>
          if n1 <=? n2 then <{false}> else <{true}>
      | (a1', a2') =>
          <{ a1' > a2' }>
      end
  | <{ ~ b1 }>  =>
      match (fold_constants_bexp b1) with
      | <{true}> => <{false}>
      | <{false}> => <{true}>
      | b1' => <{ ~ b1' }>
      end
  | <{ b1 && b2 }>  =>
      match (fold_constants_bexp b1,
             fold_constants_bexp b2) with
      | (<{true}>, <{true}>) => <{true}>
      | (<{true}>, <{false}>) => <{false}>
      | (<{false}>, <{true}>) => <{false}>
      | (<{false}>, <{false}>) => <{false}>
      | (b1', b2') => <{ b1' && b2' }>
      end
  end.

Example fold_bexp_ex1 :
  fold_constants_bexp <{ true && ~(false && true) }>
  = <{ true }>.
Proof. reflexivity. Qed.

Example fold_bexp_ex2 :
  fold_constants_bexp <{ (X = Y) && (0 = (2 - (1 + 1))) }>
  = <{ (X = Y) && true }>.
Proof. reflexivity. Qed.

(** To fold constants in a command, we apply the appropriate folding
    functions on all embedded expressions. *)

Fixpoint fold_constants_com (c : com) : com :=
  match c with
  | <{ skip }> =>
      <{ skip }>
  | <{ x := a }> =>
      <{ x := (fold_constants_aexp a) }>
  | <{ c1 ; c2 }>  =>
      <{ fold_constants_com c1 ; fold_constants_com c2 }>
  | <{ if b then c1 else c2 end }> =>
      match fold_constants_bexp b with
      | <{true}>  => fold_constants_com c1
      | <{false}> => fold_constants_com c2
      | b' => <{ if b' then fold_constants_com c1
                       else fold_constants_com c2 end}>
      end
  | <{ while b do c1 end }> =>
      match fold_constants_bexp b with
      | <{true}> => <{ while true do skip end }>
      | <{false}> => <{ skip }>
      | b' => <{ while b' do (fold_constants_com c1) end }>
      end
  end.

Example fold_com_ex1 :
  fold_constants_com
    (* Original program: *)
    <{ X := 4 + 5;
       Y := X - 3;
       if (X - Y) = (2 + 4) then skip
       else Y := 0 end;
       if 0 <= (4 - (2 + 1)) then Y := 0
       else skip end;
       while Y = 0 do
         X := X + 1
       end }>
  = (* After constant folding: *)
    <{ X := 9;
       Y := X - 3;
       if (X - Y) = 6 then skip
       else Y := 0 end;
       Y := 0;
       while Y = 0 do
         X := X + 1
       end }>.
Proof. reflexivity. Qed.

(* ================================================================= *)
(** ** Soundness of Constant Folding *)

(** Now we need to show that what we've done is correct. *)

(** Here's the proof for arithmetic expressions: *)

Theorem fold_constants_aexp_sound :
  atrans_sound fold_constants_aexp.
Proof.
  unfold atrans_sound. intros a. unfold aequiv. intros st.
  induction a; simpl;
    (* ANum and AId follow immediately *)
    try reflexivity;
    (* APlus, AMinus, and AMult follow from the IH
       and the observation that
              aeval st (<{ a1 + a2 }>)
            = ANum ((aeval st a1) + (aeval st a2))
            = aeval st (ANum ((aeval st a1) + (aeval st a2)))
       (and similarly for AMinus/minus and AMult/mult) *)
    try (destruct (fold_constants_aexp a1);
         destruct (fold_constants_aexp a2);
         rewrite IHa1; rewrite IHa2; reflexivity). Qed.

(** **** Exercise: 3 stars, standard, optional (fold_bexp_Eq_informal)

    Here is an informal proof of the [BEq] case of the soundness
    argument for boolean expression constant folding.  Read it
    carefully and compare it to the formal proof that follows.  Then
    fill in the [BLe] case of the formal proof (without looking at the
    [BEq] case, if possible).

   _Theorem_: The constant folding function for booleans,
   [fold_constants_bexp], is sound.

   _Proof_: We must show that [b] is equivalent to [fold_constants_bexp b],
   for all boolean expressions [b].  Proceed by induction on [b].  We
   show just the case where [b] has the form [a1 = a2].

   In this case, we must show

       beval st <{ a1 = a2 }>
     = beval st (fold_constants_bexp <{ a1 = a2 }>).

   There are two cases to consider:

     - First, suppose [fold_constants_aexp a1 = ANum n1] and
       [fold_constants_aexp a2 = ANum n2] for some [n1] and [n2].

       In this case, we have

           fold_constants_bexp <{ a1 = a2 }>
         = if n1 =? n2 then <{true}> else <{false}>

       and

           beval st <{a1 = a2}>
         = (aeval st a1) =? (aeval st a2).

       By the soundness of constant folding for arithmetic
       expressions (Lemma [fold_constants_aexp_sound]), we know

           aeval st a1
         = aeval st (fold_constants_aexp a1)
         = aeval st (ANum n1)
         = n1

       and

           aeval st a2
         = aeval st (fold_constants_aexp a2)
         = aeval st (ANum n2)
         = n2,

       so

           beval st <{a1 = a2}>
         = (aeval a1) =? (aeval a2)
         = n1 =? n2.

       Also, it is easy to see (by considering the cases [n1 = n2] and
       [n1 <> n2] separately) that

           beval st (if n1 =? n2 then <{true}> else <{false}>)
         = if n1 =? n2 then beval st <{true}> else beval st <{false}>
         = if n1 =? n2 then true else false
         = n1 =? n2.

       So

           beval st (<{ a1 = a2 }>)
         = n1 =? n2.
         = beval st (if n1 =? n2 then <{true}> else <{false}>),

       as required.

     - Otherwise, one of [fold_constants_aexp a1] and
       [fold_constants_aexp a2] is not a constant.  In this case, we
       must show

           beval st <{a1 = a2}>
         = beval st (<{ (fold_constants_aexp a1) =
                         (fold_constants_aexp a2) }>),

       which, by the definition of [beval], is the same as showing

           (aeval st a1) =? (aeval st a2)
         = (aeval st (fold_constants_aexp a1)) =?
                   (aeval st (fold_constants_aexp a2)).

       But the soundness of constant folding for arithmetic
       expressions ([fold_constants_aexp_sound]) gives us

         aeval st a1 = aeval st (fold_constants_aexp a1)
         aeval st a2 = aeval st (fold_constants_aexp a2),

       completing the case.  [] *)

Theorem fold_constants_bexp_sound:
  btrans_sound fold_constants_bexp.
Proof.
  unfold btrans_sound. intros b. unfold bequiv. intros st.
  induction b;
    (* true and false are immediate *)
    try reflexivity.
  - (* BEq *)
    simpl.
    remember (fold_constants_aexp a1) as a1' eqn:Heqa1'.
    remember (fold_constants_aexp a2) as a2' eqn:Heqa2'.
    replace (aeval st a1) with (aeval st a1') by
       (subst a1'; rewrite <- fold_constants_aexp_sound; reflexivity).
    replace (aeval st a2) with (aeval st a2') by
       (subst a2'; rewrite <- fold_constants_aexp_sound; reflexivity).
    destruct a1'; destruct a2'; try reflexivity.
    (* The only interesting case is when both a1 and a2
       become constants after folding *)
      simpl. destruct (n =? n0); reflexivity.
  - (* BNeq *)
    simpl.
    remember (fold_constants_aexp a1) as a1' eqn:Heqa1'.
    remember (fold_constants_aexp a2) as a2' eqn:Heqa2'.
    replace (aeval st a1) with (aeval st a1') by
       (subst a1'; rewrite <- fold_constants_aexp_sound; reflexivity).
    replace (aeval st a2) with (aeval st a2') by
       (subst a2'; rewrite <- fold_constants_aexp_sound; reflexivity).
    destruct a1'; destruct a2'; try reflexivity.
    (* The only interesting case is when both a1 and a2
       become constants after folding *)
      simpl. destruct (n =? n0); reflexivity.
  - (* BLe *)
    simpl.
    remember (fold_constants_aexp a1) as a1' eqn:Heqa1'.
    remember (fold_constants_aexp a2) as a2' eqn:Heqa2'.
    replace (aeval st a1) with (aeval st a1') by 
      (subst a1'; rewrite <- fold_constants_aexp_sound; reflexivity).
    replace (aeval st a2) with (aeval st a2') by 
      (subst a2'; rewrite <- fold_constants_aexp_sound; reflexivity).
    destruct a1'; destruct a2'; try reflexivity.
    simpl. destruct (n <=? n0); reflexivity.
  - (* BGt *)
    simpl.
    remember (fold_constants_aexp a1) as a1' eqn:Heqa1'.
    remember (fold_constants_aexp a2) as a2' eqn:Heqa2'.
    replace (aeval st a1) with (aeval st a1') by 
      (subst a1'; rewrite <- fold_constants_aexp_sound; reflexivity).
    replace (aeval st a2) with (aeval st a2') by 
      (subst a2'; rewrite <- fold_constants_aexp_sound; reflexivity).
    destruct a1'; destruct a2'; try reflexivity.
    simpl. destruct (n <=? n0); reflexivity.
  - (* BNot *)
    simpl. remember (fold_constants_bexp b) as b' eqn:Heqb'.
    rewrite IHb.
    destruct b'; reflexivity.
  - (* BAnd *)
    simpl.
    remember (fold_constants_bexp b1) as b1' eqn:Heqb1'.
    remember (fold_constants_bexp b2) as b2' eqn:Heqb2'.
    rewrite IHb1. rewrite IHb2.
    destruct b1'; destruct b2'; reflexivity.
Qed.

(** [] *)

(** **** Exercise: 3 stars, standard (fold_constants_com_sound)

    Complete the [while] case of the following proof. *)

Theorem fold_constants_com_sound :
  ctrans_sound fold_constants_com.
Proof.
  unfold ctrans_sound. intros c.
  induction c; simpl.
  - (* skip *) apply refl_cequiv.
  - (* := *) apply CAsgn_congruence.
              apply fold_constants_aexp_sound.
  - (* ; *) apply CSeq_congruence; assumption.
  - (* if *)
    assert (bequiv b (fold_constants_bexp b)). {
      apply fold_constants_bexp_sound. }
    destruct (fold_constants_bexp b) eqn:Heqb;
      try (apply CIf_congruence; assumption).
      (* (If the optimization doesn't eliminate the if, then the
          result is easy to prove from the IH and
          [fold_constants_bexp_sound].) *)
    + (* b always true *)
      apply trans_cequiv with c1; try assumption.
      apply if_true; assumption.
    + (* b always false *)
      apply trans_cequiv with c2; try assumption.
      apply if_false; assumption.
  - (* while *)
    assert (bequiv b (fold_constants_bexp b)). { apply fold_constants_bexp_sound. }
    destruct (fold_constants_bexp b) eqn:Heqb; try (apply CWhile_congruence; assumption).
    + apply while_true. assumption.
    + apply while_false. assumption.
Qed.
(** [] *)

(* ================================================================= *)
(** ** Soundness of (0 + n) Elimination, Redux *)

(** **** Exercise: 4 stars, standard, optional (optimize_0plus_var)

    Recall the definition [optimize_0plus] from the [Imp] chapter
    of _Logical Foundations_:

    Fixpoint optimize_0plus (a:aexp) : aexp :=
      match a with
      | ANum n =>
          ANum n
      | <{ 0 + a2 }> =>
          optimize_0plus a2
      | <{ a1 + a2 }> =>
          <{ (optimize_0plus a1) + (optimize_0plus a2) }>
      | <{ a1 - a2 }> =>
          <{ (optimize_0plus a1) - (optimize_0plus a2) }>
      | <{ a1 * a2 }> =>
          <{ (optimize_0plus a1) * (optimize_0plus a2) }>
      end.

   Note that this function is defined over the old version of [aexp]s,
   without states.

   Write a new version of this function that deals with variables (by
   leaving them alone), plus analogous ones for [bexp]s and commands:

     optimize_0plus_aexp
     optimize_0plus_bexp
     optimize_0plus_com
*)

Fixpoint optimize_0plus_aexp (a : aexp) : aexp :=
  match a with 
  | ANum n => ANum n
  | AId x => AId x
  | <{ 0 + a2 }> => optimize_0plus_aexp a2
  | <{ a1 + a2 }> => <{ (optimize_0plus_aexp a1) + (optimize_0plus_aexp a2) }>
  | <{ a1 - a2 }> => <{ (optimize_0plus_aexp a1) - (optimize_0plus_aexp a2) }>
  | <{ a1 * a2 }> => <{ (optimize_0plus_aexp a1) * (optimize_0plus_aexp a2) }>
  end.
  
Fixpoint optimize_0plus_bexp (b : bexp) : bexp :=
  match b with
  | <{ true }> => <{ true }>
  | <{ false }> => <{ false }>
  | <{ a1 = a2 }> => <{ (optimize_0plus_aexp a1) = (optimize_0plus_aexp a2) }>
  | <{ a1 <> a2 }> => <{ (optimize_0plus_aexp a1) <> (optimize_0plus_aexp a2) }>
  | <{ a1 <= a2 }> => <{ (optimize_0plus_aexp a1) <= (optimize_0plus_aexp a2) }>
  | <{ a1 > a2 }> => <{ (optimize_0plus_aexp a1) > (optimize_0plus_aexp a2) }>
  | <{ ~ b }> => <{ ~ (optimize_0plus_bexp b) }>
  | <{ b1 && b2 }> => <{ (optimize_0plus_bexp b1) && (optimize_0plus_bexp b2) }>
  end.
  
Fixpoint optimize_0plus_com (c : com) : com :=
  match c with
  | <{ skip }> => <{ skip }>
  | <{ x := a }> => <{ x := (optimize_0plus_aexp a) }>
  | <{ c1; c2 }> => <{ (optimize_0plus_com c1); (optimize_0plus_com c2) }>
  | <{ if b then c1 else c2 end }> => <{ if (optimize_0plus_bexp b) then (optimize_0plus_com c1) else (optimize_0plus_com c2) end }>
  | <{ while b do c end }> => <{ while (optimize_0plus_bexp b) do (optimize_0plus_com c) end }>
  end.
  
Example test_optimize_0plus:
    optimize_0plus_com
       <{ while X <> 0 do X := 0 + X - 1 end }>
  =    <{ while X <> 0 do X := X - 1 end }>.
Proof. reflexivity. Qed.

(** Prove that these three functions are sound, as we did for
    [fold_constants_*].  Make sure you use the congruence lemmas in the
    proof of [optimize_0plus_com] -- otherwise it will be _long_! *)

Theorem optimize_0plus_aexp_sound:
  atrans_sound optimize_0plus_aexp.
Proof.
  unfold atrans_sound. unfold aequiv. intros a st.
  induction a; simpl; try reflexivity.
  - destruct a1; try (rewrite IHa1; rewrite IHa2; reflexivity).
    * destruct n; simpl; rewrite IHa2; reflexivity.
  - rewrite IHa1. rewrite IHa2. reflexivity.
  - rewrite IHa1. rewrite IHa2. reflexivity.
Qed.

Theorem optimize_0plus_bexp_sound :
  btrans_sound optimize_0plus_bexp.
Proof.
  unfold btrans_sound. unfold bequiv. intros b st.
  induction b; simpl; try (repeat rewrite <- optimize_0plus_aexp_sound); try reflexivity.
  - rewrite IHb. reflexivity.
  - rewrite IHb1. rewrite IHb2. reflexivity.
Qed.

Theorem optimize_0plus_com_sound :
  ctrans_sound optimize_0plus_com.
Proof.
  unfold ctrans_sound. unfold cequiv. intros c.
  induction c; intros st st'; simpl.
  - split; intros H; assumption.
  - split; intros H; inversion H; subst; 
    apply E_Asgn; rewrite <- optimize_0plus_aexp_sound; reflexivity.
  - split; intros H; inversion H; subst; 
    apply IHc1 in H2; apply IHc2 in H5; apply E_Seq with st'0; assumption.
  - assert (bequiv b (optimize_0plus_bexp b)) as Hb. { apply optimize_0plus_bexp_sound. }
    apply (CIf_congruence _ _ _ _ _ _ Hb IHc1 IHc2).
  - assert (bequiv b (optimize_0plus_bexp b)) as Hb. { apply optimize_0plus_bexp_sound. }
    apply (CWhile_congruence _ _ _ _ Hb IHc).
Qed.

(** Finally, let's define a compound optimizer on commands that first
    folds constants (using [fold_constants_com]) and then eliminates
    [0 + n] terms (using [optimize_0plus_com]). *)

Definition optimizer (c : com) := optimize_0plus_com (fold_constants_com c).

(** Prove that this optimizer is sound. *)

Theorem optimizer_sound :
  ctrans_sound optimizer.
Proof.
  unfold ctrans_sound. unfold optimizer. unfold cequiv.
  intros c. 
  assert (forall st st', st =[ (fold_constants_com c) ]=> st' <-> st =[(optimize_0plus_com (fold_constants_com c)) ]=> st').
  { apply optimize_0plus_com_sound. }
  assert (forall st st', st =[ c ]=> st' <-> st =[ (fold_constants_com c) ]=> st').
  { apply fold_constants_com_sound. }
  apply (trans_cequiv _ _ _ H0 H).
Qed.

(** [] *)

(* ################################################################# *)
(** * Proving Inequivalence *)

(** Next, let's look at some programs that are _not_ equivalent. *)

(** Suppose that [c1] is a command of the form

       X := a1; Y := a2

    and [c2] is the command

       X := a1; Y := a2'

    where [a2'] is formed by substituting [a1] for all occurrences
    of [X] in [a2].

    For example, [c1] and [c2] might be:

       c1  =  (X := 42 + 53;
               Y := Y + X)
       c2  =  (X := 42 + 53;
               Y := Y + (42 + 53))

    Clearly, this _particular_ [c1] and [c2] are equivalent.  Is this
    true in general? *)

(** We will see in a moment that it is not, but it is worthwhile
    to pause, now, and see if you can find a counter-example on your
    own. *)

(** More formally, here is the function that substitutes an arithmetic
    expression [u] for each occurrence of a given variable [x] in
    another expression [a]: *)

Fixpoint subst_aexp (x : string) (u : aexp) (a : aexp) : aexp :=
  match a with
  | ANum n       =>
      ANum n
  | AId x'       =>
      if String.eqb x x' then u else AId x'
  | <{ a1 + a2 }>  =>
      <{ (subst_aexp x u a1) + (subst_aexp x u a2) }>
  | <{ a1 - a2 }> =>
      <{ (subst_aexp x u a1) - (subst_aexp x u a2) }>
  | <{ a1 * a2 }>  =>
      <{ (subst_aexp x u a1) * (subst_aexp x u a2) }>
  end.

Example subst_aexp_ex :
  subst_aexp X <{42 + 53}> <{Y + X}>
  = <{ Y + (42 + 53)}>.
Proof. simpl. reflexivity. Qed.

(** And here is the property we are interested in, expressing the
    claim that commands [c1] and [c2] as described above are
    always equivalent.  *)

Definition subst_equiv_property : Prop := forall x1 x2 a1 a2,
  cequiv <{ x1 := a1; x2 := a2 }>
         <{ x1 := a1; x2 := subst_aexp x1 a1 a2 }>.

(** Sadly, the property does _not_ always hold.

    Here is a counterexample:

       X := X + 1; Y := X

    If we perform the substitution, we get

       X := X + 1; Y := X + 1

    which clearly isn't equivalent. *)

Theorem subst_inequiv :
  ~ subst_equiv_property.
Proof.
  unfold subst_equiv_property.
  intros Contra.

  (* Here is the counterexample: assuming that [subst_equiv_property]
     holds allows us to prove that these two programs are
     equivalent... *)
  remember <{ X := X + 1;
              Y := X }>
      as c1.
  remember <{ X := X + 1;
              Y := X + 1 }>
      as c2.
  assert (cequiv c1 c2) by (subst; apply Contra).
  clear Contra.

  (* ... allows us to show that the command [c2] can terminate
     in two different final states:
        st1 = (Y !-> 1 ; X !-> 1)
        st2 = (Y !-> 2 ; X !-> 1). *)
  remember (Y !-> 1 ; X !-> 1) as st1.
  remember (Y !-> 2 ; X !-> 1) as st2.
  assert (H1 : empty_st =[ c1 ]=> st1);
  assert (H2 : empty_st =[ c2 ]=> st2);
  try (subst;
       apply E_Seq with (st' := (X !-> 1));
       apply E_Asgn; reflexivity).
  clear Heqc1 Heqc2.

  apply H in H1.
  clear H.

  (* Finally, we use the fact that evaluation is deterministic
     to obtain a contradiction. *)
  assert (Hcontra : st1 = st2)
    by (apply (ceval_deterministic c2 empty_st); assumption).
  clear H1 H2.
  
  assert (Hcontra' : st1 Y = st2 Y)
    by (rewrite Hcontra; reflexivity).
  subst. discriminate. Qed.

(** **** Exercise: 4 stars, standard, optional (better_subst_equiv)

    The equivalence we had in mind above was not complete nonsense --
    in fact, it was actually almost right.  To make it correct, we
    just need to exclude the case where the variable [X] occurs in the
    right-hand side of the first assignment statement. *)

Inductive var_not_used_in_aexp (x : string) : aexp -> Prop :=
  | VNUNum : forall n, var_not_used_in_aexp x (ANum n)
  | VNUId : forall y, x <> y -> var_not_used_in_aexp x (AId y)
  | VNUPlus : forall a1 a2,
      var_not_used_in_aexp x a1 ->
      var_not_used_in_aexp x a2 ->
      var_not_used_in_aexp x (<{ a1 + a2 }>)
  | VNUMinus : forall a1 a2,
      var_not_used_in_aexp x a1 ->
      var_not_used_in_aexp x a2 ->
      var_not_used_in_aexp x (<{ a1 - a2 }>)
  | VNUMult : forall a1 a2,
      var_not_used_in_aexp x a1 ->
      var_not_used_in_aexp x a2 ->
      var_not_used_in_aexp x (<{ a1 * a2 }>).

Lemma aeval_weakening : forall x st a ni,
  var_not_used_in_aexp x a ->
  aeval (x !-> ni ; st) a = aeval st a.
Proof.
  intros x st a ni Hvar. induction Hvar; simpl; try reflexivity;
  try (rewrite IHHvar1; rewrite IHHvar2; reflexivity).
  - rewrite t_update_neq; auto.
Qed.

(** Using [var_not_used_in_aexp], formalize and prove a correct version
    of [subst_equiv_property]. *)

(* FILL IN HERE

    [] *)
Definition subst_equiv_property_correct : Prop := forall x1 x2 a1 a2,
  var_not_used_in_aexp x1 a1 ->
  cequiv <{ x1 := a1; x2 := a2 }>
         <{ x1 := a1; x2 := subst_aexp x1 a1 a2 }>.
         
Ltac H_inversion := match goal with
  | H1 : ?st =[ ?x1 := ?a1 ]=> ?st', H2 : ?st' =[ ?x2 := ?a2 ]=> ?st'' |- _ =>
      inversion H1; subst; inversion H2; subst
  end.

Ltac apply_e_seq := match goal with 
  | |- ?st =[ ?x1 := ?a1; ?x2 := _ ]=> ?st' => 
    apply E_Seq with (x1 !-> aeval st a1; st); apply E_Asgn; simpl; try reflexivity
  end.

Ltac seq_inversion := match goal with
  | H : ?st =[ ?x1 := ?a1; ?x2 := ?a2 ]=> ?st' |- _ =>
    inversion H; subst; H_inversion
end.

Ltac string_decision := match goal with
  | |- context[if (?x1 =? ?x)%string then _ else _] => destruct (x1 =? x)%string eqn:Hx;
       [apply String.eqb_eq in Hx; rewrite Hx; simpl; rewrite t_update_eq
        | apply String.eqb_neq in Hx; simpl; rewrite t_update_neq]; auto
end.
  
Lemma var_not_used_eval : forall x a n st, 
  var_not_used_in_aexp x a -> aeval (x !-> n; st) a = aeval st a.
Proof.
  intros x a n st Hvar. induction Hvar;
  try (simpl; rewrite IHHvar1; rewrite IHHvar2; reflexivity).
  - reflexivity.
  - simpl. rewrite t_update_neq; auto.
Qed.

Ltac var_not_used := match goal with
  | Hvar : var_not_used_in_aexp ?x ?a |- context[aeval (?x !-> ?n; ?st) ?a] => 
    apply (var_not_used_eval _ _ n st) in Hvar; rewrite Hvar
end.

Lemma equiv_eval : forall st x1 x2 n a, 
  cequiv <{ x1 := n; x2 := a }> <{ x1 := n; x2 := (subst_aexp x1 n a) }>
  -> aeval (x1 !-> aeval st n; st) a = aeval (x1 !-> aeval st n; st) (subst_aexp x1 n a).
Proof.
  intros st x1 x2 n a H. unfold cequiv in H.
  specialize H with st (x2 !-> aeval (x1 !-> aeval st n; st) a; x1 !-> aeval st n; st).
  destruct H as [H1 H2].
  assert (st =[ x1 := n; x2 := a ]=> (x2 !-> aeval (x1 !-> aeval st n; st) a; x1 !-> aeval st n; st)).
  { apply_e_seq. }
  apply H1 in H. seq_inversion.
  clear H4 H7 H H2 H1. 
  simpl. simpl in H8. 
  assert (forall x, (x2 !-> aeval (x1 !-> aeval st n; st) (subst_aexp x1 n a); x1 !-> aeval st n; st) x =
  (x2 !-> aeval (x1 !-> aeval st n; st) a; x1 !-> aeval st n; st) x).
  { apply equal_f. assumption. }
  clear H8. specialize H with x2. 
  repeat rewrite t_update_eq in H.
  rewrite H. reflexivity.
Qed.
  
Ltac apply_equiv_eval st := match goal with
  | H : cequiv <{ ?x1 := ?n; ?x2 := ?a }> <{ ?x1 := ?n; ?x2 := (subst_aexp ?x1 ?n ?a) }>
    |- _ => apply (equiv_eval st) in H; simpl in H; rewrite H
  end.

Theorem subst_equiv : subst_equiv_property_correct.
Proof.
  intros x1 x2 a1 a2 Hvar. 
  induction a2; induction Hvar; simpl;
  try (intros st st'; split; intros H'; seq_inversion; apply_e_seq);
  try string_decision;
  try (subst; repeat var_not_used; reflexivity);
  try (repeat apply_equiv_eval st; reflexivity).
  - subst. rewrite t_update_neq; auto.
  - subst. rewrite t_update_neq; auto.
Qed.

(** **** Exercise: 3 stars, standard (inequiv_exercise)

    Prove that an infinite loop is not equivalent to [skip] *)

Theorem inequiv_exercise:
  ~ cequiv <{ while true do skip end }> <{ skip }>.
Proof.
  unfold cequiv. intros H'.
  destruct (H' empty_st empty_st) as [_ H].
  clear H'.
  assert (empty_st =[ skip ]=> empty_st) by constructor.
  apply H in H0. clear H.
  assert (bequiv <{ true }> <{ true }>). { intro st. reflexivity. }
  apply (while_true_nonterm _ <{ skip }> empty_st empty_st) in H.
  contradiction.
Qed.

(** [] *)

(* ################################################################# *)
(** * Extended Exercise: Nondeterministic Imp *)

(** As we have seen (in theorem [ceval_deterministic] in the [Imp]
    chapter), Imp's evaluation relation is deterministic.  However,
    _non_-determinism is an important part of the definition of many
    real programming languages. For example, in many imperative
    languages (such as C and its relatives), the order in which
    function arguments are evaluated is unspecified.  The program
    fragment

      x = 0;
      f(++x, x)

    might call [f] with arguments [(1, 0)] or [(1, 1)], depending how
    the compiler chooses to order things.  This can be a little
    confusing for programmers, but it gives the compiler writer useful
    freedom.

    In this exercise, we will extend Imp with a simple
    nondeterministic command and study how this change affects
    program equivalence.  The new command has the syntax [HAVOC X],
    where [X] is an identifier. The effect of executing [HAVOC X] is
    to assign an _arbitrary_ number to the variable [X],
    nondeterministically. For example, after executing the program:

      HAVOC Y;
      Z := Y * 2

    the value of [Y] can be any number, while the value of [Z] is
    twice that of [Y] (so [Z] is always even). Note that we are not
    saying anything about the _probabilities_ of the outcomes -- just
    that there are (infinitely) many different outcomes that can
    possibly happen after executing this nondeterministic code.

    In a sense, a variable on which we do [HAVOC] roughly corresponds
    to an uninitialized variable in a low-level language like C.  After
    the [HAVOC], the variable holds a fixed but arbitrary number.  Most
    sources of nondeterminism in language definitions are there
    precisely because programmers don't care which choice is made (and
    so it is good to leave it open to the compiler to choose whichever
    will run faster).

    We call this new language _Himp_ (``Imp extended with [HAVOC]''). *)

Module Himp.

(** To formalize Himp, we first add a clause to the definition of
    commands. *)

Inductive com : Type :=
  | CSkip : com
  | CAsgn : string -> aexp -> com
  | CSeq : com -> com -> com
  | CIf : bexp -> com -> com -> com
  | CWhile : bexp -> com -> com
  | CHavoc : string -> com.                (* <--- NEW *)

Notation "'havoc' l" := (CHavoc l)
                          (in custom com at level 60, l constr at level 0).
Notation "'skip'"  :=
         CSkip (in custom com at level 0).
Notation "x := y"  :=
         (CAsgn x y)
            (in custom com at level 0, x constr at level 0,
             y at level 85, no associativity).
Notation "x ; y" :=
         (CSeq x y)
           (in custom com at level 90, right associativity).
Notation "'if' x 'then' y 'else' z 'end'" :=
         (CIf x y z)
           (in custom com at level 89, x at level 99,
            y at level 99, z at level 99).
Notation "'while' x 'do' y 'end'" :=
         (CWhile x y)
            (in custom com at level 89, x at level 99, y at level 99).

(** **** Exercise: 2 stars, standard (himp_ceval)

    Now, we must extend the operational semantics. We have provided
   a template for the [ceval] relation below, specifying the big-step
   semantics. What rule(s) must be added to the definition of [ceval]
   to formalize the behavior of the [HAVOC] command? *)

Reserved Notation "st '=[' c ']=>' st'"
         (at level 40, c custom com at level 99, st constr,
          st' constr at next level).

Inductive ceval : com -> state -> state -> Prop :=
  | E_Skip : forall st,
      st =[ skip ]=> st
  | E_Asgn  : forall st a n x,
      aeval st a = n ->
      st =[ x := a ]=> (x !-> n ; st)
  | E_Seq : forall c1 c2 st st' st'',
      st  =[ c1 ]=> st'  ->
      st' =[ c2 ]=> st'' ->
      st  =[ c1 ; c2 ]=> st''
  | E_IfTrue : forall st st' b c1 c2,
      beval st b = true ->
      st =[ c1 ]=> st' ->
      st =[ if b then c1 else c2 end ]=> st'
  | E_IfFalse : forall st st' b c1 c2,
      beval st b = false ->
      st =[ c2 ]=> st' ->
      st =[ if b then c1 else c2 end ]=> st'
  | E_WhileFalse : forall b st c,
      beval st b = false ->
      st =[ while b do c end ]=> st
  | E_WhileTrue : forall st st' st'' b c,
      beval st b = true ->
      st  =[ c ]=> st' ->
      st' =[ while b do c end ]=> st'' ->
      st  =[ while b do c end ]=> st''
  | E_Havoc : forall st x n,
    st =[ havoc x ]=> (x !-> n; st)
  where "st =[ c ]=> st'" := (ceval c st st').

(** As a sanity check, the following claims should be provable for
    your definition: *)

Example havoc_example1 : empty_st =[ havoc X ]=> (X !-> 0).
Proof. apply E_Havoc. Qed.

Example havoc_example2 :
  empty_st =[ skip; havoc Z ]=> (Z !-> 42).
Proof.
  apply E_Seq with empty_st; constructor.
Qed.

(* Do not modify the following line: *)
Definition manual_grade_for_Check_rule_for_HAVOC : option (nat*string) := None.
(** [] *)

(** Finally, we repeat the definition of command equivalence from above: *)

Definition cequiv (c1 c2 : com) : Prop := forall st st' : state,
  st =[ c1 ]=> st' <-> st =[ c2 ]=> st'.

(** Let's apply this definition to prove some nondeterministic
    programs equivalent / inequivalent. *)

(** **** Exercise: 3 stars, standard (havoc_swap)

    Are the following two programs equivalent? *)

Definition pXY :=
  <{ havoc X ; havoc Y }>.

Definition pYX :=
  <{ havoc Y; havoc X }>.

(** If you think they are equivalent, prove it. If you think they are
    not, prove that. *)

Theorem pXY_cequiv_pYX :
  cequiv pXY pYX \/ ~cequiv pXY pYX.
Proof.
  left. intros st st'. unfold pXY. unfold pYX.
  split; intros H; inversion H; subst.
  - inversion H2. subst. inversion H5. subst.
    apply E_Seq with (Y !-> n0; st).
    * constructor.
    * assert ((X !-> n; Y !-> n0; st) = (Y !-> n0; X !-> n; st)).
      { apply t_update_permute. discriminate. }
      rewrite <- H0. constructor.
  - inversion H2. subst. inversion H5. subst.
    apply E_Seq with (X !-> n0; st).
    * constructor.
    * assert ((X !-> n0; Y !-> n; st) = (Y !-> n; X !-> n0; st)).
      { apply t_update_permute. discriminate. }
      rewrite H0. constructor.
Qed.

(** [] *)

(** **** Exercise: 4 stars, standard, optional (havoc_copy)

    Are the following two programs equivalent? *)

Definition ptwice :=
  <{ havoc X; havoc Y }>.

Definition pcopy :=
  <{ havoc X; Y := X }>.

(** If you think they are equivalent, then prove it. If you think they
    are not, then prove that.  (Hint: You may find the [assert] tactic
    useful.) *)

Theorem ptwice_cequiv_pcopy :
  cequiv ptwice pcopy \/ ~cequiv ptwice pcopy.
Proof.
  right. unfold cequiv. unfold ptwice. unfold pcopy.
  intros H'. specialize H' with empty_st (Y !-> 3; X !-> 4).
  destruct H' as [H _]. 
  assert (empty_st =[ havoc X; havoc Y ]=> (Y !-> 3; X !-> 4)).
  { apply E_Seq with (X !-> 4); constructor. }
  apply H in H0. clear H.
  inversion H0. subst. inversion H2. subst. inversion H5. subst.
  simpl in H6.
  assert (~(forall x, (Y !-> (X !-> n) X; X !-> n) x = (Y !-> 3; X !-> 4) x)).
  { intros contra. destruct (eq_dec n 3).
    { specialize contra with X. rewrite e in contra. 
      rewrite t_update_neq in contra; [.. | discriminate].
      rewrite t_update_eq in contra.
      rewrite t_update_neq in contra; [.. | discriminate].
      rewrite t_update_eq in contra. discriminate contra.
    }
    { specialize contra with Y. repeat rewrite t_update_eq in contra.
      contradiction. }
  }
  apply H. apply equal_f. assumption.
Qed.

(** [] *)

(** The definition of program equivalence we are using here has some
    subtle consequences on programs that may loop forever.  What
    [cequiv] says is that the set of possible _terminating_ outcomes
    of two equivalent programs is the same. However, in a language
    with nondeterminism, like Himp, some programs always terminate,
    some programs always diverge, and some programs can
    nondeterministically terminate in some runs and diverge in
    others. The final part of the following exercise illustrates this
    phenomenon.
*)

(** **** Exercise: 4 stars, advanced (p1_p2_term)

    Consider the following commands: *)

Definition p1 : com :=
  <{ while ~ (X = 0) do
       havoc Y;
       X := X + 1
     end }>.

Definition p2 : com :=
  <{ while ~ (X = 0) do
       skip
     end }>.

(** Intuitively, [p1] and [p2] have the same termination behavior:
    either they loop forever, or they terminate in the same state they
    started in.  We can capture the termination behavior of [p1] and
    [p2] individually with these lemmas: *)

Lemma p1_may_diverge : forall st st', st X <> 0 ->
  ~ st =[ p1 ]=> st'.
Proof.
  unfold p1. intros st st' Hst Hwhile.
  remember <{ while ~ X = 0 do havoc Y; X := X + 1 end }> as cw eqn:Heqcw.
  induction Hwhile; inversion Heqcw; subst; clear Heqcw.
  - simpl in H. apply negb_false_iff in H. apply eqb_eq in H. contradiction.
  - inversion Hwhile1. subst. inversion H2. subst. inversion H5. subst.
    apply IHHwhile2.
    * simpl. rewrite t_update_eq. rewrite t_update_neq.
      + rewrite add_1_r. apply neq_succ_0.
      + discriminate.
    * reflexivity.
Qed.

Lemma p2_may_diverge : forall st st', st X <> 0 ->
  ~ st =[ p2 ]=> st'.
Proof.
  unfold p2. intros st st' Hst Hwhile.
  remember <{ while ~ X = 0 do skip end }> as cw eqn:Heqcw.
  induction Hwhile; inversion Heqcw; subst; clear Heqcw.
  - simpl in H. apply negb_false_iff in H. apply eqb_eq in H. contradiction.
  - inversion Hwhile1. subst. apply IHHwhile2; auto.
Qed.

(** [] *)

(** **** Exercise: 4 stars, advanced (p1_p2_equiv)

    Use these two lemmas to prove that [p1] and [p2] are actually
    equivalent. *)

Theorem p1_p2_equiv : cequiv p1 p2.
Proof.
  unfold p1. unfold p2.
  intros st st'. destruct (st X) eqn:HstX.
  - split; intros H; inversion H; subst.
    * apply E_WhileFalse. assumption.
    * simpl in H2. rewrite HstX in H2. discriminate H2.
    * apply E_WhileFalse. assumption.
    * simpl in H2. rewrite HstX in H2. discriminate H2.
  - assert (st X <> 0) as Hneq. { rewrite HstX. discriminate. }
    apply (p1_may_diverge st st') in Hneq as Hp1.
    apply (p2_may_diverge st st') in Hneq as Hp2.
    split; intros contra; contradiction.
Qed.

(** [] *)

(** **** Exercise: 4 stars, advanced (p3_p4_inequiv)

    Prove that the following programs are _not_ equivalent.  (Hint:
    What should the value of [Z] be when [p3] terminates?  What about
    [p4]?) *)

Definition p3 : com :=
  <{ Z := 1;
     while X <> 0 do
       havoc X;
       havoc Z
     end }>.

Definition p4 : com :=
  <{ X := 0;
     Z := 1 }>.

Theorem p3_p4_inequiv : ~ cequiv p3 p4.
Proof.
  unfold p3. unfold p4. unfold cequiv.
  intros H'. specialize H' with (st := X !-> 1).
  edestruct H' as [H _]. 
  eassert ((X !-> 1) =[ Z := 1; while X <> 0 do havoc X; havoc Z end ]=> _) as Heval.
  { eapply E_Seq.
    { eapply E_Asgn. simpl. eexists. }
    { eapply E_WhileTrue.
      { reflexivity. }
      { apply E_Seq with (X !-> 0; Z !-> 1; X !-> 1); apply E_Havoc. }
      { apply E_WhileFalse. reflexivity. }
    }
  }
  apply H in Heval.
  inversion Heval. subst.
  inversion H2. subst. inversion H5. subst.
  simpl in H6.
  eapply equal_f in H6.
  instantiate (1 := Z) in H6.
  instantiate (1 := 3) in H6.
  repeat rewrite t_update_eq in H6.
  discriminate H6.
Qed.

(** [] *)

(** **** Exercise: 5 stars, advanced, optional (p5_p6_equiv)

    Prove that the following commands are equivalent.  (Hint: As
    mentioned above, our definition of [cequiv] for Himp only takes
    into account the sets of possible terminating configurations: two
    programs are equivalent if and only if the set of possible terminating
    states is the same for both programs when given a same starting state
    [st].  If [p5] terminates, what should the final state be? Conversely,
    is it always possible to make [p5] terminate?) *)

Definition p5 : com :=
  <{ while X <> 1 do
       havoc X
     end }>.

Definition p6 : com :=
  <{ X := 1 }>.

Theorem p5_p6_equiv : cequiv p5 p6.
Proof.
  unfold p5. unfold p6.
  intros st st'.
  split; intros H.
  - remember <{ while X <> 1 do havoc X end }> as cw eqn:Heqcw.
    induction H; inversion Heqcw; subst.
    * simpl in H. apply negb_false_iff in H. apply eqb_eq in H.
      assert (st = (X !-> 1; st)) as Heq.
      { apply functional_extensionality. intros x. destruct (string_dec x X).
        { rewrite e. rewrite t_update_eq. assumption. }
        { rewrite t_update_neq; auto. }
      }
      rewrite Heq at 2. apply E_Asgn. reflexivity.
    * assert (<{ while X <> 1 do havoc X end }> = <{ while X <> 1 do havoc X end }>). { auto. }
      apply IHceval2 in H2. inversion H2. subst. simpl.
      inversion H0. subst.
      assert ((X !-> 1; X !-> n; st) = (X !-> 1; st)) as Heq.
      { apply functional_extensionality. intros x. destruct (string_dec x X).
        { rewrite e. repeat rewrite t_update_eq. reflexivity. }
        { repeat (rewrite t_update_neq; auto). }
      }
      rewrite Heq. apply E_Asgn. reflexivity.
  - inversion H. subst. simpl.
    destruct (eq_dec (st X) 1).
    * assert (st = (X !-> 1; st)) as Heq.
      { apply functional_extensionality. intros x. destruct (string_dec x X).
        { rewrite e0. rewrite t_update_eq. auto. }
        { rewrite t_update_neq; auto. }
      }
      rewrite <- Heq. apply E_WhileFalse.
      simpl. rewrite e. reflexivity.
    * eapply E_WhileTrue.
      + simpl. apply negb_true_iff. apply eqb_neq. assumption.
      + apply E_Havoc.
      + instantiate (1 := 1). apply E_WhileFalse. reflexivity.
Qed.
(** [] *)

End Himp.

(* ################################################################# *)
(** * Additional Exercises *)

(** **** Exercise: 3 stars, standard, optional (swap_noninterfering_assignments)

    (Hint: You may or may not -- depending how you approach it -- need
    to use [functional_extensionality] explicitly for this one.) *)

Theorem swap_noninterfering_assignments: forall l1 l2 a1 a2,
  l1 <> l2 ->
  var_not_used_in_aexp l1 a2 ->
  var_not_used_in_aexp l2 a1 ->
  cequiv
    <{ l1 := a1; l2 := a2 }>
    <{ l2 := a2; l1 := a1 }>.
Proof.
  intros l1 l2 a1 a2 Hneq Hl1 Hl2 st st'.
  split; intros H; inversion H; subst; inversion H2; subst; inversion H5; subst.
  - eapply aeval_weakening in Hl1. rewrite Hl1.
    eapply E_Seq.
    * apply E_Asgn. eexists.
    * rewrite t_update_permute; auto.
      apply E_Asgn. apply aeval_weakening. assumption.
  - eapply aeval_weakening in Hl2. rewrite Hl2.
    eapply E_Seq.
    * apply E_Asgn. eexists.
    * rewrite t_update_permute; auto.
      apply E_Asgn. apply aeval_weakening. assumption.
Qed.

(** [] *)

(** **** Exercise: 4 stars, standard, optional (for_while_equiv)

    This exercise extends the optional [add_for_loop] exercise from
    the [Imp] chapter, where you were asked to extend the language
    of commands with C-style [for] loops.  Prove that the command:

      for (c1; b; c2) {
          c3
      }

    is equivalent to:

       c1;
       while b do
         c3;
         c2
       end
*)
(* FILL IN HERE

    [] *)
Print Libraries.
Module FImp.

From PLF Require Import Imp.
Include Imp.ForImp.

Theorem for_while_equiv : forall c1 c2 c3 b st st',
  st =[ for c1 : b : c2 do c3 end ]=> st' <-> st =[ c1; while b do c3; c2 end ]=> st'.
Proof.
  intros c1 c2 c3 b st st'. split; intros H.
  - inversion H. subst. eapply E_Seq; eauto.
  - inversion H. subst. eapply E_For; eauto.
Qed.

End FImp.

(** **** Exercise: 4 stars, advanced, optional (capprox)

    In this exercise we define an asymmetric variant of program
    equivalence we call _program approximation_. We say that a
    program [c1] _approximates_ a program [c2] when, for each of
    the initial states for which [c1] terminates, [c2] also terminates
    and produces the same final state. Formally, program approximation
    is defined as follows: *)

Definition capprox (c1 c2 : com) : Prop := forall (st st' : state),
  st =[ c1 ]=> st' -> st =[ c2 ]=> st'.

(** For example, the program

  c1 = while X <> 1 do
         X := X - 1
       end

    approximates [c2 = X := 1], but [c2] does not approximate [c1]
    since [c1] does not terminate when [X = 0] but [c2] does.  If two
    programs approximate each other in both directions, then they are
    equivalent. *)

(** Find two programs [c3] and [c4] such that neither approximates
    the other. *)

Definition c3 : com := <{ X := 1 }>.

Definition c4 : com := <{ X := 3}>.

Theorem c3_c4_different : ~ capprox c3 c4 /\ ~ capprox c4 c3.
Proof.
  unfold capprox. unfold c3. unfold c4.
  split; intros H; specialize H with (st := empty_st);
  [eassert (empty_st =[ X := 1 ]=> _) as Htrue by (constructor; reflexivity) 
    | eassert (empty_st =[ X := 3 ]=> _) as Htrue by (constructor; reflexivity)];
  simpl in Htrue; apply H in Htrue; inversion Htrue; subst;
  simpl in H4; eapply equal_f in H4; instantiate (1 := X) in H4;
  repeat rewrite t_update_eq in H4; discriminate H4.
Qed.

(** Find a program [cmin] that approximates every other program. *)

Definition cmin : com := <{ while true do skip end }>.

Theorem cmin_minimal : forall c, capprox cmin c.
Proof.
  intros c st st'. unfold cmin. intros Hmin.
  assert (bequiv <{ true }> <{ true }>). { intros st0. reflexivity. }
  apply (while_true_nonterm _ <{ skip }> st st') in H.
  contradiction.
Qed.

(** Finally, find a non-trivial property which is preserved by
    program approximation (when going from left to right). *)
(* The program always terminates *)
Definition zprop (c : com) : Prop := forall st, exists st', st =[ c ]=> st'.

Theorem zprop_preserving : forall c c',
  zprop c -> capprox c c' -> zprop c'.
Proof.
  unfold zprop. unfold capprox.
  intros c c' Hz Happrox. intros st.
  specialize Hz with st. destruct Hz as [st' Hz].
  exists st'. apply Happrox. assumption.
Qed.
(** [] *)

(* 2025-01-06 19:48 *)