play wav and mp3 files from SD in the same sketch

[hammerheaddown]

i have looked over and over in the examples and even here for a solution

i can play a mp3 just fine using this code:
https://github.com/pschatzmann/arduino-audio-tools/blob/main/examples/examples-stream/streams-sd_mp3-i2s/streams-sd_mp3-i2s.ino

and a wav file works but i cant seem to get them both to work at same time.

here is my code:

/**
 * @file streams-sd_mp3-i2s.ino
 * @author Phil Schatzmann
 * @brief decode MP3 file and output it on I2S
 * @version 0.1
 * @date 2021-96-25
 * 
 * @copyright Copyright (c) 2021 
 */


#include <SPI.h>
#include <SD.h>
#include "AudioTools.h"
#include "AudioTools/AudioCodecs/CodecMP3Helix.h"
#include "driver/i2s_std.h"

// Define SD card and I2S pins (YOUR DEFINITIONS)
#define SD_MISO GPIO_NUM_13
#define SD_MOSI GPIO_NUM_11
#define SD_SCK  GPIO_NUM_12
#define SD_CS   GPIO_NUM_10

#define I2S_BCLK GPIO_NUM_5
#define I2S_DOUT GPIO_NUM_6
#define I2S_LRC  GPIO_NUM_14

const int chipSelect=10;
I2SStream i2s; // final output of decoded stream

StreamCopy copier; 
File audioFile;


String text2speech = "/recordings/text2speech.mp3"; // SD Card filename, assuming in root directory
EncodedAudioStream decoder(&i2s, new MP3DecoderHelix()); // Decoding stream

String speech2text = "/recordings/speech2txt.wav"; // SD Card filename, assuming in root directory
EncodedAudioStream decoderTwo(&i2s, new WAVDecoder()); // Decoding stream

void playMP3(String text2speech){
  
 // setup file
  SD.begin(chipSelect);
  audioFile = SD.open(text2speech);

  delay(10);
  #ifdef DEBUG_MODE
    Serial.println("Free Heap after sd set up : " + String(ESP.getFreeHeap()));
  #endif

  // setup output (using custom I2S pins)
  auto cfg = i2s.defaultConfig(TX_MODE);
  cfg.pin_bck = I2S_BCLK;
  cfg.pin_ws = I2S_LRC;
  cfg.pin_data = I2S_DOUT;
  //cfg.sample_rate = 44100; // Important: Set initial sample rate
  cfg.i2s_format = I2S_STD_FORMAT; 
  i2s.begin(cfg);

  delay(10);
  #ifdef DEBUG_MODE
    Serial.println("Free Heap after i2s set up : " + String(ESP.getFreeHeap()));
  #endif

  // setup I2S based on sampling rate provided by decoder
  decoder.begin();
  delay(10);
  #ifdef DEBUG_MODE
    Serial.println("Free Heap after decoder set up : " + String(ESP.getFreeHeap()));
  #endif


  // begin copy
  copier.begin(decoder, audioFile);
  delay(10);
  #ifdef DEBUG_MODE
    Serial.println("Free Heap after copier set up : " + String(ESP.getFreeHeap()));
  #endif

}

void playwav(String speech2text){
  
  // setup file
    SD.begin(chipSelect);
    audioFile = SD.open(speech2text);

    delay(10);
    #ifdef DEBUG_MODE
      Serial.println("Free Heap after sd set up : " + String(ESP.getFreeHeap()));
    #endif

    // setup output (using custom I2S pins)
    auto cfg = i2s.defaultConfig(TX_MODE);
    cfg.pin_bck = I2S_BCLK;
    cfg.pin_ws = I2S_LRC;
    cfg.pin_data = I2S_DOUT;
    //cfg.sample_rate = 44100; // Important: Set initial sample rate
    cfg.i2s_format = I2S_STD_FORMAT; 
    i2s.begin(cfg);

    delay(10);
    #ifdef DEBUG_MODE
      Serial.println("Free Heap after i2s set up : " + String(ESP.getFreeHeap()));
    #endif

    // setup I2S based on sampling rate provided by decoder
    decoderTwo.begin();
    delay(10);
    #ifdef DEBUG_MODE
      Serial.println("Free Heap after decoder set up : " + String(ESP.getFreeHeap()));
    #endif


    // begin copy
    copier.begin(decoderTwo, audioFile);
    delay(10);
    #ifdef DEBUG_MODE
      Serial.println("Free Heap after copier set up : " + String(ESP.getFreeHeap()));
    #endif

}

void setup(){
  Serial.begin(115200);
  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Error);  

  playMP3(text2speech);
  delay(100);
  #ifdef DEBUG_MODE
    Serial.println("Free Heap after playing MP3 : " + String(ESP.getFreeHeap()));
  #endif

  playwav(speech2text);
  delay(100);
  #ifdef DEBUG_MODE
    Serial.println("Free Heap after playing WAV : " + String(ESP.getFreeHeap()));
  #endif

}

void loop(){

  delay(10);
  #ifdef DEBUG_MODE
    Serial.println("Free Heap b4 copier set up : " + String(ESP.getFreeHeap()));
  #endif

  if (!copier.copy()) {
    stop();
  }
}

[pschatzmann]

I assume you are compiling in Arduino!

I don't recommend to change any settings in the preferences if you don't know what you are doing.
Did you try to change the setting for compiler warnings back to Default or None ?

ps. your logic is completely wrong: one way to correct this is to remove the copy() from the loop and add a copier.copyAll() at the end of your play methods to process the complere file.

Another is to call playwav() only after you completeley processed the first file (when the copy in the loop returns 0)

[hammerheaddown]

i got the loop working with the google ttS and happy with that. thanks!! i have another question about that and will post the code in case someone else can use it. but in another thread

but the 1st (original) question was just having both a wav and a mp3 decoder and i could use either if needed. they normally dont go in the start i just did a minimal sketch so they ended up there. the plan is to have a button press

blue button (pin21) --> will play my speech2text( ) function  --> which will play a file @ located --> /recordings/speech2text.wav
red button (pin18)--> will play my text2speech( ) function  -->  which will play a file @ located --> /recordings/ text2speech.mp3

so 2 different functions but 2 different media type files

hope that helps my explanation and thanks a ton for your responses

[pschatzmann]

Did you read the Wiki: the chapter Internative Audio should put you on the right track.

There is already a google tts example in the examples-tts

[hammerheaddown]

yeah i have been in there and used some info to get as far as i have thanks!

but it still doesnt help in using both a wav and a mp3 in same sketch unless i missed it, i see how to use wav and a mp3 just not both

i will go thru those examples some more and see what i can maybe piece together. you have so so many awesome examples thanks for all your work

[pschatzmann]

This is straight forward: you can just combine the approach given in the wiki with what you already have developped:

• Just use separate handler methods for wav and mp3 that uses the parameters given in the example.
• You can pass the file name as parameter instead of the frequency of the example.
• Your methods sets up the copier and the file source, so that the loop can automatically process it just with copier.copy().

[hammerheaddown]

ok so this is what I did...

you can prob see a better way to do this, or simplify it

maybe someone googling will find there way here and are helped in some way. Since i have found snippets of code by google i know it can come in handy.

#include <SD.h>
#include <SPI.h>
#include "AudioTools.h"
#include "AudioTools/AudioCodecs/CodecMP3Helix.h"

// --------------------------  SD Pin Setup      --------------------------------------
#define SD_MISO GPIO_NUM_13
#define SD_MOSI GPIO_NUM_11
#define SD_SCK  GPIO_NUM_12
#define SD_CS   GPIO_NUM_10

// --------------------------  AMP Pin Setup     ------------------------------------------
#define I2S_BCLK GPIO_NUM_5
#define I2S_DOUT GPIO_NUM_6
#define I2S_LRC  GPIO_NUM_14

// --------------------------  Push Button Setup ---------------------------------------
#define PUSH_BUTTON_PIN 21                                                  // Replace with your push button pin
#define MY_DEBOUNCE_DELAY 50

I2SStream i2s;
const int chipSelect = SD_CS;

volatile bool interruptRequested = false;                                   // Global interrupt flag
String speech2TxtFilename= "/recordings/speech2txt.wav";
String text2speechFilename = "/recordings/text2speech.mp3";

void playWavFile(String filename);
void playMp3File(String filename);
void audio_tools_i2s_config();
void listRecordings();
void interruptAudioPlayback();
void handleButtonInterrupt();
void playMp3Task(void *pvParameters);
void playWavTask(void *pvParameters);
void startWavPlayback(String filename);
void startMp3Playback(String filename);

void audio_tools_i2s_config() {
  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Error);
  auto cfg = i2s.defaultConfig(TX_MODE);
  cfg.pin_bck = I2S_BCLK;
  cfg.pin_ws = I2S_LRC;
  cfg.pin_data = I2S_DOUT;
  cfg.i2s_format = I2S_STD_FORMAT;
  i2s.begin(cfg);
  
}

void interruptAudioPlayback() {
  interruptRequested = true;

  delay(100); // Add a 50ms debounce delay
  #ifdef DEBUG_MODE
    Serial.println("Free Heap " + String(ESP.getFreeHeap()));
  #endif
  delay(10);
}

void handleButtonInterrupt() {
  interruptAudioPlayback();                       // Call the same interrupt function
}

void playWavFile(String filename) {
 
  #ifdef DEBUG_MODE
    Serial.println("Free Heap before b4 we continue " + String(ESP.getFreeHeap()));
  #endif

  WAVDecoder wav;
  EncodedAudioStream decoder(&i2s, &wav);
  StreamCopy copier;
  File audioFile;

  #ifdef DEBUG_MODE
    Serial.println("Free Heap before b4 we continue " + String(ESP.getFreeHeap()));
  #endif

  audioFile = SD.open(filename.c_str());

  if (!audioFile) {
    Serial.print("Failed to open WAV file: ");
    Serial.println(filename);
    return;
  }
  decoder.begin();
  copier.begin(decoder, audioFile);

  #ifdef DEBUG_MODE
    Serial.println("Free Heap before b4 we continue " + String(ESP.getFreeHeap()));
  #endif

  while (copier.copy()) {
    if (interruptRequested) {

      #ifdef DEBUG_MODE
        Serial.println("Free Heap before b4 we continue " + String(ESP.getFreeHeap()));
      #endif

      copier.end();
      decoder.end();
      interruptRequested = false;
      Serial.println("WAV playback interrupted.");
      return;
    }
    if (Serial.available() > 0) {
      String command = Serial.readStringUntil('\n');
      command.trim();
      if (command.equalsIgnoreCase("interrupt") || command.equalsIgnoreCase("3")) {
        interruptAudioPlayback();
      }
    }
  }
  audioFile.close();
  decoder.end();
  copier.end();


  Serial.println("WAV playback finished.");
  #ifdef DEBUG_MODE
    Serial.println("Free Heap before b4 we continue " + String(ESP.getFreeHeap()));
  #endif

}

void playMp3File(String filename) {
  
  #ifdef DEBUG_MODE
    Serial.println("Free Heap before b4 we continue " + String(ESP.getFreeHeap()));
  #endif

  MP3DecoderHelix mp3;
  EncodedAudioStream decoder(&i2s, &mp3);
  StreamCopy copier;
  File audioFile;

  #ifdef DEBUG_MODE
    Serial.println("Free Heap before b4 we continue " + String(ESP.getFreeHeap()));
  #endif
  
  audioFile = SD.open(filename.c_str());
  if (!audioFile) {
    Serial.print("Failed to open MP3 file: ");
    Serial.println(filename);
    return;
  }
  decoder.begin();
  copier.begin(decoder, audioFile);

  #ifdef DEBUG_MODE
    Serial.println("Free Heap before b4 we continue " + String(ESP.getFreeHeap()));
  #endif

  while (copier.copy()) {
    if (interruptRequested) {

      #ifdef DEBUG_MODE
        Serial.println("Free Heap before b4 we continue " + String(ESP.getFreeHeap()));
      #endif

      copier.end();
      decoder.end();
      interruptRequested = false;
      Serial.println("MP3 playback interrupted.");
      return;
    }
    if (Serial.available() > 0) {
      String command = Serial.readStringUntil('\n');
      command.trim();
      if (command.equalsIgnoreCase("interrupt") || command.equalsIgnoreCase("3")) {
        interruptAudioPlayback();
      }
    }
  }
  audioFile.close();
  decoder.end();
  copier.end();
  Serial.println("MP3 playback finished.");

  #ifdef DEBUG_MODE
    Serial.println("Free Heap before b4 we continue " + String(ESP.getFreeHeap()));
  #endif

}

void startMp3Playback(String filename) {
  String* filenamePtr = new String(filename); // Allocate memory for filename
  xTaskCreate(
      playMp3Task,
      "MP3 Playback",
      4096,
      filenamePtr,
      5,
      NULL
  );
}

void startWavPlayback(String filename) {
  String* filenamePtr = new String(filename); // Allocate memory for filename
  xTaskCreate(
      playWavTask,
      "WAV Playback",
      4096,
      filenamePtr,
      5,
      NULL
  );
}

void playMp3Task(void *pvParameters) {
  String filename = *((String*)pvParameters); // Retrieve filename from parameter
  playMp3File(filename);
  delete (String*)pvParameters; // Clean up allocated memory
  vTaskDelete(NULL); // Delete the task
}

void playWavTask(void *pvParameters) {
  String filename = *((String*)pvParameters); // Retrieve filename from parameter
  playWavFile(filename);
  delete (String*)pvParameters; // Clean up allocated memory
  vTaskDelete(NULL); // Delete the task
}

void listRecordings() {
  File dir = SD.open("/recordings");
  if (!dir) {
    Serial.println("Failed to open directory");
    return;
  }
  if (!dir.isDirectory()) {
    Serial.println("Not a directory");
    dir.close();
    return;
  }

  File file = dir.openNextFile();
  while (file) {
    if (file.isDirectory()) {
      Serial.print("  DIR : ");
      Serial.println(file.name());
    } else {
      Serial.print("  FILE: ");
      Serial.print(file.name());
      Serial.print("  SIZE: ");
      Serial.println(file.size());
    }
    file = dir.openNextFile();
  }
  file.close();
  dir.close();
}

void setup() {
  Serial.begin(115200);
  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Info);
  pinMode(PUSH_BUTTON_PIN, INPUT_PULLUP);                                                       // Configure button pin as input with pull-up resistor
  attachInterrupt(digitalPinToInterrupt(PUSH_BUTTON_PIN), handleButtonInterrupt, FALLING);      // Use your desired mode
  SPI.begin(SD_SCK, SD_MISO, SD_MOSI, SD_CS);
  if (!SD.begin(chipSelect)) {
    Serial.println("SD card initialization failed!");
    while (1);
  }

  audio_tools_i2s_config();
}

void loop() {
  // --- Push Button Logic with Debouncing ---
  int buttonState = digitalRead(PUSH_BUTTON_PIN);
  static bool lastButtonState = HIGH;

  if (interruptRequested) {
    interruptRequested = false;
  }

  if (buttonState != lastButtonState) {
    delay(MY_DEBOUNCE_DELAY);
    buttonState = digitalRead(PUSH_BUTTON_PIN);

    if (buttonState == LOW && lastButtonState == HIGH) {
      interruptAudioPlayback(); // Interrupt on button press
    }
    lastButtonState = buttonState;
  }

  if (Serial.available()) {
    String command = Serial.readStringUntil('\n');
    command.trim();

    if (command.equalsIgnoreCase("interrupt") || command.equalsIgnoreCase("3")) {
      interruptAudioPlayback();
    }

    if (command.equalsIgnoreCase("recordings") || command.equalsIgnoreCase("5")) {
      listRecordings();
    }

    if (command.equalsIgnoreCase("speech") || command.equalsIgnoreCase("6")) {
      startWavPlayback(speech2TxtFilename);
    }

    if (command.equalsIgnoreCase("text") || command.equalsIgnoreCase("7")) {
      startMp3Playback(text2speechFilename);
    }
  }
}

so this will play a wav and or a mp3 … since when we record it ends up a wav and most TTS platforms send back a mp3

i added the list files just for something extra. Also because I was working on a "interrupt" for my TTS playback i added that logic here too just in case someone can use it in anyway. the interrupt works from serial command u see in the loop or a button pushed

FYI the debugging wont go away no matter the setting... I'm gonna go up and delete that part if I can so ppl can find this without so much clutter. I'm not sure if title can be changed

[pschatzmann]

You defined the log level as Info in the second line in setup() ! Just change it to Warning if you don't want to see the info messages...

[hammerheaddown]

OH Ok, i was thinking you meant in Arduino Ide , sweet will change it right now!

i went and looked at my project that started this question and i had it at Error

those errors happen while it is compiling .. everything still works so not an issue at this time

[pschatzmann]

Just for inspiration. A sketch which uses the logic described in the chapter Interative Audio would look something like this:

#include "SPI.h"
#include "SD.h"
#include "AudioTools.h"
#include "AudioTools/AudioCodecs/CodecMP3Helix.h"

File file;
I2SStream i2s;
MP3DecoderHelix mp3;
WAVDecoder wav;
EncodedAudioStream decoder(&i2s, &mp3);  // Decoding stream
StreamCopy copier(decoder, file);
AudioActions action;
const int chipSelect=10;

// starts playback of indicated file
void actionKeyOn(bool active, int pin, void* ptr) {
  const char* fileName = (const char*)ptr;
  file.close();
  decoder.end();

  if (StrView(fileName).endsWith("mp3")) {
    decoder.setDecoder(&mp3);
  }
  if (StrView(fileName).endsWith("wav")) {
    decoder.setDecoder(&wav);
  }
  decoder.begin();
  file = SD.open(fileName);
}

// assign gpio buttons to playback files
void setupActions() {
  action.add(6, actionKeyOn, AudioActions::ActiveLow,(void*) "file.wav");
  action.add(7, actionKeyOn, AudioActions::ActiveLow,(void*) "file.mp3");
}

void setup() {
  Serial.begin(115200);
  AudioLogger::instance().begin(Serial,AudioLogger::Info);

  // setup SD
  SD.begin(chipSelect);

  // setup output (using custom I2S pins)
  auto cfg = i2s.defaultConfig(TX_MODE);
  i2s.begin(cfg);

  setupActions();
}

// playback selected file
void loop() {
  copier.copy();
  action.processActions();
}

This is much shorter...

[hammerheaddown]

i love it, do you have more similar examples using:

// assign gpio buttons to playback files
void setupActions() {
  action.add(6, actionKeyOn, AudioActions::ActiveLow,(void*) "file.wav");
  action.add(7, actionKeyOn, AudioActions::ActiveLow,(void*) "file.mp3");
}

cause im not sure i understand that section. are you simulating a button push or something? i am not seeing any way that is being called to use when you want it unless im missing it

but i know this snippet

const char* fileName = (const char*)ptr;
  file.close();
  decoder.end();

  if (StrView(fileName).endsWith("mp3")) {
    decoder.setDecoder(&mp3);
  }
  if (StrView(fileName).endsWith("wav")) {
    decoder.setDecoder(&wav);

Is definitely going to come in handy lol

[pschatzmann]

yes it does: have a look at the curl example!
It's basically just a http post as in my other examples mentioned above...

[hammerheaddown]

this one?
https://github.com/pschatzmann/arduino-audio-tools/blob/main/tests-cmake/url-test/url-test.cpp

swore it said curl lol... i typed curl in the search

[pschatzmann]

No this is a http get example: look in the examples-tts for the post examples!

[hammerheaddown]

i have been at this all day...

i dont know why or if it s there api but this sketch will work... if i reset to test, it will cut off... sometimes cuts off anyways

i left you a api key to play with its only good for 24 hours and has a limit on it

#include "AudioTools.h"
#include "AudioTools/AudioCodecs/CodecMP3Helix.h"
#include <WiFi.h>
#include <WiFiUdp.h>
#include <WiFiClientSecure.h>
#include <HTTPClient.h>
#include <ArduinoJson.h>
#include "freertos/FreeRTOS.h"
#include "freertos/queue.h"
#include <chrono> // For timekeeping

// --------------------------  AMP Pin Setup    ------------------------------------------
#define I2S_BCLK GPIO_NUM_5
#define I2S_DOUT GPIO_NUM_6
#define I2S_LRC  GPIO_NUM_14

i2s_chan_handle_t tx_handle;

// ----- Wifi Credentials
const char *ssid = "xxx";
const char *password = "xxx";

const char *deepgramApiKey = "a620afcfbd57c3c421605209cf73fb5509fa2b5b";
#define STT_LANGUAGE "en"
#define TIMEOUT_DEEPGRAM 12
#define STT_KEYWORDS "&keywords=Gigolo&keywords=Google"
String optional_param = "?model=nova-2-general";

URLStream url; 
I2SStream i2s;
EncodedAudioStream decoder(&i2s, new MP3DecoderHelix());
StreamCopy copier(decoder);

unsigned long lastKeepAliveTime = 0;
const unsigned long keepAliveInterval = 15000; // 10 seconds

void deepgramTTS(const char* textToSpeech) {
    char escapedText[512];
    int j = 0;
    for (int i = 0; textToSpeech[i] != '\0'; i++) {
        if (textToSpeech[i] == '"') {
            escapedText[j++] = '\\';
        }
        escapedText[j++] = textToSpeech[i];
    }
    escapedText[j] = '\0';

    char requestBody[1024];
    JsonDocument doc;
    doc["text"] = escapedText;
    serializeJson(doc, requestBody);

    Serial.println("RequestBody: " + String(requestBody));

    HTTPClient http;
    http.begin("https://api.deepgram.com/v1/speak?model=aura-luna-en");
    http.addHeader("Authorization", "Token " + String(deepgramApiKey));
    http.addHeader("Content-Type", "application/json");

    int httpCode = http.POST(requestBody);

    Serial.print("HTTP Response Code: ");
    Serial.println(httpCode);

    if (httpCode == HTTP_CODE_OK) {
        delay(100);
        decoder.begin();

        Stream& httpStream = http.getStream();
        uint8_t buffer[1024];
        int bytesRead;

        auto lastDataTime = std::chrono::steady_clock::now();
        const auto timeoutDuration = std::chrono::seconds(15);

        unsigned long previousMillis = 0;
        const long interval = 5;

        while (true) {
            unsigned long currentMillis = millis();
            if(currentMillis - previousMillis >= interval){
                previousMillis = currentMillis;
                bytesRead = httpStream.readBytes(buffer, sizeof(buffer));

                if (bytesRead > 0) {
                    decoder.write(buffer, bytesRead);
                    Serial.print("Chunk played: ");
                    Serial.println(bytesRead);
                    lastDataTime = std::chrono::steady_clock::now();
                } else {
                    auto now = std::chrono::steady_clock::now();
                    auto timeSinceLastData = std::chrono::duration_cast<std::chrono::seconds>(now - lastDataTime);

                    if (timeSinceLastData > timeoutDuration) {
                        Serial.println("Timeout: No data received. Reconnecting...");

                        int retryCount = 0;
                        const int maxRetries = 3;

                        while (retryCount < maxRetries) {
                            http.end();
                            http.begin("https://api.deepgram.com/v1/speak?model=aura-luna-en");
                            http.addHeader("Authorization", "Token " + String(deepgramApiKey));
                            http.addHeader("Content-Type", "application/json");
                            httpCode = http.POST(requestBody);
                            if (httpCode == HTTP_CODE_OK) {
                                httpStream = http.getStream();
                                lastDataTime = std::chrono::steady_clock::now();
                                Serial.println("Reconnected Successfully");
                                retryCount = 0;
                                break;
                            } else {
                                Serial.print("Reconnection attempt ");
                                Serial.print(retryCount + 1);
                                Serial.println(" failed.");
                                Serial.printf("[HTTP] POST reconnection failed, error: %s\n", http.errorToString(httpCode).c_str());
                                retryCount++;
                                delay(1000);
                            }
                        }
                        if (retryCount >= maxRetries) {
                            Serial.println("Max reconnection attempts reached. Aborting.");
                            break;
                        }
                    }

                    if (!httpStream.available()) {
                        if (bytesRead == 0) {
                            Serial.println("End of stream or zero bytes read.");
                            break;
                        }
                    }
                }
                Serial.print("httpStream.available(): ");
                Serial.println(httpStream.available());
                Serial.print("Time since last data (ms): ");
                Serial.println(std::chrono::duration_cast<std::chrono::milliseconds>(std::chrono::steady_clock::now() - lastDataTime).count());
                Serial.print("Free Heap: ");
                Serial.println(ESP.getFreeHeap());
                Serial.print("WiFi RSSI: ");
                Serial.println(WiFi.RSSI());
                Serial.print("http.connected(): ");
                Serial.println(http.connected());
            }

        }

        while (decoder.available()) {
            copier.copy();
        }

        copier.end();
        decoder.end();

    } else {
        Serial.printf("[HTTP] POST TTS... failed, error: %s\n", http.errorToString(httpCode).c_str());
        Serial.println("Response: " + http.getString());
    }
    http.end();
}

// not sending at the moment was giving errors
void sendKeepAlive() {
    HTTPClient http;
    http.begin("https://api.deepgram.com/v1/listen"); // Correct endpoint
    http.addHeader("Authorization", "Token " + String(deepgramApiKey));
    http.addHeader("Content-Type", "application/json");

    String keepAliveMessage = "{\"type\":\"KeepAlive\"}";
    int httpCode = http.POST(keepAliveMessage);

    if (httpCode == HTTP_CODE_OK) {
        Serial.println("Keep-alive sent successfully");
    } else {
        Serial.println("Failed to send keep-alive");
    }

    http.end();
}

void audio_tools_i2s_config() {
  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Error);
  auto cfg = i2s.defaultConfig(TX_MODE);
  cfg.pin_bck = I2S_BCLK;
  cfg.pin_ws = I2S_LRC;
  cfg.pin_data = I2S_DOUT;
  cfg.i2s_format = I2S_STD_FORMAT;
  i2s.begin(cfg);
}

void setup() {
    Serial.begin(115200);
    WiFi.begin(ssid, password);
    while (WiFi.status() != WL_CONNECTED) {
        delay(1000);
        //Serial.println("Connecting to WiFi...");
    }
    Serial.println("Connected to WiFi");

  audio_tools_i2s_config();
  delay(10);
    #ifdef DEBUG_MODE
      Serial.println("Free Heap after audio tools i2s config setup: " + String(ESP.getFreeHeap()));
    #endif
}

void loop() {
    deepgramTTS("I am truly sorry for the repeated errors. I am still under development and learning, but this is a particularly bad mistake that I need to address. Thank you for your patience and for pointing out my error..");
    delay(10000);
}

wasnt sure if it is possible if im messing something up in my code or it is there api

[hammerheaddown]

here is a sample of it just stopping it gets to " I'm truly sorry" and then no more

23:45:38.205 -> RequestBody: {"text":"I am truly sorry for the repeated errors. I am still under development and learning, but this is a particularly bad mistake that I need to address. Thank you for your patience and for pointing out my error.."}
23:45:39.425 -> HTTP Response Code: 200
23:45:39.557 -> Chunk played: 1024
23:45:39.718 -> Chunk played: 1024
23:45:39.952 -> Chunk played: 1024
23:45:40.077 -> Chunk played: 1024
23:45:40.254 -> Chunk played: 1024
23:45:40.296 -> Chunk played: 379
23:45:40.296 -> End of stream or zero bytes read.

and this got to about "but this is" i thought i heard "so"

23:47:48.613 -> RequestBody: {"text":"I am truly sorry for the repeated errors. I am still under development and learning, but this is a particularly bad mistake that I need to address. Thank you for your patience and for pointing out my error.."}
23:47:49.832 -> HTTP Response Code: 200
23:47:50.051 -> Chunk played: 1024
23:47:50.097 -> Chunk played: 714
23:47:50.330 -> Chunk played: 1024
23:47:50.469 -> Chunk played: 1024
23:47:50.633 -> Chunk played: 1024
23:47:50.812 -> Chunk played: 1024
23:47:50.982 -> Chunk played: 1024
23:47:51.154 -> Chunk played: 1024
23:47:51.331 -> Chunk played: 1024
23:47:51.513 -> Chunk played: 1024
23:47:51.653 -> Chunk played: 1024
23:47:51.841 -> Chunk played: 1024
23:47:51.981 -> Chunk played: 1024
23:47:52.198 -> Chunk played: 1024
23:47:52.338 -> Chunk played: 1024
23:47:52.478 -> Chunk played: 1024
23:47:52.655 -> Chunk played: 1024
23:47:52.837 -> Chunk played: 825
23:47:52.837 -> End of stream or zero bytes read.

and straight nothing

23:49:10.925 -> Connected to WiFi
23:49:10.925 -> RequestBody: {"text":"I am truly sorry for the repeated errors. I am still under development and learning, but this is a particularly bad mistake that I need to address. Thank you for your patience and for pointing out my error.."}
23:49:11.978 -> HTTP Response Code: 200
23:49:12.111 -> Chunk played: 1024
23:49:12.111 -> Chunk played: 87
23:49:12.149 -> End of stream or zero bytes read.