std.c: define freopen() and the stdio streams

This allows for daemonization and output-redirection sorts of code
in libc-linked Zig projects on *nix-y platforms to affect the
stdio stream usage of other libc-based library code the project
may be linking, e.g.:

    // Set stderr to go nowhere without errors:
    _ = std.c.freopen("/dev/null", "r+", std.c.stderr());

    // Append stdout to a file:
    _ = std.c.freopen("/tmp/output.txt", "a", std.c.stdout());

The stdio streams are returned from function calls because they're
commonly #defines in the libc headers pointing at variously-named
externs, and one doesn't generally assign to them directly anyways
(freopen() is the portable way to assign something new to a stdio
stream).

NetBSD, OpenBSD, and Solaris stdio streams are not supported in
this patch and will cause a compileError if you try to use the
them, for now. Supporting them would require a more complex and
fragile solution using a definition of "FILE" that is not just an
opaque type (because their C libraries publish an extern array of
FILE objects and then #define the stdio stream names as pointers
to the array elements).

Author: blblack

lib/std/c.zig

@@ -10482,6 +10482,7 @@ pub const futex = switch (native_os) {
 pub extern "c" var environ: [*:null]?[*:0]u8;
 
 pub extern "c" fn fopen(noalias filename: [*:0]const u8, noalias modes: [*:0]const u8) ?*FILE;
+pub extern "c" fn freopen(noalias filename: [*:0]const u8, noalias modes: [*:0]const u8, noalias stream: *FILE) ?*FILE;
 pub extern "c" fn fclose(stream: *FILE) c_int;
 pub extern "c" fn fwrite(noalias ptr: [*]const u8, size_of_type: usize, item_count: usize, noalias stream: *FILE) usize;
 pub extern "c" fn fread(noalias ptr: [*]u8, size_of_type: usize, item_count: usize, noalias stream: *FILE) usize;
@@ -10782,6 +10783,34 @@ pub const pthread_t = switch (native_os) {
 };
 pub const FILE = opaque {};
 
+// NetBSD, OpenBSD, and Solaris definitions could be created, but the stdio
+// streams on these are stored in an extern array of FILE objects, so we'd need
+// precise definitions of the size of "struct FILE" for various arches and
+// versions to get the correct offsets...
+pub fn stdin() *FILE {
+    return switch (native_os) {
+        .linux, .serenity, .haiku => private.stdin,
+        .freebsd, .dragonfly, .macos, .ios, .tvos, .watchos, .visionos => private.__stdinp,
+        else => @compileError("stdio streams unsupported on this platform"),
+    };
+}
+
+pub fn stdout() *FILE {
+    return switch (native_os) {
+        .linux, .serenity, .haiku => private.stdout,
+        .freebsd, .dragonfly, .macos, .ios, .tvos, .watchos, .visionos => private.__stdoutp,
+        else => @compileError("stdio streams unsupported on this platform"),
+    };
+}
+
+pub fn stderr() *FILE {
+    return switch (native_os) {
+        .linux, .serenity, .haiku => private.stderr,
+        .freebsd, .dragonfly, .macos, .ios, .tvos, .watchos, .visionos => private.__stderrp,
+        else => @compileError("std streams unsupported on this platform"),
+    };
+}
+
 pub extern "c" fn dlopen(path: ?[*:0]const u8, mode: RTLD) ?*anyopaque;
 pub extern "c" fn dlclose(handle: *anyopaque) c_int;
 pub extern "c" fn dlsym(handle: ?*anyopaque, symbol: [*:0]const u8) ?*anyopaque;
@@ -11283,6 +11312,16 @@ const private = struct {
     extern "c" fn __libc_current_sigrtmin() c_int;
     extern "c" fn __libc_current_sigrtmax() c_int;
 
+    // Linux, Serenity, Haiku
+    extern "c" var stdin: *FILE;
+    extern "c" var stdout: *FILE;
+    extern "c" var stderr: *FILE;
+
+    // FreeBSD, Dragonfly, Darwin
+    extern "c" var __stdinp: *FILE;
+    extern "c" var __stdoutp: *FILE;
+    extern "c" var __stderrp: *FILE;
+
     // Don't forget to add another clown when an OS picks yet another unique
     // symbol name for errno location!
     // 🤡🤡🤡🤡🤡🤡