geo3x3.nelua

require 'math'
require 'string'

global function encode(lat: number, lng: number, level: number): string
  if level < 1 then
    return ""
  end
  local res = ""
  if lng >= 0.0 then
    res = "E"
  else
    res = "W"
    lng = lng + 180.0
  end
  lat = lat + 90.0
  local unit = 180.0

  for i = 1, level - 1 do
    unit = unit / 3
    local x = math.floor(lng / unit)
    local y = math.floor(lat / unit)
    res = res .. string.format("%d", x + y * 3 + 1)
    lng = lng - x * unit
    lat = lat - y * unit
  end
  return res
end

global function decode(code: string): [4]number
  local c = string.sub(code, 1, 1)
  local begin = 0
  local flg = false
  if c == "-" or c == "W" then
    flg = true
    begin = 1
  elseif c == "+" or c == "E" then
    begin = 1
  end
  local unit = 180.0
  local lat = 0.0
  local lng = 0.0
  local level = 1
  for i = begin, string.len(code) - 1 do
    local n = tonumber(string.sub(code, i + 1, i + 1))
    if n == 0 then
      break
    end
    unit = unit / 3
    n = n - 1
    lng = lng + math.floor(n % 3) * unit
    lat = lat + math.floor(n / 3) * unit
    level = level + 1
  end
  lat = lat + unit / 2
  lng = lng + unit / 2
  lat = lat - 90.0
  if flg then
    lng = lng - 180.0
  end
  return {lat, lng, level, unit}
end