[CSM v3 / CM v2] feat: SettleGeneralDelayedPenalty + SetMerkleGateTree + SubmitWithdrawals factories

contracts/EVMScriptFactories/SettleGeneralDelayedPenalty.sol

@@ -0,0 +1,119 @@
+// SPDX-FileCopyrightText: 2024 Lido <[email protected]>
+// SPDX-License-Identifier: GPL-3.0
+
+pragma solidity 0.8.6;
+
+import "../TrustedCaller.sol";
+import "../libraries/EVMScriptCreator.sol";
+import "../interfaces/IEVMScriptFactory.sol";
+import "../interfaces/ICSModule.sol";
+import "../interfaces/ICSAccounting.sol";
+
+/// @author vgorkavenko
+/// @notice Creates EVMScript to settle general delayed penalty for a specific node operators
+contract SettleGeneralDelayedPenalty is TrustedCaller, IEVMScriptFactory {
+
+    // -------------
+    // ERRORS
+    // -------------
+
+    string private constant ERROR_EMPTY_NODE_OPERATORS_IDS =
+        "EMPTY_NODE_OPERATORS_IDS";
+    string private constant ERROR_OUT_OF_RANGE_NODE_OPERATOR_ID =
+        "OUT_OF_RANGE_NODE_OPERATOR_ID";
+    string private constant ERROR_NODE_OPERATORS_IDS_AND_MAX_AMOUNTS_LENGTH_MISMATCH =
+        "NODE_OPERATORS_IDS_AND_MAX_AMOUNTS_LENGTH_MISMATCH";
+    string private constant ERROR_MAX_AMOUNT_SHOULD_BE_GREATER_OR_EQUAL_THAN_ACTUAL_LOCKED =
+        "MAX_AMOUNT_SHOULD_BE_GREATER_OR_EQUAL_THAN_ACTUAL_LOCKED";
+    string private constant ERROR_MAX_AMOUNT_SHOULD_BE_GREATER_THAN_ZERO =
+        "MAX_AMOUNT_SHOULD_BE_GREATER_THAN_ZERO";
+
+    // -------------
+    // VARIABLES
+    // -------------
+
+    /// @notice Address of Module Contract
+    ICSModule public immutable module;
+    ICSAccounting public immutable accounting;
+
+    // -------------
+    // CONSTRUCTOR
+    // -------------
+
+    constructor(address _trustedCaller, address _module)
+        TrustedCaller(_trustedCaller)
+    {
+        module = ICSModule(_module);
+        accounting = ICSAccounting(ICSModule(_module).ACCOUNTING());
+    }
+
+    // -------------
+    // EXTERNAL METHODS
+    // -------------
+
+    /// @notice Creates EVMScript to settle general delayed penalty for the specific node operators
+    /// @param _creator Address who creates EVMScript
+    /// @param _evmScriptCallData Encoded: uint256[] memory nodeOperatorIds, uint256[] memory maxAmounts
+    function createEVMScript(address _creator, bytes memory _evmScriptCallData)
+        external
+        view
+        override
+        onlyTrustedCaller(_creator)
+        returns (bytes memory)
+    {
+        (uint256[] memory nodeOperatorIds, uint256[] memory maxAmounts) = _decodeEVMScriptCallData(_evmScriptCallData);
+
+        _validateInputData(nodeOperatorIds, maxAmounts);
+
+        return
+            EVMScriptCreator.createEVMScript(
+                address(module),
+                ICSModule.settleGeneralDelayedPenalty.selector,
+                _evmScriptCallData
+            );
+    }
+
+    /// @notice Decodes call data used by createEVMScript method
+    /// @param _evmScriptCallData Encoded: uint256[] memory nodeOperatorIds, uint256[] memory maxAmounts
+    /// @return Node operator IDs and max amounts to settle general delayed penalty
+    function decodeEVMScriptCallData(bytes memory _evmScriptCallData)
+        external
+        pure
+        returns (uint256[] memory, uint256[] memory)
+    {
+        return _decodeEVMScriptCallData(_evmScriptCallData);
+    }
+
+    // ------------------
+    // PRIVATE METHODS
+    // ------------------
+
+    function _decodeEVMScriptCallData(bytes memory _evmScriptCallData)
+        private
+        pure
+        returns (uint256[] memory, uint256[] memory)
+    {
+        return abi.decode(_evmScriptCallData, (uint256[], uint256[]));
+    }
+
+    function _validateInputData(
+        uint256[] memory nodeOperatorsIds,
+        uint256[] memory maxAmounts
+    ) private view {
+        require(nodeOperatorsIds.length > 0, ERROR_EMPTY_NODE_OPERATORS_IDS);
+        require(
+            nodeOperatorsIds.length == maxAmounts.length,
+            ERROR_NODE_OPERATORS_IDS_AND_MAX_AMOUNTS_LENGTH_MISMATCH
+        );
+        uint256 nodeOperatorsCount = module.getNodeOperatorsCount();
+        for (uint256 i = 0; i < nodeOperatorsIds.length; ++i) {
+            (uint256 nodeOperatorId, uint256 maxAmount) = (nodeOperatorsIds[i], maxAmounts[i]);
+            require(nodeOperatorId < nodeOperatorsCount, ERROR_OUT_OF_RANGE_NODE_OPERATOR_ID);
+            uint256 actualLocked = accounting.getActualLockedBond(
+                nodeOperatorId
+            );
+            require(maxAmount > 0, ERROR_MAX_AMOUNT_SHOULD_BE_GREATER_THAN_ZERO);
+            require(maxAmount >= actualLocked, ERROR_MAX_AMOUNT_SHOULD_BE_GREATER_OR_EQUAL_THAN_ACTUAL_LOCKED);
+        }
+    }
+}

contracts/interfaces/ICSAccounting.sol

@@ -0,0 +1,14 @@
+// SPDX-FileCopyrightText: 2024 Lido <[email protected]>
+// SPDX-License-Identifier: GPL-3.0
+
+ pragma solidity 0.8.6;
+
+/// @title Lido's CSM accounting interface
+interface ICSAccounting {
+    /// @notice Get amount of the locked bond in ETH (stETH) by the given Node Operator
+    /// @param nodeOperatorId ID of the Node Operator
+    /// @return Amount of the actual locked bond
+    function getActualLockedBond(
+        uint256 nodeOperatorId
+    ) external view returns (uint256);
+}

contracts/interfaces/ICSModule.sol

@@ -5,11 +5,16 @@
 
 /// @title Lido's Community Staking Module interface
 interface ICSModule {
+
+    function ACCOUNTING() external view returns (address);
+
     /// @notice Settles blocked bond for the given Node Operators
     /// @dev Should be called by the Easy Track
     /// @param nodeOperatorIds IDs of the Node Operators
-    function settleELRewardsStealingPenalty(
-        uint256[] memory nodeOperatorIds
+    /// @param maxAmounts Maximum amounts to settle for each Node Operator
+    function settleGeneralDelayedPenalty(
+        uint256[] memory nodeOperatorIds,
+        uint256[] memory maxAmounts
     ) external;
 
     function getNodeOperatorsCount() external view returns (uint256);

tests/conftest.py

@@ -9,6 +9,7 @@
 import constants
 from utils.lido import contracts as lido_contracts_
 from utils.csm import contracts as csm_contracts_
+from utils.cm import contracts as cm_contracts_
 from utils import deployed_date_time
 from utils.test_helpers import set_account_balance
 from utils.submit_exit_requests_test_helpers import MAX_REQUESTS
@@ -111,6 +112,11 @@ def csm_contracts():
     return csm_contracts_(network=brownie.network.show_active())
 
 
+@pytest.fixture(scope="module")
+def cm_contracts():
+    return cm_contracts_(network=brownie.network.show_active())
+
+
 @pytest.fixture(scope="module")
 def motion_settings(owner, MotionSettings):
     return owner.deploy(
@@ -431,6 +437,11 @@ def cs_module(csm_contracts):
     return csm_contracts.module
 
 
+@pytest.fixture(scope="module")
+def curated_module(cm_contracts):
+    return cm_contracts.curated_module
+
+
 @pytest.fixture(scope="module")
 def voting(lido_contracts):
     return lido_contracts.aragon.voting