Feature/cmake targets

CMakeLists.txt

@@ -23,186 +23,95 @@
 # OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
 # SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 
-cmake_minimum_required(VERSION 3.16.3)
-project(kindr)
+# Project configuration
+cmake_minimum_required(VERSION 3.5)
 
+project(kindr
+  VERSION 0.0.0
+  LANGUAGES CXX
+)
 
+# Include helper packages
+include(CTest)
+include(GNUInstallDirs)
+include(CMakePackageConfigHelpers)
 
-if("$ENV{ROS_VERSION}" STREQUAL "1" OR USE_CMAKE)
-
-
-
-# Check if catkin package should be built.
-if(NOT USE_CMAKE)
-  find_package(catkin QUIET)
-  message(STATUS "Setting pure CMake build to false as not specified.")
-  set(USE_CMAKE false CACHE BOOL "Choose whether to build with CMake." FORCE)
-  set_property(CACHE USE_CMAKE PROPERTY STRINGS "True" "False")
-endif()
-
-if(catkin_FOUND AND NOT USE_CMAKE)
-  message(STATUS "Building kindr as a catkin package.")
-  set(BUILD_CATKIN_PACKAGE true)
-  set(BUILD_TEST false)
-else()
-  message(STATUS "Building kindr as a cmake package.")
-  set(BUILD_CATKIN_PACKAGE false)
-endif()
-
-# Configure CMake.
-if(NOT BUILD_CATKIN_PACKAGE)
-  set(EXECUTABLE_OUTPUT_PATH ${CMAKE_BINARY_DIR})
-  set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake" ${CMAKE_MODULE_PATH})
+# Set C++ 11
+if(NOT CMAKE_CXX_STANDARD)
+  set(CMAKE_CXX_STANDARD 11)
 endif()
 
-# Noisily default to Release build
-if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
-  message(STATUS "Setting build type to 'Release' as none was specified.")
-  set(CMAKE_BUILD_TYPE Release CACHE STRING "Choose the type of build." FORCE)
-  set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS
-    "Debug" "Release" "MinSizeRel" "RelWithDebInfo")
+# Output more warnings
+if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
+  add_compile_options(-Wall -Wextra -Wpedantic)
 endif()
 
-add_definitions(-std=c++11)
-
+# Dependencies
 find_package(Eigen3 REQUIRED)
 
-# Init catkin package.
-if(BUILD_CATKIN_PACKAGE)
-  catkin_package(
-    INCLUDE_DIRS
-      include
-      ${EIGEN3_INCLUDE_DIR}
-  )
-endif()
-
-include_directories(include)
-include_directories(${EIGEN3_INCLUDE_DIR})
-
-# Don't build tests if not specified.
-if(NOT BUILD_TEST)
-  message(STATUS "Setting build-tests to false as not specified.")
-  set(BUILD_TEST false CACHE BOOL "Choose whether to build tests." FORCE)
-  set_property(CACHE BUILD_TEST PROPERTY STRINGS
-    "True" "False")
-endif()
-
-if(BUILD_TEST AND EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/gtest/")
-	message(STATUS "Building GTests!")
-	option(BUILD_GTEST "build gtest" ON)
-	add_subdirectory(gtest gtest)
-	enable_testing()
-endif()
+# Add header library target
+add_library(${PROJECT_NAME} INTERFACE)
+target_include_directories(${PROJECT_NAME} INTERFACE
+  $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
+  $<INSTALL_INTERFACE:include>)
 
-install(DIRECTORY include/kindr DESTINATION include)
+target_link_libraries(${PROJECT_NAME} INTERFACE Eigen3::Eigen)
 
 # Add unit tests
-add_subdirectory(test)
+if(BUILD_TESTING)
+  enable_testing()
+  add_subdirectory(test)
+endif()
 
 # Add Doxygen documentation
 add_subdirectory(doc/doxygen)
 
-# Install catkin package.xml
-#install(FILES package.xml DESTINATION share/kindr)
-
-
-#=============================================
-# to allow find_package() on kindr
-#=============================================
-#
-# the following case be used in an external project requiring kindr:
-#  ...
-#  find_package(kindr)
-#  include_directories(${kindr_INCLUDE_DIRS})
-#  ...
-
-# NOTE: the following will support find_package for 1) local build (make) and 2) for installed files (make install)
-
-# 1- local build #
-
-# Register the local build in case one doesn't use "make install"
-export(PACKAGE kindr)
-
-# Create variable for the local build tree
-get_property(kindr_include_dirs DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR} PROPERTY INCLUDE_DIRECTORIES)
-
-# Configure config file for local build tree
-configure_file(kindrConfig.cmake.in
-  "${PROJECT_BINARY_DIR}/kindrConfig.cmake" @ONLY)
-
-# 2- installation build #
-
-# Change the include location for the case of an install location
-set(kindr_include_dirs ${CMAKE_INSTALL_PREFIX}/include ${EIGEN3_INCLUDE_DIR})
-
-
-# We put the generated file for installation in a different repository (i.e., ./CMakeFiles/)
-configure_file(kindrConfig.cmake.in
-  "${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/kindrConfig.cmake" @ONLY)
-
-install(FILES
-  "${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/kindrConfig.cmake"
-  DESTINATION share/kindr/cmake COMPONENT dev)
+# Install library
+install(TARGETS ${PROJECT_NAME}
+  EXPORT ${PROJECT_NAME}_export
+  ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
+  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+  RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
+install(DIRECTORY include/
+  DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
+
+# Export library target
+export(EXPORT ${PROJECT_NAME}_export
+  FILE ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Targets.cmake
+  NAMESPACE ${PROJECT_NAME}::)
+install(EXPORT ${PROJECT_NAME}_export
+  FILE ${PROJECT_NAME}Targets.cmake
+  NAMESPACE ${CMAKE_PROJECT_NAME}::
+  DESTINATION ${CMAKE_INSTALL_LIBDIR}/${PROJECT_NAME}/cmake)
+
+# Generate Version.cmake and Config.cmake file
+write_basic_package_version_file(
+  ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake
+  VERSION ${PROJECT_VERSION}
+  COMPATIBILITY SameMajorVersion)
+
+set(INCLUDE_INSTALL_DIR ${CMAKE_INSTALL_INCLUDEDIR})
+configure_package_config_file(
+  cmake/${PROJECT_NAME}Config.cmake.in
+  ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Config.cmake
+  INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/${PROJECT_NAME}/cmake
+  PATH_VARS INCLUDE_INSTALL_DIR)
 
 install(FILES
-  package.xml
-  DESTINATION share/kindr COMPONENT dev)
+${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake
+${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Config.cmake
+  DESTINATION ${CMAKE_INSTALL_LIBDIR}/${PROJECT_NAME}/cmake)
 
 
 #=============================================
 # Add uninstall target
 #=============================================
 configure_file(
-    "${CMAKE_CURRENT_SOURCE_DIR}/cmake_uninstall.cmake.in"
+    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
     IMMEDIATE @ONLY)
 
-if (NOT TARGET uninstall)
+if(NOT TARGET uninstall)
   add_custom_target(uninstall
     COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
-endif()
-
-
-
-else() # ROS version 2
-
-
-set(CMAKE_CXX_STANDARD 14)
-
-find_package(ament_cmake REQUIRED)
-find_package(Eigen3 REQUIRED)
-
-add_library(
-  ${PROJECT_NAME}
-  INTERFACE
-)
-target_include_directories(
-  ${PROJECT_NAME}
-  INTERFACE
-  "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>" "$<INSTALL_INTERFACE:include/${PROJECT_NAME}>"
-  ${EIGEN3_INCLUDE_DIR}
-)
-ament_target_dependencies(${PROJECT_NAME} Eigen3)
-
-# Add Doxygen documentation
-add_subdirectory(doc/doxygen)
-
-install(DIRECTORY include/ DESTINATION include/${PROJECT_NAME})
-install(
-  TARGETS ${PROJECT_NAME}
-  EXPORT export_${PROJECT_NAME}
-  LIBRARY DESTINATION lib
-  ARCHIVE DESTINATION lib
-  RUNTIME DESTINATION bin
-)
-
-if(BUILD_TESTING)
-  add_subdirectory(test)
-endif()
-
-ament_export_targets(export_${PROJECT_NAME} HAS_LIBRARY_TARGET)
-ament_export_dependencies(Eigen3)
-
-ament_package()
-
-endif()
+endif()