WRF/external/io_pnetcdf/CMakeLists.txt at 762515ab7328f82d92b1be07ddf04e5acf60cb7f · wrf-model/WRF · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
# WRF CMake Build

get_filename_component( FOLDER_COMPILE_TARGET ${CMAKE_CURRENT_SOURCE_DIR} NAME)

add_library(
            ${FOLDER_COMPILE_TARGET}
              STATIC
              )

# Do this first to simplify steps later
set_target_properties(
                      ${FOLDER_COMPILE_TARGET}
                        PROPERTIES
                          Fortran_MODULE_DIRECTORY ${CMAKE_INSTALL_PREFIX}/${FOLDER_COMPILE_TARGET}
                          EXPORT_PROPERTIES        Fortran_MODULE_DIRECTORY
                      )


target_link_libraries(  ${FOLDER_COMPILE_TARGET}
                          PRIVATE
                            $<$<BOOL:${USE_MPI}>:$<TARGET_NAME_IF_EXISTS:MPI::MPI_Fortran>>
                            $<$<BOOL:${USE_OPENMP}>:$<TARGET_NAME_IF_EXISTS:OpenMP::OpenMP_Fortran>>
                            PnetCDF::pnetcdf
                        )

target_include_directories( ${FOLDER_COMPILE_TARGET}
                            PUBLIC
                              $<TARGET_PROPERTY:${FOLDER_COMPILE_TARGET},Fortran_MODULE_DIRECTORY>
                              $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/external/ioapi_share>
                              $<INSTALL_INTERFACE:include/external/ioapi_share>
                            PRIVATE
                              ${CMAKE_CURRENT_SOURCE_DIR}
                            )


# First preprocess
get_target_property   ( FOLDER_COMPILE_TARGET_INCLUDES ${FOLDER_COMPILE_TARGET} INCLUDE_DIRECTORIES )
wrf_c_preproc_fortran(
                        TARGET_NAME     ${FOLDER_COMPILE_TARGET}_c_preproc_wrf_io
                        OUTPUT_DIR      ${CMAKE_CURRENT_BINARY_DIR}/preproc/
                        EXTENSION       ".f90"
                        INCLUDES        ${FOLDER_COMPILE_TARGET_INCLUDES}
                        DEFINITIONS     ${PROJECT_COMPILE_DEFINITIONS}
                        SOURCES         wrf_io.F90
                        )

# Now M4 preprocess
wrf_m4_preproc_fortran(
                        TARGET_NAME     ${FOLDER_COMPILE_TARGET}_m4_preproc_wrf_io
                        OUTPUT_DIR      ${CMAKE_CURRENT_BINARY_DIR}/preproc/
                        PREFIX          "m4_preproc_"
                        EXTENSION       ".f90"
                        SOURCES         ${CMAKE_CURRENT_BINARY_DIR}/preproc/wrf_io.f90
                        DEPENDENCIES    ${FOLDER_COMPILE_TARGET}_c_preproc_wrf_io
                        TARGET_SCOPE    ${FOLDER_COMPILE_TARGET}
                        FLAGS           ${M4_FLAGS}
                        )

add_dependencies( ${FOLDER_COMPILE_TARGET} ${FOLDER_COMPILE_TARGET}_m4_preproc_wrf_io )

target_sources(
                ${FOLDER_COMPILE_TARGET}
                PRIVATE
                  ${CMAKE_CURRENT_BINARY_DIR}/preproc/m4_preproc_wrf_io.f90
                  module_wrfsi_static.F90
                  field_routines.F90
                  )

install(
        TARGETS ${FOLDER_COMPILE_TARGET}
        EXPORT  ${EXPORT_NAME}Targets
        RUNTIME DESTINATION bin/
        ARCHIVE DESTINATION lib/
        LIBRARY DESTINATION lib/
        )