Implement nixpkgs_cc_configure.

This macro calls cc_autoconf_impl like before, but ahead of then also
defines a nixpkgs_package with all the tools we want for the CC
toolchain.

Author: mboes

WORKSPACE

@@ -1,6 +1,11 @@
 workspace(name = "io_tweag_rules_nixpkgs")
 
-load("//nixpkgs:nixpkgs.bzl", "nixpkgs_git_repository", "nixpkgs_package")
+load(
+    "//nixpkgs:nixpkgs.bzl",
+    "nixpkgs_cc_configure",
+    "nixpkgs_git_repository",
+    "nixpkgs_package"
+)
 
 # For tests
 
@@ -74,3 +79,5 @@ filegroup(
 )
 """,
 )
+
+nixpkgs_cc_configure(repository = "@remote_nixpkgs//:default.nix")

nixpkgs/BUILD.pkg

@@ -1,4 +1,4 @@
-package(default_visibility = [ "//visibility:public" ])
+package(default_visibility = ["//visibility:public"])
 
 filegroup(
   name = "bin",

nixpkgs/nixpkgs.bzl

@@ -187,67 +187,63 @@ stderr:
   stdout=exec_result.stdout,
   stderr=exec_result.stderr))
 
-def _cc_configure_custom(ctx):
-  overriden_tools = {
-    "gcc": ctx.path(ctx.attr.gcc),
-    "ld": ctx.path(ctx.attr.ld),
-  }
-  return cc_autoconf_impl(ctx, overriden_tools)
-
-cc_configure_custom = repository_rule(
-  implementation = _cc_configure_custom,
-  attrs = {
-    "gcc": attr.label(
-      executable=True,
-      cfg="host",
-      allow_single_file=True,
-      doc="`gcc` to use in cc toolchain",
-    ),
-    "ld": attr.label(
-      executable=True,
-      cfg="host",
-      allow_single_file=True,
-      doc="`ld` to use in cc toolchain",
-    ),
-  },
-  local = True,
-  environ = [
-        "ABI_LIBC_VERSION",
-        "ABI_VERSION",
-        "BAZEL_COMPILER",
-        "BAZEL_HOST_SYSTEM",
-        "BAZEL_LINKOPTS",
-        "BAZEL_PYTHON",
-        "BAZEL_SH",
-        "BAZEL_TARGET_CPU",
-        "BAZEL_TARGET_LIBC",
-        "BAZEL_TARGET_SYSTEM",
-        "BAZEL_USE_CPP_ONLY_TOOLCHAIN",
-        "BAZEL_DO_NOT_DETECT_CPP_TOOLCHAIN",
-        "BAZEL_USE_LLVM_NATIVE_COVERAGE",
-        "BAZEL_VC",
-        "BAZEL_VS",
-        "CC",
-        "CC_CONFIGURE_DEBUG",
-        "CC_TOOLCHAIN_NAME",
-        "CPLUS_INCLUDE_PATH",
-        "CUDA_COMPUTE_CAPABILITIES",
-        "CUDA_PATH",
-        "GCOV",
-        "HOMEBREW_RUBY_PATH",
-        "NO_WHOLE_ARCHIVE_OPTION",
-        "SYSTEMROOT",
-        "USE_DYNAMIC_CRT",
-        "USE_MSVC_WRAPPER",
-        "VS90COMNTOOLS",
-        "VS100COMNTOOLS",
-        "VS110COMNTOOLS",
-        "VS120COMNTOOLS",
-        "VS140COMNTOOLS",
-    ],
+def _nixpkgs_cc_autoconf_impl(repository_ctx):
+  # Calling repository_ctx.path() on anything but a regular file
+  # fails. So the roundabout way to do the same thing is to find
+  # a regular file we know is in the workspace (i.e. the WORKSPACE
+  # file itself) and then use dirname to get the path of the workspace
+  # root.
+  workspace_file_path = repository_ctx.path(
+    Label("@nixpkgs_cc_toolchain//:WORKSPACE")
+  )
+  workspace_root = repository_ctx.execute(
+    ["dirname", workspace_file_path]
+  ).stdout.rstrip()
+
+  # Make a list of all available tools in the Nix derivation. Override
+  # the Bazel autoconfiguration with the tools we found.
+  res = repository_ctx.execute(["ls", workspace_root + "/bin"])
+  if res.return_code == 0:
+    overriden_tools = {
+      tool: repository_ctx.path(Label("@nixpkgs_cc_toolchain//:bin/" + tool))
+      for tool in res.stdout.splitlines()
+    }
+    cc_autoconf_impl(repository_ctx, overriden_tools = overriden_tools)
+  else:
+    fail("Cannot list content of @nixpkgs_cc_toolchain:" + res.stderr)
+
+_nixpkgs_cc_autoconf = repository_rule(
+  implementation = _nixpkgs_cc_autoconf_impl
 )
-"""Overwrite cc toolchain by supplying custom `gcc` and `ld` (e.g. from
-Nix). This allows to fix mismatch of `gcc` versions between what is used by
-packages that come from Nix (e.g. `ghc`) and what Bazel detects
-automatically (i.e. system-level `gcc`).
-"""
+
+def nixpkgs_cc_configure(
+    repository = None,
+    repositories = None,
+    nix_file_content = """
+      with import <nixpkgs> {}; buildEnv {
+        name = "bazel-cc-toolchain";
+        paths = [ gcc binutils ];
+      }
+    """,
+    build_file_content = """exports_files(glob(["bin/*"]))"""):
+  """Use a CC toolchain from Nixpkgs.
+  
+  By default, Bazel auto-configures a CC toolchain from commands (e.g.
+  `gcc`) available in the environment. To make builds more hermetic, use
+  this rule to specific explicitly which commands the toolchain should
+  use.
+  """
+  if repository and repositories or not repository and not repositories:
+    fail("Specify one of repository or repositories (but not both).")
+  elif repository:
+    repositories = {"nixpkgs": repository}
+
+  nixpkgs_package(
+    name = "nixpkgs_cc_toolchain",
+    repositories = repositories,
+    nix_file_content = nix_file_content,
+    build_file_content = build_file_content,
+  )
+  _nixpkgs_cc_autoconf(name = "local_config_cc")
+  native.bind(name = "cc_toolchain", actual = "@local_config_cc//:toolchain")
+  native.register_toolchains("@local_config_cc//:all")

tests/BUILD

@@ -47,3 +47,9 @@ package(default_testonly = 1)
         timeout = "short",
     )
 ]
+
+# Test nixpkgs_cc_configure() by building some CC code.
+cc_binary(
+    name = "cc-test",
+    srcs = ["cc-test.cc"],
+)