Restore interface after giving Biggoron Claim Check

ASM/src/build.asm

@@ -133,6 +133,7 @@ RANDO_CONTEXT:
 .include "en_dns.asm"
 .include "bg_gate_shutter.asm"
 .include "big_poe.asm"
+.include "engo2_biggoronidleclaimcheck.asm"
 .include "player_laddercutscenefix.asm"
 
 .align 0x10

ASM/src/engo2_biggoronidleclaimcheck.asm

@@ -0,0 +1,16 @@
+EnGo2_BiggoronIdleClaimCheck:
+    lh      v1,28(s0)       ; displaced
+    move    v0,zero         ; default return is not reverse
+    lh      t8,28(a0)       ; actor params/variable
+    li      at,2            ; Biggoron
+    andi    t8,t8,0x1f
+    bne     at,t8,@@Return  ; only check if Biggoron
+    li      at,1
+    lb      t8,510(a0)      ; EnGo2->reverse
+    bne     at,t8,@@Return
+    li      at,0
+    sb      at,510(a0)      ; if set, unset reverse flag
+    li      v0,1            ; and branch to end in caller
+@@Return:
+    jr      ra
+    li      at,1            ; displaced

ASM/src/hacks.asm

@@ -2684,8 +2684,8 @@ claim_check_not_traded:
 ; Skip setting the BGS flag after turning in the claim check
 ; Replaces
 ;   sb      t8, 0x003E(v0)
-.orga 0xED6574
-    nop
+; .orga 0xED6574    --- displaced by Claim Check interface fix
+;     nop
 
 ; Change Biggoron animation if adult trade quest shuffle is on
 ; to always in pain until the eye drops are turned in.
@@ -4162,3 +4162,4 @@ DemoEffect_DrawJewel_AfterHook:
 .include "hacks/ovl_en_okarina_tag.asm"
 .include "hacks/sound.asm"
 .include "hacks/z_player.asm"
+.include "hacks/z_en_go2.asm"

ASM/src/hacks/z_en_go2.asm

@@ -0,0 +1,26 @@
+
+.headersize (0x80b56910 - 0x00ed2040)
+
+; Goron overlay (including Link Goron, Biggoron)
+
+;================================================================================
+; Biggoron: Set EnGo2->reverse variable when turning in Claim Check/receiving BGS
+; to delay changing action function by one frame (see below; fixes interface bug)
+;================================================================================
+; Replaces: sb      t8,62(v0)
+.org 0x80b5ae44     ; in EnGo2_SetGetItem
+    sb      t8,510(s0)
+
+;================================================================================
+; Biggoron: In "idle" action function, if EnGo2->reverse is set, unset it and
+; return without calling any functions further down (i.e. EnGo2_IsCameraModified)
+;================================================================================
+; Replaces: lh      v1,28(s0)
+;           lbu     t6,513(s0)
+;           li      at,1
+;           andi    v1,v1,0x1f
+.org 0x80b5a768     ; in EnGo2_Action_80A46B40
+    jal     EnGo2_BiggoronIdleClaimCheck
+    lbu     t6,513(s0)      ; displaced
+    bnez    v0,0x80b5a8d8   ; to function end if reverse is set
+    andi    v1,v1,0x1f      ; displaced