polydata4/build.gradle at master · unidev-polydata/polydata4 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
plugins {
    id 'io.freefair.lombok' version '8.14' apply false
    id 'com.palantir.git-version' version '3.3.0'
}

println 'Building version: ' + gitVersion()

subprojects {

    group = 'com.unidev.polydata4'
    version = gitVersion()

    apply plugin: 'java'
    apply plugin: 'idea'
    apply plugin: 'maven-publish'
    apply plugin: 'java-library'
    apply plugin: 'io.freefair.lombok'

    repositories {
        google()
        mavenCentral()
        maven {
            url = "https://mvn.universal-development.com/public"
        }
    }

    dependencies {
        testImplementation "org.mockito:mockito-core:${mokitoVersion}"
        testImplementation "org.hamcrest:hamcrest:${hamcrestVersion}"
        testImplementation "org.assertj:assertj-core:${assertjCoreVersion}"

        testImplementation "org.testcontainers:testcontainers:${testcontainersVersion}"
        testImplementation "org.testcontainers:junit-jupiter:${testcontainersVersion}"

        testImplementation "org.junit.jupiter:junit-jupiter:${junitJupiterVersion}"
        testRuntimeOnly "org.junit.platform:junit-platform-launcher"
    }

    idea {
        module {
            downloadSources = true
        }
    }

    // polydata-model stays on Java 8 to remain consumable by Java 8 downstream
    // projects. All other modules move to Java 25.
    if (project.name == 'polydata-model') {
        java {
            sourceCompatibility = JavaVersion.VERSION_1_8
            targetCompatibility = JavaVersion.VERSION_1_8
        }
    } else {
        java {
            toolchain {
                languageVersion = JavaLanguageVersion.of(25)
            }
        }
    }

    lombok {
        version = lombokVersion
    }

    tasks.withType(Copy).configureEach { duplicatesStrategy = 'exclude' }

    // docker-java defaults to API v1.32 which Docker 25+ rejects.
    // Apply to every Test task (test, itest, ...) so Testcontainers can connect.
    tasks.withType(Test).configureEach {
        useJUnitPlatform()
        def dockerApi = System.getenv().getOrDefault('DOCKER_API_VERSION', '1.44')
        systemProperty 'api.version', dockerApi
        environment 'DOCKER_API_VERSION', dockerApi
    }

    publishing {
        publications {
            mavenJava(MavenPublication) {
                from components.java
            }
        }
    }
}