Rust: Improve CFG

rust/ql/lib/codeql/rust/controlflow/internal/Completion.qll

@@ -6,6 +6,14 @@ private import SuccessorType
 private newtype TCompletion =
   TSimpleCompletion() or
   TBooleanCompletion(Boolean b) or
+  TMatchCompletion(Boolean isMatch) or
+  TLoopCompletion(TLoopJumpType kind, TLabelType label) {
+    label = TNoLabel()
+    or
+    kind = TBreakJump() and label = TLabel(any(BreakExpr b).getLifetime().getText())
+    or
+    kind = TContinueJump() and label = TLabel(any(ContinueExpr b).getLifetime().getText())
+  } or
   TReturnCompletion()
 
 /** A completion of a statement or an expression. */
@@ -51,6 +59,10 @@ abstract class ConditionalCompletion extends NormalCompletion {
   /** Gets the Boolean value of this conditional completion. */
   final boolean getValue() { result = value }
 
+  final predicate succeeded() { value = true }
+
+  final predicate failed() { value = false }
+
   /** Gets the dual completion. */
   abstract ConditionalCompletion getDual();
 }
@@ -62,7 +74,34 @@ abstract class ConditionalCompletion extends NormalCompletion {
 class BooleanCompletion extends ConditionalCompletion, TBooleanCompletion {
   BooleanCompletion() { this = TBooleanCompletion(value) }
 
-  override predicate isValidForSpecific(AstNode e) { e = any(IfExpr c).getCondition() }
+  override predicate isValidForSpecific(AstNode e) {
+    e = any(IfExpr c).getCondition()
+    or
+    any(MatchArm arm).getGuard() = e
+    or
+    exists(BinaryExpr expr |
+      expr.getOperatorName() = ["&&", "||"] and
+      e = expr.getLhs()
+    )
+    or
+    exists(Expr parent | this.isValidForSpecific(parent) |
+      parent =
+        any(PrefixExpr expr |
+          expr.getOperatorName() = "!" and
+          e = expr.getExpr()
+        )
+      or
+      parent =
+        any(BinaryExpr expr |
+          expr.getOperatorName() = ["&&", "||"] and
+          e = expr.getRhs()
+        )
+      or
+      parent = any(IfExpr ie | e = [ie.getThen(), ie.getElse()])
+      or
+      parent = any(BlockExpr be | e = be.getStmtList().getTailExpr())
+    )
+  }
 
   /** Gets the dual Boolean completion. */
   override BooleanCompletion getDual() { result = TBooleanCompletion(value.booleanNot()) }
@@ -72,6 +111,63 @@ class BooleanCompletion extends ConditionalCompletion, TBooleanCompletion {
   override string toString() { result = "boolean(" + value + ")" }
 }
 
+/**
+ * A completion that represents the result of a pattern match.
+ */
+class MatchCompletion extends TMatchCompletion, ConditionalCompletion {
+  MatchCompletion() { this = TMatchCompletion(value) }
+
+  override predicate isValidForSpecific(AstNode e) { e instanceof Pat }
+
+  override MatchSuccessor getAMatchingSuccessorType() { result.getValue() = value }
+
+  /** Gets the dual match completion. */
+  override MatchCompletion getDual() { result = TMatchCompletion(value.booleanNot()) }
+
+  override string toString() { result = "match(" + value + ")" }
+}
+
+/**
+ * A completion that represents a break or a continue.
+ */
+class LoopJumpCompletion extends TLoopCompletion, Completion {
+  override LoopJumpSuccessor getAMatchingSuccessorType() {
+    result = TLoopSuccessor(this.getKind(), this.getLabelType())
+  }
+
+  final TLoopJumpType getKind() { this = TLoopCompletion(result, _) }
+
+  final TLabelType getLabelType() { this = TLoopCompletion(_, result) }
+
+  final predicate hasLabel() { this.getLabelType() = TLabel(_) }
+
+  final string getLabelName() { TLabel(result) = this.getLabelType() }
+
+  final predicate isContinue() { this.getKind() = TContinueJump() }
+
+  final predicate isBreak() { this.getKind() = TBreakJump() }
+
+  override predicate isValidForSpecific(AstNode e) {
+    this.isBreak() and
+    e instanceof BreakExpr and
+    (
+      not e.(BreakExpr).hasLifetime() and not this.hasLabel()
+      or
+      e.(BreakExpr).getLifetime().getText() = this.getLabelName()
+    )
+    or
+    this.isContinue() and
+    e instanceof ContinueExpr and
+    (
+      not e.(ContinueExpr).hasLifetime() and not this.hasLabel()
+      or
+      e.(ContinueExpr).getLifetime().getText() = this.getLabelName()
+    )
+  }
+
+  override string toString() { result = this.getAMatchingSuccessorType().toString() }
+}
+
 /**
  * A completion that represents a return.
  */