tf-analytics/SConscript at master · tungstenfabric/tf-analytics · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
#
# Copyright (c) 2013 Juniper Networks, Inc. All rights reserved.
#

# -*- mode: python; -*-
# src directory

import platform
import subprocess
import sys

Import('contrail_common_base_doc_files')
Import('contrail_common_io_doc_files')
#requires chnage in controller/src/SConscript
#Analytics section: controller/src/analytics/analytics.sandesh
Import('controller_vns_sandesh_doc_files')

subdirs_no_dup = [
          'contrail-collector',
          'contrail-query-engine',
          'contrail-opserver',
           ]

subdirs_dup = [
          'tf-snmp-collector',
          'tf-topology'
           ]

variant_dir_map = {}
variant_dir_map['contrail-collector'] = 'analytics'
variant_dir_map['contrail-query-engine'] = 'query_engine'
variant_dir_map['tf-snmp-collector'] = 'tf-snmp-collector'
variant_dir_map['tf-topology'] = 'tf-topology'
variant_dir_map['contrail-opserver'] = 'opserver'

include = ['#/src/contrail-analytics', '#/build/include', '#src/contrail-common', '#controller/lib']

libpath = ['#/build/lib']

libs = ['boost_system', 'log4cplus', 'pthread']

common = DefaultEnvironment().Clone()

if common['OPT'] == 'production' or common.UseSystemTBB():
    libs.append('tbb')
else:
    libs.append('tbb_debug')

common.Append(LIBPATH = libpath)
common.Prepend(LIBS = libs)

common.Append(CCFLAGS = ['-Wall', '-Werror', '-Wsign-compare'])

gpp_version = subprocess.check_output(
    "g++ --version | grep g++ | awk '{print $3}'",
    shell=True, env={}).rstrip()
gpp_version_major = int(gpp_version.split(".")[0])
if gpp_version == "4.8.5" or gpp_version_major >= 8:
    common.Append(CCFLAGS =['-Wno-narrowing', '-Wno-conversion-null'])
    if gpp_version_major >= 8:
        # auto_ptr is depricated - dont error on deprication warnings
        common.Append(CCFLAGS = ['-Wno-error=deprecated-declarations', '-Wno-deprecated-declarations'])

if not sys.platform.startswith('darwin'):
    if platform.system().startswith('Linux'):
       if not platform.linux_distribution()[0].startswith('XenServer'):
          common.Append(CCFLAGS = ['-Wno-unused-local-typedefs'])
if sys.platform.startswith('freebsd'):
    common.Append(CCFLAGS = ['-Wno-unused-local-typedefs'])
common.Append(CPPPATH = include)
common.Append(CCFLAGS = ['-DRAPIDJSON_NAMESPACE=contrail_rapidjson'])

BuildEnv = common.Clone()

if sys.platform.startswith('linux'):
    BuildEnv.Append(CCFLAGS = ['-DLINUX'])
elif sys.platform.startswith('darwin'):
    BuildEnv.Append(CCFLAGS = ['-DDARWIN'])

if sys.platform.startswith('freebsd'):
    BuildEnv.Prepend(LINKFLAGS = ['-lprocstat'])

#
# Message documentation for common modules
#

# base
BuildEnv['BASE_DOC_FILES'] = contrail_common_base_doc_files

# IO
BuildEnv['IO_DOC_FILES'] = contrail_common_io_doc_files

# SANDESH
BuildEnv['VNS_SANDESH_DOC_FILES'] = controller_vns_sandesh_doc_files

# Analytics (contrail-collector)
contrail_collector_doc_files = []
analytics_doc_target = common['TOP'] + '/' + variant_dir_map['contrail-collector'] + '/'
contrail_collector_doc_files += common.SandeshGenDoc('#src/contrail-analytics/contrail-collector/analytics.sandesh', analytics_doc_target)
contrail_collector_doc_files += common.SandeshGenDoc('#src/contrail-analytics/contrail-collector/viz.sandesh', analytics_doc_target)
contrail_collector_doc_files += common.SandeshGenDoc('#src/contrail-analytics/contrail-collector/redis.sandesh', analytics_doc_target)
BuildEnv['ANALYTICS_DOC_FILES'] = contrail_collector_doc_files
#Export('contrail_collector_doc_files')


BuildEnv['INSTALL_DOC_PKG'] = BuildEnv['INSTALL_DOC'] + '/contrail-docs/html'
BuildEnv['INSTALL_MESSAGE_DOC'] = BuildEnv['INSTALL_DOC_PKG'] + '/messages'


for dir in subdirs_no_dup:
    BuildEnv.SConscript(dir + '/SConscript',
                         exports='BuildEnv',
                         variant_dir=BuildEnv['TOP'] + '/' + variant_dir_map[dir],
                         duplicate=0)

for dir in subdirs_dup:
    BuildEnv.SConscript(dirs=[dir],
                         exports='BuildEnv',
                         variant_dir=BuildEnv['TOP'] + '/' + variant_dir_map[dir],
                         duplicate=1)

#AnalyticsEnv.SConscript(dirs=['tf-snmp-collector'],
#        exports='AnalyticsEnv',
#        variant_dir=BuildEnv['TOP'] + '/tf-snmp-collector',
#        duplicate=1)

#AnalyticsEnv.SConscript(dirs=['tf-topology'],
#        exports='AnalyticsEnv',
#        variant_dir=BuildEnv['TOP'] + '/tf-topology',
#        duplicate=1)