build.gradle

import org.gradle.api.JavaVersion

plugins {
    id 'groovy'
    id 'java'
    id 'pl.allegro.tech.build.axion-release' version '1.17.2'
    id 'io.github.gradle-nexus.publish-plugin' version '2.0.0'
}

group 'org.rundeck.plugins'

ext.publishName = "jq Json Log Filter ${project.version}"
ext.githubSlug = 'rundeck-plugins/jq-json-logfilter'
ext.developers = [
        [id: 'gschueler', name: 'Greg Schueler', email: 'greg@rundeck.com']
]

scmVersion {
    ignoreUncommittedChanges = false
    tag {
        prefix = ''           // NO "v" prefix - see PLUGIN_TAGGING_ARCHITECTURE.md
        versionSeparator = ''
    }
}

ext.rundeckVersion='6.0.0-alpha1-20260407'
defaultTasks 'clean','build'
apply plugin: 'java'
apply plugin: 'idea'

java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
    withSourcesJar()
    withJavadocJar()
}

ext.rundeckPluginVersion= '1.2'

version = scmVersion.version  // Dynamic version from git tag

/**
 * Set this to a comma-separated list of full classnames of your implemented Rundeck
 * plugins.
 */
ext.pluginClassNames='com.rundeck.plugins.logging.JsonLogFilter'


repositories {
    mavenLocal()
    maven {
        name = 'Central Portal Snapshots'
        url = 'https://central.sonatype.com/repository/maven-snapshots/'
        
        // Only search this repository for org.rundeck snapshots
        content {
            includeGroup('org.rundeck')
        }
    }
    mavenCentral()
}

configurations{
    //declare custom pluginLibs configuration to include only libs for this plugin
    pluginLibs

    //declare compile to extend from pluginLibs so it inherits the dependencies
    implementation{
        extendsFrom pluginLibs
    }
}


dependencies {
    implementation 'org.apache.groovy:groovy-all:4.0.29'

    compileOnly group: 'org.rundeck', name: 'rundeck-core', version: rundeckVersion
    testImplementation group: 'org.rundeck', name: 'rundeck-core', version: rundeckVersion

    // Add secure commons-lang3 to provide alternative to vulnerable commons-lang 2.6
    implementation 'org.apache.commons:commons-lang3:3.20.0'

    pluginLibs (group: 'net.thisptr', name: 'jackson-jq', version: '1.0.0-preview.20230409') {
       exclude group: "com.fasterxml.jackson.core"
    }

    testImplementation group: 'junit', name: 'junit', version: '4.13.2'
    testImplementation "org.spockframework:spock-core:2.4-groovy-4.0"
    testImplementation "cglib:cglib-nodep:3.3.0"
    testImplementation 'org.objenesis:objenesis:1.4'
}

configurations.all {
    resolutionStrategy {
        // Replace vulnerable commons-lang with secure commons-lang3
        dependencySubstitution {
            substitute module('commons-lang:commons-lang') using module('org.apache.commons:commons-lang3:3.17.0')
        }
    }
}


// task to copy plugin libs to output/lib dir
task copyToLib(type: Copy) {
    into "$buildDir/output/lib"
    from configurations.pluginLibs
}

tasks.withType(Test).configureEach {
    useJUnitPlatform()
    
    // Java 17+ module access
    jvmArgs = [
        '--add-opens=java.base/java.lang=ALL-UNNAMED',
        '--add-opens=java.base/java.util=ALL-UNNAMED',
        '--add-opens=java.base/java.lang.reflect=ALL-UNNAMED'
    ]
}

jar {
    from "$buildDir/output"
    manifest {
        def libList = configurations.pluginLibs.collect{'lib/'+it.name}.join(' ')
        attributes 'Rundeck-Plugin-Name' : 'jq Json Log Filter'
        attributes 'Rundeck-Plugin-Description' : 'This plugin maps a JSON String output from a step to key/value context variables.'
        attributes 'Rundeck-Plugin-Rundeck-Compatibility-Version': '3.0.6+'
        attributes 'Rundeck-Plugin-Tags': 'java,json,log filter'
        attributes 'Rundeck-Plugin-License': 'Apache 2.0'
        attributes 'Rundeck-Plugin-Source-Link': 'https://github.com/rundeck-plugins/jq-json-logfilter'
        attributes 'Rundeck-Plugin-Target-Host-Compatibility': 'all'
        attributes 'Rundeck-Plugin-Classnames': pluginClassNames
        attributes 'Rundeck-Plugin-File-Version': version
        attributes 'Rundeck-Plugin-Version': rundeckPluginVersion, 'Rundeck-Plugin-Archive': 'true'
        attributes 'Rundeck-Plugin-Libs': "${libList}"
        attributes 'Main-Class': "com.rundeck.plugins.logging.JsonLogFilter"
        attributes 'Class-Path': "${libList} lib/rundeck-core-${rundeckVersion}.jar"
    }
}
//set jar task to depend on copyToLib
jar.dependsOn(copyToLib)

nexusPublishing {
    packageGroup = 'org.rundeck.plugins'
    repositories {
        sonatype {
            nexusUrl.set(uri("https://ossrh-staging-api.central.sonatype.com/service/local/"))
            snapshotRepositoryUrl.set(uri("https://central.sonatype.com/repository/maven-snapshots/"))
        }
    }
}

apply from: "${rootDir}/gradle/publishing.gradle"