Cannot use SPI and A2DP at the same time

[hientv1999]

Hi, I'm using ESP32 Wrover 4MB with SH1107 SPI OLED. In the past, I use I2C OLED and it works flawlessly with this A2DP library. Now I want to use SPI for faster refresh rate. I have made the SPI code for OLED work. Now I integrated A2DP and SPI together, OLED doesn't work anymore, but A2DP still works. After countless amount of trials, I figure out the SPI will stop working after I initialize the I2S in A2DP. I wonder why is it and if there is any fix for this?

Below is the code that you can use to recreate the issue.

#include <Arduino.h>
#include <BluetoothA2DPSinkQueued.h>
#include <SPI.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SH110X.h>

// A2DP setup
BluetoothA2DPSinkQueued a2dp_sink;
const char *device_name = "BluetoothA2DPSinkQueued";

// Pin Definitions
#define DC 2
#define WS 12
#define DOUT 14
#define SCK 18
#define CS 0
#define MOSI 23
#define BCLK 26

// SH1107 OLED setup
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 128
#define OLED_RESET -1 // No reset pin

Adafruit_SH1107 display(SCREEN_WIDTH, SCREEN_HEIGHT, &SPI, DC, OLED_RESET, CS);

void setup() {
// Initialize serial
Serial.begin(115200);

// Initialize SH1107 OLED display
if (!display.begin(0x3C, true)) {
    Serial.println(F("Failed to initialize the SH1107 display"));
    while (1);
}
display.clearDisplay();
display.setTextSize(1);
display.setTextColor(SH110X_WHITE);
display.setCursor(0, 0);
display.println("A2DP Sink");
display.display();

// Start A2DP sink
static i2s_config_t i2s_config = {
    .mode = (i2s_mode_t) (I2S_MODE_MASTER | I2S_MODE_TX),
    .sample_rate = 44100, // updated automatically by A2DP
    .bits_per_sample = (i2s_bits_per_sample_t)32,
    .channel_format = I2S_CHANNEL_FMT_RIGHT_LEFT,
    .communication_format = (i2s_comm_format_t) (I2S_COMM_FORMAT_STAND_I2S),
    .intr_alloc_flags = 0, // default interrupt priority
    .dma_buf_count = 4,
    .dma_buf_len = 128,
    .use_apll = true,
    .tx_desc_auto_clear = true // avoiding noise in case of data unavailability
};
a2dp_sink.set_i2s_port(I2S_NUM_1);
a2dp_sink.set_i2s_config(i2s_config);
i2s_pin_config_t my_pin_config = {
    .bck_io_num = BCLK,
    .ws_io_num = WS,
    .data_out_num = DOUT,
    .data_in_num = I2S_PIN_NO_CHANGE
};
a2dp_sink.set_pin_config(my_pin_config);
a2dp_sink.start(device_name, false);

}
void loop() {
// Update display
display.clearDisplay();
display.setCursor(0, 0);
display.println("Playing Audio...");
display.display();
delay(1000); // Adjust the delay as needed
}

[pschatzmann]

Not sure: my first guess would be that you should not use pin 0 because this is usually used as masterclock for I2S

ps. you are still using the old I2S API, that will not work any more after you upgrade to the actual ESP32 core

[hientv1999]

Hi,

Thank you very much for your speedy help. You are totally correct. I used VSPI, so I changed CS to pin 5 and SPI OLED works flawlessly now with A2DP.

Can you please show me where to find the new I2S API for PlatformIO?

Thank you

[pschatzmann]

Just read the readme of the A2DP project