NixOS #36

yuchangyuan · 2022-06-10T10:39:36Z

yuchangyuan
Jun 10, 2022

An incomplete is nix package for sunshine(file name sunshine.nix), lack nvidia support and metadata is incomplete. and this file should use with callPackage.

{ stdenv, fetchgit, cmake, pkgconfig
, openssl, boost, libpulseaudio, libopus, ffmpeg, libevdev, libffi
, xorg
, libdrm, libcap, mesa
, wayland
, avahi }:
stdenv.mkDerivation rec {
  name = "sunshine-" + version;
  version = "v0.13.0";

  src = fetchgit {
    url = "https://github.com/SunshineStream/Sunshine.git";
    fetchSubmodules = true;
    rev = "refs/tags/${version}";
    sha256 = "1nwm2v62gpxs5wyyyxgj24xkf3hsbvfmj7pycdzp526kkv9l1yxm";
  };

  nativeBuildInputs = [ pkgconfig cmake ];

  postPatch = ''
    sed -i -e 's|/usr/include/libevdev-1.0|${libevdev}/include/libevdev-1.0|' ./CMakeLists.txt
    sed -i -e 's/-Wno-format/-Wno-format -Wno-format-security/' ./third-party/cbs/CMakeLists.txt

    # fix ASSETS_DIR
    sed -i -e '4iset(SUNSHINE_ASSETS_DIR "'$out'/share/assets")' ./CMakeLists.txt
  '';

  buildInputs = [
    # common
    openssl libpulseaudio libopus ffmpeg libevdev libffi
    (boost.override { enableShared = false; }) # boost need static
    # x11
    xorg.libXtst xorg.libX11 xorg.libXrandr xorg.libXfixes xorg.libxcb
    # kms
    libdrm libcap
    # wayland
    wayland
  ];

  installPhase = ''
    mkdir -p $out/bin
    cp -a sunshine sunshine-* $out/bin

    mkdir -p $out/share
    cp -a ../assets $out/share
  '';

  postFixup = ''
    patchelf \
      --set-rpath $(patchelf --print-rpath $out/bin/sunshine-*):${mesa}/lib:${avahi}/lib:/run/opengl-driver/lib \
      $out/bin/sunshine-*
  '';

  meta = {
    homepage = https://sunshinestream.github.io;
    description = "Sunshine is a Gamestream host for Moonlight! Stream your PC to any supported Moonlight client app.";
  };
}

And opengl should be enabled, use below config as reference:

    hardware.opengl = {
      enable = true;

      extraPackages = with pkgs; [
        vaapiIntel # enable intel vaapi support
        intel-compute-runtime
        opencl-icd
        libGL # for libEGL.so
      ];
    };

and sunshine executable should be wrapper for cap_sys_admin:

      security.wrappers = {
        sunshine = {
          owner = "root";
          group = "root";
          capabilities = "cap_sys_admin+p";
          source = "${mypkgs.sunshine}/bin/sunshine";
        };
      };

please note that mypkgs.sunshine in above config is the sunshine package to be wrapped.

yuchangyuan · 2022-09-13T12:52:06Z

yuchangyuan
Sep 13, 2022
Author

update for NixOS 22.05

{ stdenv, fetchgit, cmake, pkgconfig
, openssl, boost, libpulseaudio, libopus, ffmpeg, libevdev, libffi
, icu
, xorg
, libdrm, libcap, mesa
, wayland
, avahi }:
stdenv.mkDerivation rec {
  name = "sunshine-" + version;
  version = "v0.14.1";

  src = fetchgit {
    url = "https://github.com/SunshineStream/Sunshine.git";
    fetchSubmodules = true;
    rev = "refs/tags/${version}";
    sha256 = "156nqgrwygvwm47acvyv42hgk4mpn06i6mh4qg42rnhzwq0867a8";
  };

  nativeBuildInputs = [ pkgconfig cmake ];

  postPatch = ''
    sed -i -e 's|/usr/include/libevdev-1.0|${libevdev}/include/libevdev-1.0|' ./CMakeLists.txt
    sed -i -e 's/-Wno-format/-Wno-format -Wno-format-security/' ./third-party/cbs/CMakeLists.txt

    # fix ASSETS_DIR
    sed -i -e '/PROJECT_LONG_DESCRIPTION/iset(SUNSHINE_ASSETS_DIR "share/assets")' ./CMakeLists.txt
    sed -i -e '/PROJECT_LONG_DESCRIPTION/iset(SUNSHINE_CONFIG_DIR "share/config")' ./CMakeLists.txt

    # fix for cmake
    sed -i -e '/HOMEPAGE_URL.*lizardbyte/aLANGUAGES C CXX' ./CMakeLists.txt
  '';

  buildInputs = [
    # common
    openssl libpulseaudio libopus ffmpeg libevdev libffi
    icu
    (boost.override { enableShared = false; }) # boost need static
    # x11
    xorg.libXtst xorg.libX11 xorg.libXrandr xorg.libXfixes xorg.libxcb
    # kms
    libdrm libcap
    # wayland
    wayland
  ];

  postFixup = ''
    patchelf \
      --set-rpath $(patchelf --print-rpath $out/bin/sunshine-*):${mesa}/lib:${avahi}/lib:/run/opengl-driver/lib \
      $out/bin/sunshine-*
  '';

  meta = {
    homepage = https://sunshinestream.github.io;
    description = "Sunshine is a Gamestream host for Moonlight! Stream your PC to any supported Moonlight client app.";
  };
}

5 replies

ReenigneArcher Sep 13, 2022
Maintainer

This is somewhat incorrect, since cmake variables were adjusted in the last release.

Why are you patching cmakelists? You can just pass these args to cmake.

yuchangyuan Sep 13, 2022
Author

This is somewhat incorrect, since cmake variables were adjusted in the last release.

yes, no so corret.

Why are you patching cmakelists? You can just pass these args to cmake.

I choose to patch cmakelists due I am neither familiar with cmake nor cmake build system in Nix, modify cmakelists directly is quickest for me. This is also why I just post here, not open an PR to NixOS.

After read some document, I think above code snippet can update as below:

{ stdenv, fetchgit, cmake, pkgconfig
, openssl, boost, libpulseaudio, libopus, ffmpeg, libevdev, libffi
, icu
, xorg
, libdrm, libcap, mesa
, wayland
, avahi }:
stdenv.mkDerivation rec {
  name = "sunshine-" + version;
  version = "v0.14.1";

  src = fetchgit {
    url = "https://github.com/SunshineStream/Sunshine.git";
    fetchSubmodules = true;
    rev = "refs/tags/${version}";
    sha256 = "156nqgrwygvwm47acvyv42hgk4mpn06i6mh4qg42rnhzwq0867a8";
  };

  nativeBuildInputs = [ pkgconfig cmake ];

  cmakeFlags = ["-DSUNSHINE_ASSETS_DIR=share/assets" "-DSUNSHINE_CONFIG_DIR=share/config"];

  postPatch = ''
    sed -i -e 's|/usr/include/libevdev-1.0|${libevdev}/include/libevdev-1.0|' ./CMakeLists.txt
    sed -i -e 's/-Wno-format/-Wno-format -Wno-format-security/' ./third-party/cbs/CMakeLists.txt

    # fix for cmake
    sed -i -e '/HOMEPAGE_URL.*lizardbyte/aLANGUAGES C CXX' ./CMakeLists.txt
  '';

  buildInputs = [
    # common
    openssl libpulseaudio libopus ffmpeg libevdev libffi
    icu
    (boost.override { enableShared = false; }) # boost need static
    # x11
    xorg.libXtst xorg.libX11 xorg.libXrandr xorg.libXfixes xorg.libxcb
    # kms
    libdrm libcap
    # wayland
    wayland
  ];

  postFixup = ''
    patchelf \
      --set-rpath $(patchelf --print-rpath $out/bin/sunshine-*):${mesa}/lib:${avahi}/lib:/run/opengl-driver/lib \
      $out/bin/sunshine-*
  '';

  meta = {
    homepage = https://sunshinestream.github.io;
    description = "Sunshine is a Gamestream host for Moonlight! Stream your PC to any supported Moonlight client app.";
  };
}

ReenigneArcher Sep 13, 2022
Maintainer

These are my comments, knowing almost nothing about NixOS, so I may not have everything 100% right. Assuming we can get a nice nix build file, we can probably integrate it directly into our project. There seem to be some github actions supporting this (e.g. https://github.com/marketplace/actions/install-nix)

updated url

url = "https://github.com/SunshineStream/Sunshine.git"; -> url = "https://github.com/LizardByte/Sunshine.git";

Sorry for the org name change, I know it's inconvenient.

flags

cmakeFlags = ["-DSUNSHINE_ASSETS_DIR=share/assets" "-DSUNSHINE_CONFIG_DIR=share/config"]; ->

cmakeFlags = ["-DCMAKE_INSTALL_PREFIX=/usr" "-DSUNSHINE_ASSETS_DIR=share/sunshine" "-DSUNSHINE_EXECUTABLE_PATH=/usr/bin/sunshine" "-DSUNSHINE_ENABLE_WAYLAND=ON" "-DSUNSHINE_ENABLE_X11=ON" "-DSUNSHINE_ENABLE_DRM=ON" "-DSUNSHINE_ENABLE_CUDA=ON"];

No idea if the above syntax is correct, but those are the flags you should probably use. Basically that is what we use during our CI builds, with one difference.

patch - adding PROJECT/LANGUAGES

The below is not necessary.

    # fix for cmake
    sed -i -e '/HOMEPAGE_URL.*lizardbyte/aLANGUAGES C CXX' ./CMakeLists.txt

Per cmake project the default values are C CXX. So you are creating a patch that does nothing.

patch - cbs

Probably easier to pass a flag on the command line, than patching the file with sed. Is there an issue with seeing the warnings?

patch - libevdev location

What is the actual path of libevdev in this build?

additional comments

Just adding this reference in the event we add to add a nixfile to the repo. http://elatov.github.io/2022/01/building-a-nix-package/

yuchangyuan Sep 14, 2022
Author

my free time in work day is quite limited, so here I do some quick reply, and will reply more details later, probably this weekend

These are my comments, knowing almost nothing about NixOS, so I may not have everything 100% right. Assuming we can get a nice nix build file, we can probably integrate it directly into our project. There seem to be some github actions supporting this (e.g. https://github.com/marketplace/actions/install-nix)

updated url

url = "https://github.com/SunshineStream/Sunshine.git"; -> url = "https://github.com/LizardByte/Sunshine.git";

Sorry for the org name change, I know it's inconvenient.

my fault, not update url

flags

cmakeFlags = ["-DSUNSHINE_ASSETS_DIR=share/assets" "-DSUNSHINE_CONFIG_DIR=share/config"]; ->

cmakeFlags = ["-DCMAKE_INSTALL_PREFIX=/usr" "-DSUNSHINE_ASSETS_DIR=share/sunshine" "-DSUNSHINE_EXECUTABLE_PATH=/usr/bin/sunshine" "-DSUNSHINE_ENABLE_WAYLAND=ON" "-DSUNSHINE_ENABLE_X11=ON" "-DSUNSHINE_ENABLE_DRM=ON" "-DSUNSHINE_ENABLE_CUDA=ON"];

CMAKE_INSTALL_PREFIX and SUNSHINE_EXECUTABLE_PATH is not necessary for Nix, actually I think this two variable will be override by cmake build system of Nix. For other options, it's better encode as argument of nix package, rather than hard encode(I will give more details later).

No idea if the above syntax is correct, but those are the flags you should probably use. Basically that is what we use during our CI builds, with one difference.

syntax is ok.

patch - adding PROJECT/LANGUAGES

The below is not necessary.
    # fix for cmake
    sed -i -e '/HOMEPAGE_URL.*lizardbyte/aLANGUAGES C CXX' ./CMakeLists.txt
Per cmake project the default values are C CXX. So you are creating a patch that does nothing.

I read the cmake document, these two language is default, but cmake in Nix complain about this, I will invest this later.

patch - cbs

Probably easier to pass a flag on the command line, than patching the file with sed. Is there an issue with seeing the warnings?

maybe build will fail without patch(gcc version of Nix is high), I do not remember the details, I will check this later.

patch - libevdev location

What is the actual path of libevdev in this build?

I will reply later.

additional comments

Just adding this reference in the event we add to add a nixfile to the repo. http://elatov.github.io/2022/01/building-a-nix-package/

yuchangyuan Sep 18, 2022
Author

below is improved nix package:

{ stdenv, fetchgit, cmake, pkgconfig
, lib
, openssl, boost, libpulseaudio, libopus, ffmpeg, libevdev, libffi
, icu
, xorg
, libdrm, libcap, mesa
, wayland
, avahi
, cudatoolkit
, enableWayland ? true
, enableDrm ? true
, enableCuda ? false
}:
stdenv.mkDerivation rec {
  name = "sunshine-" + version;
  version = "v0.14.1";

  src = fetchgit {
    url = "https://github.com/LizardByte/Sunshine.git";
    fetchSubmodules = true;
    rev = "refs/tags/${version}";
    sha256 = "156nqgrwygvwm47acvyv42hgk4mpn06i6mh4qg42rnhzwq0867a8";
  };

  nativeBuildInputs = [ pkgconfig cmake ] ++
                      lib.optional enableCuda cudatoolkit;

  cmakeFlags = ["-DSUNSHINE_ASSETS_DIR=share/assets" "-DSUNSHINE_CONFIG_DIR=share/config"] ++
               # always enable X11
               ["-DSUNSHINE_ENABLE_X11=ON"] ++
               lib.optional enableWayland "-DSUNSHINE_ENABLE_WAYLAND=ON" ++
               lib.optional enableDrm "-DSUNSHINE_ENABLE_DRM=ON" ++
               lib.optional enableCuda "-DSUNSHINE_ENABLE_CUDA=ON";

  postPatch = ''
    sed -i -e 's|/usr/include/libevdev-1.0|${libevdev}/include/libevdev-1.0|' ./CMakeLists.txt
    sed -i -e 's/-Wno-format/-Wno-format -Wno-format-security/' ./third-party/cbs/CMakeLists.txt
  '';

  buildInputs = [
    # common
    openssl libpulseaudio libopus ffmpeg libevdev libffi
    icu
    (boost.override { enableShared = false; }) # boost need static
    # x11
    xorg.libXtst xorg.libX11 xorg.libXrandr xorg.libXfixes xorg.libxcb
  ] ++
  lib.optionals enableWayland [
    # wayland
    wayland
  ] ++
  lib.optionals enableDrm [
    # kms
    libdrm libcap
  ];

  postFixup = ''
    patchelf \
      --set-rpath $(patchelf --print-rpath $out/bin/sunshine-*):${mesa}/lib:${avahi}/lib:/run/opengl-driver/lib \
      $out/bin/sunshine-*
  '';

  meta = with lib; {
    description = "Sunshine is a Gamestream host for Moonlight.";
    longDescription = ''
      Sunshine is a self hosted, low latency, cloud gaming solution with support for AMD,
      Intel, and Nvidia GPUs. It is an open source implementation of NVIDIA's GameStream, as used by the NVIDIA Shield.
      Connect to Sunshine from any Moonlight client, available for nearly any device imaginable.
    '';
    homepage = https://app.lizardbyte.dev;
    changelog = "https://github.com/LizardByte/Sunshine/releases/tag/${version}";
    license = licenses.gpl3;
    platforms = platforms.linux;
  };
}

and below is more detailed reply(I simplified some quote):

CMAKE_INSTALL_PREFIX and SUNSHINE_EXECUTABLE_PATH is not necessary for Nix, actually I think this two variable will be override by cmake build system of Nix. For other options, it's better encode as argument of nix package, rather than hard encode(I will give more details later).

Optional feature is controlled by package argument in above improved nix package, which can be easily overrided, and X11 is always enabled, due lack of X11 will cause some dependency compile fail.

patch - adding PROJECT/LANGUAGES

The below is not necessary.
    # fix for cmake
    sed -i -e '/HOMEPAGE_URL.*lizardbyte/aLANGUAGES C CXX' ./CMakeLists.txt
Per cmake project the default values are C CXX. So you are creating a patch that does nothing.
I read the cmake document, these two language is default, but cmake in Nix complain about this, I will invest this later.

My system is upgraded to NixOS 22.05 now, and previous cmake warning(or error) can not reproduce now. and above sed command is not necessary now.

patch - cbs

Probably easier to pass a flag on the command line, than patching the file with sed. Is there an issue with seeing the warnings?

maybe build will fail without patch(gcc version of Nix is high), I do not remember the details, I will check this later.

without patch, cbs build will fail with below error message:

cc1: error: '-Wformat-security' ignored without '-Wformat' [8;;https://gcc.gnu.org/onlinedocs/gcc/Warning-Options.html#index-Wformat-security-Werror=format-security8;;]

and I have no idea how to pass the flag(-Wno-format-security -Wno-format) on command line.

patch - libevdev location

What is the actual path of libevdev in this build?

I will reply later.

every package installed by Nix will store under /nix/store, with an unique name. path of libevdev used currently on my system is

/nix/store/1myrirwg1yrzawxc6hin65280ppv5dra-libevdev-1.12.1/

but this maybe change after system upgrade. So I replace hard encoded include path in CMakeLists.txt with "${libevdev}/include/libevdev-1.0", which "${libevdev}" will evaluate to actual libevdev install path by nix.

LizardByte-bot · 2026-01-18T11:22:54Z

LizardByte-bot
Jan 18, 2026
Maintainer

This discussion was automatically closed because it has been inactive for 365 days.

0 replies

LizardByte

NixOS #36

Uh oh!

yuchangyuan Jun 10, 2022

Replies: 2 comments · 5 replies

Uh oh!

yuchangyuan Sep 13, 2022 Author

Uh oh!

ReenigneArcher Sep 13, 2022 Maintainer

Uh oh!

yuchangyuan Sep 13, 2022 Author

Uh oh!

ReenigneArcher Sep 13, 2022 Maintainer

updated url

flags

patch - adding PROJECT/LANGUAGES

patch - cbs

patch - libevdev location

meta

additional comments

Uh oh!

yuchangyuan Sep 14, 2022 Author

updated url

flags

patch - adding PROJECT/LANGUAGES

patch - cbs

patch - libevdev location

meta

additional comments

Uh oh!

yuchangyuan Sep 18, 2022 Author

patch - adding PROJECT/LANGUAGES

patch - cbs

patch - libevdev location

Uh oh!

LizardByte-bot Jan 18, 2026 Maintainer

yuchangyuan
Jun 10, 2022

Replies: 2 comments 5 replies

yuchangyuan
Sep 13, 2022
Author

ReenigneArcher Sep 13, 2022
Maintainer

yuchangyuan Sep 13, 2022
Author

ReenigneArcher Sep 13, 2022
Maintainer

yuchangyuan Sep 14, 2022
Author

yuchangyuan Sep 18, 2022
Author

LizardByte-bot
Jan 18, 2026
Maintainer