[POC|Invalid] Testing vcpkg without installed MSVC

.gitignore

@@ -290,7 +290,7 @@ __pycache__/
 /packages/
 /scripts/buildsystems/tmp/
 #ignore custom triplets
-/triplets/*
+
 #add vcpkg-designed triplets back in
 !/triplets/arm-uwp.cmake
 !/triplets/arm64-windows.cmake

ports/msvc/extract-vsix.ps1

@@ -0,0 +1,19 @@
+param (
+    [Parameter(Mandatory=$true)]
+    [string]$VsixFile,
+    [Parameter(Mandatory=$true)]
+    [string]$ExtractTo = "install"
+)
+
+Add-Type -AssemblyName System.IO.Compression.FileSystem
+[System.IO.Compression.ZipFile]::OpenRead(${VsixFile}).Entries |
+    Where-Object { $_.FullName -like 'Contents/*' } |
+    ForEach-Object { 
+        $relativePath = $_.FullName.Substring(9)  # Remove 'Contents/'
+        $outputPath = Join-Path -Path ${ExtractTo} -ChildPath $relativePath
+        $parentPath = [System.IO.Path]::GetDirectoryName($outputPath)
+        if(-not (Test-Path -Path $parentPath)) {
+            New-Item -Path $parentPath -ItemType Directory -Force
+        }
+        [System.IO.Compression.ZipFileExtensions]::ExtractToFile($_, $outputPath, $true)  # Extract entry to the install folder
+    }

ports/msvc/msvc-env.cmake

@@ -0,0 +1,100 @@
+include_guard(GLOBAL)
+
+if(NOT DEFINED ENV{VCPKG_TOOLCHAIN_ENV_ALREADY_SET})
+  set(MSVC_DIR "${CMAKE_CURRENT_LIST_DIR}/../../")
+  set(VS_DIR "${CMAKE_CURRENT_LIST_DIR}/../../VS")
+  set(SDK_DIR "${CMAKE_CURRENT_LIST_DIR}/../../WinSDK")
+
+  set(WinSDK_VERSION "@WinSDK_VERSION@")
+  set(VCToolkit_VERSION "@VCToolkit_VERSION@")
+  set(VCToolkit_REDIST_VERSION "@VCToolkit_REDIST_VERSION@")
+
+  set(LIB 
+        "${VS_DIR}/VC/Tools/MSVC/${VCToolkit_VERSION}/ATLMFC/lib/x64"
+        "${VS_DIR}/VC/Tools/MSVC/${VCToolkit_VERSION}/lib/x64"
+        #"${SDK_DIR}/Windows Kits/NETFXSDK/4.8/lib/um/x64"
+        "${SDK_DIR}/Windows Kits/10/lib/${WinSDK_VERSION}/ucrt/x64"
+        "${SDK_DIR}/Windows Kits/10/lib/${WinSDK_VERSION}/um/x64"
+  )
+  cmake_path(CONVERT "${LIB}" TO_NATIVE_PATH_LIST LIB NORMALIZE)
+  set(ENV{LIB} "${LIB}")
+  set(LIBPATH 
+        "${VS_DIR}/VC/Tools/MSVC/${VCToolkit_VERSION}/ATLMFC/lib/x64"
+        "${VS_DIR}/VC/Tools/MSVC/${VCToolkit_VERSION}/lib/x64"
+        "${VS_DIR}/VC/Tools/MSVC/${VCToolkit_VERSION}/lib/x86/store/references"
+        "${SDK_DIR}/Windows Kits/10/UnionMetadata/${WinSDK_VERSION}"
+        "${SDK_DIR}/Windows Kits/10/References/${WinSDK_VERSION}"
+        #C:/Windows/Microsoft.NET/Framework64/v4.0.30319
+  )
+  cmake_path(CONVERT "${LIBPATH}" TO_NATIVE_PATH_LIST LIBPATH NORMALIZE)
+  set(ENV{LIBPATH} "${LIBPATH}")
+  set(INCLUDE
+        "${VS_DIR}/VC/Tools/MSVC/${VCToolkit_VERSION}/include"
+        "${VS_DIR}/VC/Tools/MSVC/${VCToolkit_VERSION}/ATLMFC/include"
+        "${VS_DIR}/VC/Auxiliary/VS/include"
+        "${SDK_DIR}/Windows Kits/10/include/${WinSDK_VERSION}/ucrt"
+        "${SDK_DIR}/Windows Kits/10/include/${WinSDK_VERSION}/um"
+        "${SDK_DIR}/Windows Kits/10/include/${WinSDK_VERSION}/shared"
+        "${SDK_DIR}/Windows Kits/10/include/${WinSDK_VERSION}/winrt"
+        "${SDK_DIR}/Windows Kits/10/include/${WinSDK_VERSION}/cppwinrt"
+        #"${SDK_DIR}/Windows Kits/NETFXSDK/4.8/include/um"
+  )
+  cmake_path(CONVERT "${INCLUDE}" TO_NATIVE_PATH_LIST INCLUDE NORMALIZE)
+  set(ENV{INCLUDE} "${INCLUDE}")
+  set(EXTERNAL_INCLUDE ${INCLUDE})
+  cmake_path(CONVERT "${EXTERNAL_INCLUDE}" TO_NATIVE_PATH_LIST EXTERNAL_INCLUDE NORMALIZE)
+
+  set(ENV{EXTERNAL_INCLUDE} "${EXTERNAL_INCLUDE}")
+  set(ENV{DevEnvDir} "${VS_DIR}/Common7/IDE/")
+  set(ENV{ExtensionSdkDir} "${SDK_DIR}/Windows Kits/10/ExtensionSDKs")
+  set(ENV{UniversalCRTSdkDir} "${SDK_DIR}/Windows Kits/10/")
+  set(ENV{UCRTVersion} "${WinSDK_VERSION}")
+  set(ENV{VCIDEInstallDir} "${VS_DIR}/Common7/IDE/VC/")
+  set(ENV{VCINSTALLDIR} "${VS_DIR}/VC/")
+  set(ENV{VCToolsInstallDir} "${VS_DIR}/VC/Tools/MSVC/${VCToolkit_VERSION}/")
+  set(ENV{VCToolsRedistDir} "${VS_DIR}/VC/Redist/MSVC/${VCToolkit_REDIST_VERSION}/")
+  set(ENV{VCToolsVersion} "${VCToolkit_VERSION}")
+  set(ENV{VisualStudioVersion} "17.0")
+  set(ENV{VS170COMNTOOLS} "${VS_DIR}/Common7/Tools/")
+  set(ENV{VSINSTALLDIR} "${VS_DIR}/")
+  set(WindowsLibPath 
+        "${SDK_DIR}/Windows Kits/10/UnionMetadata/${WinSDK_VERSION}"
+        "${SDK_DIR}/Windows Kits/10/References/${WinSDK_VERSION}"
+  )
+  cmake_path(CONVERT "${WindowsLibPath}" TO_NATIVE_PATH_LIST WindowsLibPath NORMALIZE)
+  set(ENV{WindowsLibPath} "${WindowsLibPath}")
+  set(ENV{WindowsSdkBinPath} "${SDK_DIR}/Windows Kits/10/bin/")
+  set(ENV{WindowsSdkDir} "${SDK_DIR}/Windows Kits/10/")
+  set(ENV{WindowsSDKLibVersion} "${WinSDK_VERSION}\\")
+  set(ENV{WindowsSdkVerBinPath} "${SDK_DIR}/Windows Kits/10/bin/${WinSDK_VERSION}/")
+  set(ENV{WindowsSDKVersion} "${WinSDK_VERSION}\\")
+  #set(WindowsSDK_ExecutablePath_x64 "${SDK_DIR}/Windows/v10.0A/bin/NETFX 4.8 Tools/x64/")
+  #set(WindowsSDK_ExecutablePath_x86 "${SDK_DIR}/Windows/v10.0A/bin/NETFX 4.8 Tools/")
+
+  set(ADD_TO_PATH 
+        "${VS_DIR}/VC/Tools/MSVC/${VCToolkit_VERSION}/bin/HostX64/x64"
+        #${VS_DIR}/Common7/IDE/VC/VCPackages
+        #${VS_DIR}/Common7/IDE/CommonExtensions/Microsoft/TestWindow
+        #${VS_DIR}/Common7/IDE/CommonExtensions/Microsoft/TeamFoundation/Team Explorer
+        "${VS_DIR}/MSBuild/Current/bin/Roslyn"
+        #C:/Program Files (x86)/Microsoft SDKs/Windows/v10.0A/bin/NETFX 4.8 Tools/x64/
+        #C:/Program Files (x86)/HTML Help Workshop
+        #${VS_DIR}/Common7/IDE/CommonExtensions/Microsoft/FSharp/Tools
+        #${VS_DIR}/Team Tools/DiagnosticsHub/Collector
+        "${SDK_DIR}/Windows Kits/10/bin/${WinSDK_VERSION}/x64"
+        "${SDK_DIR}/Windows Kits/10/bin/x64"
+        "${VS_DIR}/MSBuild/Current/Bin/"
+        #C:/Windows/Microsoft.NET/Framework64/v4.0.30319
+        #${VS_DIR}/Common7/IDE/
+        #${VS_DIR}/Common7/Tools/
+  )
+  cmake_path(CONVERT "$ENV{PATH}" TO_CMAKE_PATH_LIST path)
+  list(PREPEND path ${ADD_TO_PATH})
+
+  cmake_path(CONVERT "${path}" TO_NATIVE_PATH_LIST path NORMALIZE)
+  set(ENV{PATH} "${path}")
+
+  set(ENV{VCPKG_TOOLCHAIN_ENV_ALREADY_SET} "1")
+endif()
+
+set(MSVC_FOUND TRUE)

ports/msvc/portfile.cmake

@@ -0,0 +1,25 @@
+set(VCPKG_POLICY_DLLS_WITHOUT_LIBS enabled)
+set(VCPKG_POLICY_EMPTY_INCLUDE_FOLDER enabled)
+set(VCPKG_POLICY_SKIP_COPYRIGHT_CHECK enabled)
+
+find_program(pwsh_exe NAMES pwsh powershell)
+
+include("${CMAKE_CURRENT_LIST_DIR}/portfile_winsdk.cmake")
+include("${CMAKE_CURRENT_LIST_DIR}/portfile_toolkit.cmake")
+include("${CMAKE_CURRENT_LIST_DIR}/portfile_msbuild.cmake")
+
+if(NOT VCPKG_CRT_LINKAGE STREQUAL "static")
+    file(COPY "${CURRENT_PACKAGES_DIR}/VS/VC/Redist/MSVC/${VCToolkit_REDIST_VERSION}/x64/Microsoft.VC143.CRT/" DESTINATION "${CURRENT_PACKAGES_DIR}/bin")
+    file(COPY "${CURRENT_PACKAGES_DIR}/VS/VC/Redist/MSVC/${VCToolkit_REDIST_VERSION}/x64/Microsoft.VC143.MFC/" DESTINATION "${CURRENT_PACKAGES_DIR}/bin")
+    file(COPY "${CURRENT_PACKAGES_DIR}/WinSDK/Windows Kits/10/Redist/${WinSDK_VERSION}/ucrt/DLLs/x64/" DESTINATION "${CURRENT_PACKAGES_DIR}/bin")
+
+    if(NOT VCPKG_BUILD_TYPE)
+        file(COPY "${CURRENT_PACKAGES_DIR}/VS/VC/Redist/MSVC/${VCToolkit_REDIST_VERSION}/debug_nonredist/x64/Microsoft.VC143.DebugCRT/" DESTINATION "${CURRENT_PACKAGES_DIR}/debug/bin")
+        file(COPY "${CURRENT_PACKAGES_DIR}/VS/VC/Redist/MSVC/${VCToolkit_REDIST_VERSION}/debug_nonredist/x64/Microsoft.VC143.DebugMFC/" DESTINATION "${CURRENT_PACKAGES_DIR}/debug/bin")
+        file(COPY "${CURRENT_PACKAGES_DIR}/WinSDK/Windows Kits/10/bin/${WinSDK_VERSION}/x64/ucrt" DESTINATION "${CURRENT_PACKAGES_DIR}/debug/bin")
+        file(COPY "${CURRENT_PACKAGES_DIR}/WinSDK/Windows Kits/10/Redist/${WinSDK_VERSION}/ucrt/DLLs/x64/" DESTINATION "${CURRENT_PACKAGES_DIR}/debug/bin" PATTERN "ucrtbase.dll" EXCLUDE)
+    endif()
+endif()
+
+configure_file("${CMAKE_CURRENT_LIST_DIR}/msvc-config.cmake" "${CURRENT_PACKAGES_DIR}/share/${PORT}/${PORT}-config.cmake" @ONLY)
+configure_file("${CMAKE_CURRENT_LIST_DIR}/msvc-env.cmake" "${CURRENT_PACKAGES_DIR}/share/${PORT}/msvc-env.cmake" @ONLY)

ports/msvc/portfile_msbuild.cmake

@@ -0,0 +1,66 @@
+block()
+  set(MSBuild_FILES "")
+  include("${CMAKE_CURRENT_LIST_DIR}/download_msbuild.cmake")
+  set(prefix MSBuild)
+
+  foreach(item IN LISTS ${prefix}_FILES)
+    vcpkg_download_distfile(
+        downloaded_file
+        URLS "${${prefix}_${item}_URL}"
+        FILENAME "VS-${VERSION}/MSBuild/${${prefix}_${item}_FILENAME}"
+        SHA512 "${${prefix}_${item}_SHA512}"
+    )
+
+    list(APPEND vsix_installers "${downloaded_file}")
+  endforeach()
+
+  set(counter 0)
+  foreach(item IN LISTS vsix_installers)
+      vcpkg_execute_required_process(
+        COMMAND "${pwsh_exe}" -ExecutionPolicy Bypass -File "${CMAKE_CURRENT_LIST_DIR}/extract-vsix.ps1" "-VsixFile" "${item}" "-ExtractTo" "${CURRENT_PACKAGES_DIR}/VS"
+        WORKING_DIRECTORY "${CURRENT_BUILDTREES_DIR}"
+        LOGNAME "extract_msbuild_${counter}.log"
+      )
+  endforeach()
+
+  set(msbuild_base "${CURRENT_PACKAGES_DIR}/VS/MSBuild/Microsoft/VC/v170/")
+  set(winsdk_props "${msbuild_base}/Microsoft.Cpp.WindowsSDK.props")
+  set(vc_common_props "${msbuild_base}/Microsoft.Cpp.Common.props")
+  file(READ "${winsdk_props}" winsdk_props_content)
+  string(REPLACE 
+    [[<_LatestWindowsTargetPlatformVersion>$([Microsoft.Build.Utilities.ToolLocationHelper]::GetLatestSDKTargetPlatformVersion($(SDKIdentifier), $(SDKVersion)))</_LatestWindowsTargetPlatformVersion>]]
+    "<_LatestWindowsTargetPlatformVersion>${WinSDK_VERSION}</_LatestWindowsTargetPlatformVersion>" 
+    winsdk_props_content 
+    "${winsdk_props_content}"
+  )
+  string(REPLACE 
+    [[<WindowsSdkDir_10 Condition=\"'$(WindowsSdkDir_10)' == ''\">$(Registry:HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\Microsoft SDKs\\Windows\\v10.0@InstallationFolder)</WindowsSdkDir_10>]]
+    "" 
+    winsdk_props_content 
+    "${winsdk_props_content}"
+  )
+  string(REPLACE 
+    [[<WindowsSdkDir_10 Condition=\"'$(WindowsSdkDir_10)' == ''\">$(Registry:HKEY_LOCAL_MACHINE\\SOFTWARE\\Wow6432Node\\Microsoft\\Microsoft SDKs\\Windows\\v10.0@InstallationFolder)</WindowsSdkDir_10>]]
+    "<WindowsSdkDir_10 Condition=\"'$(WindowsSdkDir_10)' == ''\">$(MSBuildThisFileDirectory)\\..\\..\\..\\..\\..\\WinSDK\\Windows Kits\\10\\</WindowsSdkDir_10>" 
+    winsdk_props_content 
+    "${winsdk_props_content}"
+  )
+  string(REPLACE 
+    [[<UniversalCRTSdkDir_10 Condition=\"'$(UniversalCRTSdkDir_10)' == ''\">$(Registry:HKEY_LOCAL_MACHINE\\SOFTWARE\\Wow6432Node\\Microsoft\\Windows Kits\\Installed Roots@KitsRoot10)</UniversalCRTSdkDir_10>]]
+    "" 
+    winsdk_props_content 
+    "${winsdk_props_content}"
+  )
+  string(REPLACE 
+    [[<UniversalCRTSdkDir_10 Condition=\"'$(UniversalCRTSdkDir_10)' == ''\">$(Registry:HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\Windows Kits\\Installed Roots@KitsRoot10)</UniversalCRTSdkDir_10>]]
+    "<UniversalCRTSdkDir_10 Condition=\"'$(UniversalCRTSdkDir_10)' == ''\">$(MSBuildThisFileDirectory)\\..\\..\\..\\..\\..\\WinSDK\\Windows Kits\\10\\</UniversalCRTSdkDir_10>" 
+    winsdk_props_content 
+    "${winsdk_props_content}"
+  )
+  file(WRITE "${winsdk_props}" "${winsdk_props_content}")
+
+  vcpkg_replace_string("${vc_common_props}"
+    [[<VSInstallDir>$(VsInstallRoot)\</VSInstallDir>]]
+    "<VSInstallDir>$(MSBuildThisFileDirectory)\\..\\..\\..\\..\\</VSInstallDir>"
+  )
+endblock()

ports/msvc/portfile_toolkit.cmake

@@ -0,0 +1,33 @@
+block(PROPAGATE VCToolkit_VERSION VCToolkit_REDIST_VERSION)
+  set(VCToolkit_FILES "")
+  include("${CMAKE_CURRENT_LIST_DIR}/download_toolkit.cmake")
+  set(prefix VCToolkit)
+
+  foreach(item IN LISTS VCToolkit_FILES)
+    vcpkg_download_distfile(
+        downloaded_file
+        URLS "${${prefix}_${item}_URL}"
+        FILENAME "VS-${VERSION}/VS/${${prefix}_${item}_FILENAME}"
+        SHA512 "${${prefix}_${item}_SHA512}"
+    )
+
+    list(APPEND vsix_installers "${downloaded_file}")
+  endforeach()
+
+  set(counter 0)
+  foreach(item IN LISTS vsix_installers)
+      math(EXPR counter "${counter} + 1")
+      message(STATUS "Extracting '${item}'")
+      vcpkg_execute_required_process(
+        COMMAND "${pwsh_exe}" -ExecutionPolicy Bypass -File "${CMAKE_CURRENT_LIST_DIR}/extract-vsix.ps1" "-VsixFile" "${item}" "-ExtractTo" "${CURRENT_PACKAGES_DIR}/VS"
+        WORKING_DIRECTORY "${CURRENT_BUILDTREES_DIR}"
+        LOGNAME "extract_msbuild_${counter}.log"
+      )
+  endforeach()
+  file(GLOB vc_redist_version_folder LIST_DIRECTORIES true "${CURRENT_PACKAGES_DIR}/VS/VC/Redist/MSVC/*")
+  cmake_path(GET vc_redist_version_folder FILENAME VCToolkit_REDIST_VERSION)
+  file(GLOB vc_toolkit_version_folder LIST_DIRECTORIES true "${CURRENT_PACKAGES_DIR}/VS/VC/Tools/MSVC/*")
+  cmake_path(GET vc_toolkit_version_folder FILENAME VCToolkit_VERSION)
+endblock()
+
+#D:\vcpkg_folders\no_msvc\packages\msvc_x64-windows-release\VS\VC\Tools\MSVC\14.41.34120

ports/msvc/portfile_winsdk.cmake

@@ -0,0 +1,122 @@
+block(PROPAGATE WinSDK_VERSION)
+  set(WinSDK_FILES "")
+  include("${CMAKE_CURRENT_LIST_DIR}/download_sdk.cmake")
+
+  set(to_skip
+      "MsiVal2-x86_en-us"
+      "Orca-x86_en-us"
+      "Windows App Certification Kit x86-x86_en-us"
+      "Windows App Certification Kit x86 \\(OnecoreUAP\\)-x86_en-us"
+      "Windows SDK for Windows Store Apps Legacy Tools-x86_en-us"
+      "Windows SDK-x86_en-us"
+  )
+
+  set(match_skip
+      "DirectX"
+      "Certification Kit Native Components"
+      "Windows App Certification Kit Native Components"
+      "Universal CRT Tools"
+      "Application Verifier"
+  )
+
+  list(APPEND to_skip ${match_skip})
+
+  list(JOIN to_skip "|" to_skip_regex)
+  set(to_skip_regex "(${to_skip_regex})")
+
+  set(exclude_from_skip
+      "Application Verifier x64 ExternalPackage (DesktopEditions)-x64_en-us"
+      "Application Verifier x64 ExternalPackage (OnecoreUAP)-x64_en-us"
+  )
+  list(JOIN exclude_from_skip "|" exclude_regex)
+  set(exclude_regex "(${exclude_regex})")
+
+  set(prefix WinSDK)
+
+  foreach(sdkitem IN LISTS WinSDK_FILES)
+    set(skip FALSE)
+    string(TOLOWER "${${prefix}_${sdkitem}_FILENAME}" filename_lower)
+
+    if(   "${${prefix}_${sdkitem}_FILENAME}" MATCHES "${to_skip_regex}" AND 
+      NOT "${${prefix}_${sdkitem}_FILENAME}" MATCHES "${exclude_regex}")
+      message(STATUS "Skipping '${${prefix}_${sdkitem}_FILENAME}'")
+      continue()
+    endif()
+
+    set(filename "${${prefix}_${sdkitem}_FILENAME}")
+    if(NOT "${filename_lower}" MATCHES "winsdk(installer|setup)")
+      string(PREPEND filename "Installers/")
+    endif()
+
+    vcpkg_download_distfile(
+        downloaded_file
+        URLS "${${prefix}_${sdkitem}_URL}"
+        FILENAME "VS-${VERSION}/WinSDK/${filename}"
+        SHA512 "${${prefix}_${sdkitem}_SHA512}"
+    )
+
+    if(downloaded_file MATCHES ".msi$")
+      list(APPEND msi_installers "${downloaded_file}")
+    endif()
+  endforeach()
+
+  set(installFolderSdk "${CURRENT_PACKAGES_DIR}/WinSDK")
+
+  set(counter 0)
+  foreach(msi IN LISTS msi_installers)
+    cmake_path(GET msi STEM LAST_ONLY componentName)
+    cmake_path(GET msi FILENAME filename)
+    math(EXPR counter "${counter} + 1")
+
+    message(STATUS "Extracting '${componentName}'")
+    string(REPLACE " " "" componentName "${componentName}")
+    set(installLocation "${CURRENT_BUILDTREES_DIR}/sdk")
+
+    # Create the install location directory
+    file(MAKE_DIRECTORY "${installLocation}")
+    cmake_path(NATIVE_PATH installLocation NORMALIZE installLocation)
+    cmake_path(NATIVE_PATH msi NORMALIZE msi)
+
+    # Extract the MSI file
+    cmake_path(NATIVE_PATH msi msi_native)
+    vcpkg_execute_required_process(
+        COMMAND "${LESSMSI}" x "${msi_native}"
+        WORKING_DIRECTORY "${installLocation}"
+        LOGNAME "lessmsi-${componentName}_cmake.log"
+    )
+    cmake_path(GET msi FILENAME packstem)
+    string(REPLACE ".msi" "" packstem "${packstem}")
+
+    # Copy the extracted files to the SDK install folder
+    if(EXISTS "${installLocation}/${packstem}/SourceDir/")
+        file(COPY "${installLocation}/${packstem}/SourceDir/" DESTINATION "${installFolderSdk}/")
+    else()
+        message(STATUS "Installer had no files or dirs to extract")
+        message(STATUS "Skipping '${componentName}'")
+    endif()
+
+    # Handle extra categories
+    foreach(pattern IN LISTS exclude_from_skip)
+        if(skip AND componentName MATCHES "${pattern}")
+            file(GLOB_RECURSE catFiles "${installLocation}/*.cat")
+            set(catalogsPath "${installFolderSdk}/Program Files/Windows Kits/10/Catalogs")
+            file(MAKE_DIRECTORY "${catalogsPath}")
+            foreach(catFile IN LISTS catFiles)
+                file(COPY "${catFile}" DESTINATION "${catalogsPath}")
+            endforeach()
+        endif()
+    endforeach()
+
+    # Handle specific component
+    if(componentName MATCHES "WindowsAppCertificationKitNativeComponents-x64_en-us")
+        set(kitsPath "${installFolderSdk}/Windows Kits")
+        file(MAKE_DIRECTORY "${kitsPath}")
+        file(COPY "${installLocation}/Windows Kits" DESTINATION "${kitsPath}")
+    endif()
+  endforeach()
+
+  # Remove unknown stuff
+  file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/WinSDK/Windows App Certification Kit/")
+  file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/WinSDK/Microsoft/")
+  file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/WinSDK/Microsoft SDKs/")
+endblock()

ports/msvc/vcpkg.json

@@ -0,0 +1,8 @@
+{
+  "name": "msvc",
+  "version": "17.12.0",
+  "license": "MIT",
+  "dependencies": [
+    "vcpkg-tool-lessmsi"
+  ]
+}

ports/vcpkg-cmake/vcpkg.json

@@ -2,5 +2,8 @@
   "name": "vcpkg-cmake",
   "version-date": "2024-04-23",
   "documentation": "https://learn.microsoft.com/vcpkg/maintainers/functions/vcpkg_cmake_configure",
-  "license": "MIT"
+  "license": "MIT",
+  "dependencies" : [
+    "msvc"
+  ]
 }