add Tests

Author: findmyway

Project.toml

@@ -3,11 +3,20 @@ uuid = "d3baf920-4533-4796-be79-acb40839d791"
 authors = ["Jun Tian <[email protected]> and contributors"]
 version = "0.1.0"
 
-[extras]
-Test = "8dfed614-e22c-5e08-85e1-65c5234f0b40"
+[deps]
+JSON3 = "0f8b85d8-7281-11e9-16c2-39a750bddbf1"
+TimeZones = "f269a46b-ccf7-5d73-abea-4c690281aa53"
+URIs = "5c2747f8-b7ea-4ff2-ba2e-563bfd36b1d4"
+UUIDs = "cf7118a7-6976-5b1a-9a39-7adc72f591a4"
 
 [compat]
 julia = "1"
+JSON3 = "1"
+TimeZones = "1"
+URIs = "1"
+
+[extras]
+Test = "8dfed614-e22c-5e08-85e1-65c5234f0b40"
 
 [targets]
 test = ["Test"]

README.md

@@ -1 +1,29 @@
 # CloudEvents
+
+This package provides the Julia SDK for [CloudEvents](https://github.com/cloudevents/spec).
+
+## Basic Usage
+
+Below we provide the most common usages.
+
+```julia
+using CloudEvents
+
+# Create a CloudEvent manually
+data = Dict("message" => "Hello World!")
+ce = CloudEvent(data; type="example", source="https://example.com/event-producer")
+
+headers, body = to_http(ce)  # structure mode by default
+# headers, body = to_http(ce, :binary)  # or binary mode
+
+# Send CloudEvent
+using HTTP
+
+HTTP.post("<your url>", headers, body)
+
+# Receive CloudEvent
+using JSON3
+HTTP.serve() do req
+    ce = from_http(HTTP.headers(req), JSON3.read(req.body))
+end
+```

src/CloudEvents.jl

@@ -1,5 +1,6 @@
 module CloudEvents
 
-# Write your package code here.
+include("cloud_event.jl")
+include("http.jl")
 
 end

src/cloud_event.jl

@@ -0,0 +1,107 @@
+export CloudEvent
+
+using URIs: URI
+using TimeZones: ZonedDateTime, localzone, now
+using UUIDs: uuid4
+
+mutable struct CloudEvent{T}
+    # required
+    id::String
+    source::URI
+    specversion::String
+    type::String
+
+    # optional
+    datacontenttype::Union{String,Nothing}
+    dataschema::Union{URI,Nothing}
+    subject::Union{String,Nothing}
+    time::Union{ZonedDateTime,Nothing}
+
+    # extra
+    extensions::Dict
+
+    data::T
+
+    function CloudEvent(id, source, specversion, type, datacontenttype, dataschema, subject, time, extensions, data)
+        if source isa String
+            source = URI(source)
+        end
+        if time isa String
+            time = ZonedDateTime(time, "yyyy-mm-ddTHH:MM:SSz")
+        end
+        if dataschema isa String
+            dataschema = URI(dataschema)
+        end
+
+        specversion == "0.3" || specversion == "1.0" || @error "unknown specversion $specversion"
+
+        new{typeof(data)}(id, source, specversion, type, datacontenttype, dataschema, subject, time, extensions, data)
+    end
+end
+
+required_fields(::Type{<:CloudEvent}) = ("id", "source", "specversion", "type")
+optional_fields(::Type{<:CloudEvent}) = ("datacontenttype", "dataschema", "subject", "time")
+known_fields(ce::Type{<:CloudEvent}) = (required_fields(ce)..., optional_fields(ce)...)
+
+function CloudEvent(
+    data
+    ; type,
+    source,
+    id=string(uuid4()),
+    time=now(localzone()),
+    specversion="1.0",
+    datacontenttype=nothing,
+    dataschema=nothing,
+    subject=nothing,
+    kw...
+)
+    extensions = Dict(convert(String, k) => v for (k, v) in kw)
+    CloudEvent(id, source, specversion, type, datacontenttype, dataschema, subject, time, extensions, data)
+end
+
+Base.getindex(ce::CloudEvent) = ce.data
+
+function Base.getindex(ce::CloudEvent, k::String)
+    if k in known_fields(typeof(ce))
+        getfield(ce, Symbol(k))
+    else
+        get(ce.extensions, k, nothing)
+    end
+end
+
+Base.setindex!(ce::CloudEvent, v) = ce.data = v
+
+function Base.setindex!(ce::CloudEvent, v, k)
+    if k in known_fields(typeof(ce))
+        setfield!(ce, Symbol(k), v)
+    else
+        setindex!(ce.extensions, v, k)
+    end
+end
+
+Base.keys(ce::CloudEvent) = (known_fields(typeof(ce))..., keys(ce.extensions)...)
+
+function Base.convert(::Type{Dict}, ce::CloudEvent)
+    res = Dict(
+        "id" => ce.id,
+        "source" => ce.resource,
+        "specversion" => ce.specversion,
+        "type" => ce.type,
+        "datacontenttype" => ce.datacontenttype,
+        "dataschema" => ce.dataschema,
+        "subject" => ce.subject,
+        "time" => ce.time
+        ;
+        ce.extensions...
+    )
+
+    res["data"] = ce.data
+    res
+end
+
+Base.convert(T::Type{<:CloudEvent}, x::AbstractDict) = CloudEvent(
+    (x[f] for f in required_fields(T))...,
+    (get(x, f, nothing) for f in optional_fields(T))...,
+    Dict(f => x[f] for f in keys(x) if x ∉ known_fields(T)),
+    get(x, "data", nothing)
+)

src/http.jl

@@ -0,0 +1,41 @@
+export from_http, to_http
+
+using JSON3
+
+function from_http(headers, body)
+    content_type = "application/cloudevents+json"
+
+    ce = Dict()
+    for (k, v) in headers
+        k = lowercase(k)
+        if k == "content-type"
+            content_type = v
+        elseif startswith(k, "ce-")
+            ce[k[4:end]] = v
+        end
+    end
+    ce["data"] = body
+
+    # FIXME: `application/json; charset=utf-8` is not handled
+    if content_type == "application/cloudevents+json"
+        ce = Dict(string(k) => v for (k, v) in pairs(JSON3.read(body)))
+    end
+
+    convert(CloudEvent, ce)
+end
+
+to_http(ce::CloudEvent, mode::Symbol=:structure) = to_http(ce, Val(mode))
+
+# https://github.com/cloudevents/spec/blob/main/cloudevents/bindings/http-protocol-binding.md#31-binary-content-mode
+function to_http(ce::CloudEvent, ::Val{:binary})
+    headers = ["ce-$k" => string(ce[k]) for k in keys(ce) if !isnothing(ce[k])]
+    body = ce[]
+    headers, body
+end
+
+# https://github.com/cloudevents/spec/blob/main/cloudevents/bindings/http-protocol-binding.md#32-structured-content-mode
+function to_http(ce::CloudEvent, ::Val{:structure})
+    headers = ["Content-Type" => "application/cloudevents+json"]
+    body = JSON3.write(Dict(k => string(ce[k]) for k in keys(ce) if !isnothing(ce[k]))) # TODO: more efficient, allow custom serialization
+    headers, body
+end

test/runtests.jl

@@ -1,6 +1,35 @@
 using CloudEvents
 using Test
+using JSON3
 
 @testset "CloudEvents.jl" begin
-    # Write your tests here.
+
+    @testset "uppercase header" begin
+        headers = [
+            "Ce-Id" => "my-id",
+            "Ce-Source" => "<event-source>",
+            "Ce-Type" => "cloudevent.event.type",
+            "Ce-Specversion" => "1.0",
+            "Content-Type" => "text/plain"
+        ]
+
+        ce = from_http(headers, nothing)
+
+        @test isnothing(ce[])
+    end
+
+    @testset "cloudevents+json" begin
+        headers = ["Content-Type" => "application/cloudevents+json"]
+        body = JSON3.write(Dict(
+            "specversion" => "1.0",
+            "source" => "s",
+            "type" => "t",
+            "id" => "1234-1234-1234",
+            "data" => Dict("foo" => "bar"),
+            "extra_baz" => "baz"
+        ))
+        ce = from_http(headers, body)
+        @test ce["extra_baz"] == "baz"
+        headers, body = to_http(ce)
+    end
 end