Enabled to overwrite sort method for the regexp.

[usualoma]

Motivation

I want to weight to some conditions explicitly.

my $ra = Regexp::Assemble->new->track(1);
$ra->add(qw(ab [a-z]+));
say $ra->match('ab'); # "[a-z]+" is returned, but I want to get "ab"

Proposal

I think that we can specify matching order by specifying comparison function for regular expression.

local $Regexp::Assemble::Regexp_Cmp = sub($$) {
    my ($a, $b) = @_;
    $a =~ m/[\*\+]/ <=> $b =~ m/[\*\+]/ || $a cmp $b;
};

my $ra = Regexp::Assemble->new->track(1);
$ra->add(qw(ab [a-z]+));
say $ra->match('ab'); # "ab" is returned.

[ronsavage]

I would not do that because it would affect everyone who upgraded to the new version, wouldn't it? I suggest you simply subclass Regexp::Assemble itself, add that code (or a new method) and use your own local copy of that code. Alternately, you could propose a new method which does what you want but has no effect on any other user. That is, users could call or ignore your new method.

[usualoma]

@ronsavage
Thank you for your quick response.

Simple subclassing

I think that we can not resolve this problem by simple subclassing.

package Regexp::Assemble::Custom {
    use parent 'Regexp::Assemble';

    sub _re_sort($$) {
        my ($a, $b) = @_;
        $a =~ m/[\*\+]/ <=> $b =~ m/[\*\+]/ || $a cmp $b;
    }
}

my $ra = Regexp::Assemble::Custom->new->track(1);
$ra->add(qw(ab [a-z]+));
say $ra->match('ab'); # "[a-z]+" is returned. Regexp::Assemble::Custom::_re_sort is not called

To overwrite _re_sort by simple subclassing

If $self->_re_sort is used at Regexp::Assemble, we can resolve that by simple sublassing. However, there are places where we can not be simply replaced by $self->_re_sort.

diff --git a/lib/Regexp/Assemble.pm b/lib/Regexp/Assemble.pm
index 57f2fe9..c2f0dc0 100644
--- a/lib/Regexp/Assemble.pm
+++ b/lib/Regexp/Assemble.pm
@@ -1832,7 +1832,7 @@ sub _re_path_track {
                 grep { $_ ne '' }
                 keys %{$in->[$n]}
             ];
-            $o = '(?:' . join( '|' => sort _re_sort @$path ) . ')';
+            $o = '(?:' . join( '|' => sort {$self->_re_sort($a,$b)} @$path ) . ')';
             $o .= '?' if exists $in->[$n]{''};
             $simple  .= $o;
             $augment .= $o;

package Regexp::Assemble::Custom {
    use parent 'Regexp::Assemble';

    sub _re_sort {
        my ($self, $a, $b) = @_;
        $a =~ m/[\*\+]/ <=> $b =~ m/[\*\+]/ || $a cmp $b;
    }
}

my $ra = Regexp::Assemble::Custom->new->track(1);
$ra->add(qw(ab [a-z]+));
say $ra->match('ab'); # "ab" is returned.

To overwrite _re_sort by redifine

If __PACKAGE__->_re_sort is used at Regexp::Assemble, we can resolve that by redifine.

patch: https://gist.github.com/usualoma/58a89fd5bc8c4cfe634259158f1f46d2

use Regexp::Assemble;

package Regexp::Assemble;
no warnings 'redefine';
sub _re_sort {
    $a =~ m/[\*\+]/ <=> $b =~ m/[\*\+]/ || $a cmp $b;
};

package main;

my $ra = Regexp::Assemble->new->track(1);
$ra->add(qw(ab [a-z]+));
say $ra->match('ab'); # "ab" is returned.

about 40608cb

I believe that 40608cb is less affected and can be solved without using dirty hacks.
40608cb is fully compatible with current version (0.37), so I think that 40608cb does not break environments that is upgraded from current version.

[ronsavage]

Hmmm. I can see you've been very thorough. I can't work on this right now, since I'm at $work, so I'll have to think about it.

[usualoma]

Thank you very much. I am not in a hurry. I'd appreciate it if you could answer at your convenience.

[usualoma]

Oh... very sorry.

To overwrite _re_sort by redifine

The following code also worked at 0.37 without patch

use Regexp::Assemble;

package Regexp::Assemble;
no warnings 'redefine';
sub _re_sort {
    $a =~ m/[\*\+]/ <=> $b =~ m/[\*\+]/ || $a cmp $b;
};

package main;

my $ra = Regexp::Assemble->new->track(1);
$ra->add(qw(ab [a-z]+));
say $ra->match('ab'); # "ab" is returned.

I think that 40608cb is useful, however even without it, I can do what I want to do.

[ronsavage]

Hi Taku Glad to hear you've kept working on this, and that you've done so well. Nevertheless, I'll have a look at the code over the weekend.

…

On 11/04/17 11:28, Taku AMANO wrote: Oh... very sorry. To overwrite |_re_sort| by redifine The following code also worked at 0.37 without patch <https://gist.github.com/usualoma/58a89fd5bc8c4cfe634259158f1f46d2> use Regexp::Assemble; package Regexp::Assemble; no warnings 'redefine'; sub _re_sort { $a =~ m/[\*\+]/ <=> $b =~ m/[\*\+]/ || $a cmp $b; }; package main; my $ra = Regexp::Assemble->new->track(1); $ra->add(qw(ab [a-z]+)); say $ra->match('ab'); # "ab" is returned. I think that 40608cb <40608cb> is useful, however even without it, I can do what I want to do. — You are receiving this because you were mentioned. Reply to this email directly, view it on GitHub <#6 (comment)>, or mute the thread <https://github.com/notifications/unsubscribe-auth/AABT-AKabVIVjq46uduxqQndqqNLEZJQks5rutdFgaJpZM4M4JAg>.

-- Ron Savage - savage.net.au