build.gradle

plugins {
    id "java"
    id "eclipse"
    id "org.springframework.boot" version "2.2.0.RELEASE"
    id "io.spring.dependency-management" version "1.0.8.RELEASE"
}

ext['lombok.version'] = "1.18.10"

version = "2.2.0"

sourceCompatibility = '1.8'
targetCompatibility = '1.8'

def defaultEncoding = 'UTF-8'
tasks.withType(AbstractCompile).each { it.options.encoding = defaultEncoding }

javadoc {
    options.encoding = defaultEncoding
    options.addBooleanOption('Xdoclint:none', true)
}

test {
    include "**/model/**", "**/controller/**", "**/util/**", "**/context/**"
}

repositories {
    jcenter()
}

eclipseJdt.doLast {
    File f = file('.settings/org.eclipse.core.resources.prefs')
    f.write('eclipse.preferences.version=1\n')
    f.append('encoding/<project>=UTF-8')
}

dependencies {
    annotationProcessor "org.projectlombok:lombok"
    compileOnly "org.projectlombok:lombok"
    implementation "org.springframework.boot:spring-boot-starter-web"
    implementation "org.springframework.boot:spring-boot-starter-data-jpa"
    implementation "org.springframework.boot:spring-boot-starter-aop"
    implementation "org.springframework.boot:spring-boot-starter-actuator"
    runtime "com.h2database:h2"
    testAnnotationProcessor "org.projectlombok:lombok"
    testCompileOnly "org.projectlombok:lombok"
    testImplementation "org.springframework.boot:spring-boot-starter-test"
}

wrapper {
    gradleVersion = "5.6.3"
}