clientEngine.ml

open Grid
open Client

(** [print_boards game] prints the boards in [game] to the terminal *)
let print_boards game =
  let top_board = game |> parse |> snd |> render false in
  let bottom_board = game |> parse |> fst |> render true in 
  ANSITerminal.(print_string [white] top_board); print_endline "";
  ANSITerminal.(print_string [white] bottom_board); print_endline ""

let main serv_port player_num =
  let client = Client.make_client (serv_port + player_num) in
  let c_in, c_out = Client.inchan client, Client.outchan client in 

  Client.make_connection client serv_port; 

  let connect_msg = Client.read c_in in
  ANSITerminal.(print_string [green] connect_msg); print_endline "";

  let init_board = Client.read c_in in
  print_boards init_board;

  (** [valid_prompt ()] prompts the user for input and waits for a response from
      the server. Valid prompts include "shoot (A,1)", "score", and "quit".

        Shoot command ends turn and displays game boards on terminal

        Score command displays current score and prompts user again

        Quit command ends the game for both clients and the server *)
  let rec valid_prompt () =

    let rec loop () =
      ANSITerminal.(print_string [white] (Client.read c_in)); 
      print_endline ""; 
      let msg = read_line () in
      Client.write c_out msg;
      if msg = "score" 
      then (ANSITerminal.(print_string [yellow] (Client.read c_in)); 
            print_endline ""; 
            loop ()) 
      else Client.read c_in in

    let response = loop () in
    if String.index_opt response 'C' <> Some 0 
    then response 
    else (ANSITerminal.(print_string [red] response); print_endline ""; 
          valid_prompt ())
  in

  (** [move ()] is the set of instructions executed when it is this player's 
      turn*)
  let move () =
    let response = valid_prompt () in
    if response = "QUIT" 
    then (Client.close client; Stdlib.exit 0) 
    else print_boards response in

  (** [wait ()] is the set of instructions executed when it is the other 
      player's turn*)
  let wait () = 
    ANSITerminal.(print_string [white] "The other player is moving"); 
    print_endline "";
    let response = Client.read c_in in 
    if response = "QUIT" 
    then (ANSITerminal.(print_string [white] "the other player has quit");
          print_endline ""; Client.close client; Stdlib.exit 0) 
    else print_boards response in

  (** [cycle ()] makes a player move and wait for the other player's moves
      until the game is over *)
  let rec cycle () =
    if player_num = 1 
    then (move (); wait (); cycle ())
    else (wait (); move (); cycle ()) in 

  cycle ()

let () = main (int_of_string Sys.argv.(1)) (int_of_string Sys.argv.(2))